1add_custom_command(
2  OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/LLDBWrapPython.cpp
3  OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/lldb.py
4  DEPENDS ${SWIG_SOURCES}
5  DEPENDS ${SWIG_INTERFACES}
6  DEPENDS ${SWIG_HEADERS}
7  COMMAND ${SWIG_EXECUTABLE}
8      ${SWIG_COMMON_FLAGS}
9      -I${CMAKE_CURRENT_SOURCE_DIR}
10      -c++
11      -shadow
12      -python
13      -py3
14      -threads
15      -outdir ${CMAKE_CURRENT_BINARY_DIR}
16      -o ${CMAKE_CURRENT_BINARY_DIR}/LLDBWrapPython.cpp
17      ${CMAKE_CURRENT_SOURCE_DIR}/python.swig
18  VERBATIM
19  COMMENT "Building LLDB Python wrapper")
20
21add_custom_target(swig_wrapper_python ALL DEPENDS
22  ${CMAKE_CURRENT_BINARY_DIR}/LLDBWrapPython.cpp
23  ${CMAKE_CURRENT_BINARY_DIR}/lldb.py
24)
25
26if (NOT WIN32)
27add_custom_command(
28  OUTPUT  ${LLVM_RUNTIME_OUTPUT_INTDIR}/lldb-python
29  VERBATIM
30  COMMAND ${CMAKE_COMMAND} -E copy lldb-python ${LLVM_RUNTIME_OUTPUT_INTDIR}/lldb-python
31  WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
32)
33add_custom_target(lldb-python-wrapper ALL DEPENDS
34  ${LLVM_RUNTIME_OUTPUT_INTDIR}/lldb-python
35)
36endif()
37
38function(create_python_package swig_target working_dir pkg_dir)
39  cmake_parse_arguments(ARG "NOINIT" "" "FILES" ${ARGN})
40  if(ARG_FILES)
41    set(copy_cmd COMMAND ${CMAKE_COMMAND} -E copy ${ARG_FILES} ${pkg_dir})
42  endif()
43  if(NOT ARG_NOINIT)
44    set(init_cmd COMMAND ${Python3_EXECUTABLE}
45        "${LLDB_SOURCE_DIR}/bindings/python/createPythonInit.py"
46        "${pkg_dir}" ${ARG_FILES})
47  endif()
48  add_custom_command(TARGET ${swig_target} POST_BUILD VERBATIM
49    COMMAND ${CMAKE_COMMAND} -E make_directory ${pkg_dir}
50    ${copy_cmd}
51    ${init_cmd}
52    WORKING_DIRECTORY ${working_dir})
53endfunction()
54
55function(finish_swig_python swig_target lldb_python_bindings_dir lldb_python_target_dir)
56  # Add a Post-Build Event to copy over Python files and create the symlink to
57  # liblldb.so for the Python API(hardlink on Windows).
58  add_custom_target(${swig_target} ALL VERBATIM
59    COMMAND ${CMAKE_COMMAND} -E make_directory ${lldb_python_target_dir}
60    DEPENDS ${lldb_python_bindings_dir}/lldb.py
61    COMMENT "Python script sym-linking LLDB Python API")
62
63  if(NOT LLDB_USE_SYSTEM_SIX)
64    add_custom_command(TARGET ${swig_target} POST_BUILD VERBATIM
65      COMMAND ${CMAKE_COMMAND} -E copy
66        "${LLDB_SOURCE_DIR}/third_party/Python/module/six/six.py"
67        "${lldb_python_target_dir}/../six.py")
68  endif()
69
70  add_custom_command(TARGET ${swig_target} POST_BUILD VERBATIM
71    COMMAND ${CMAKE_COMMAND} -E copy
72      "${lldb_python_bindings_dir}/lldb.py"
73      "${lldb_python_target_dir}/__init__.py")
74
75  add_custom_command(TARGET ${swig_target} POST_BUILD VERBATIM
76    COMMAND ${CMAKE_COMMAND} -E copy
77      "${LLDB_SOURCE_DIR}/source/Interpreter/embedded_interpreter.py"
78      "${lldb_python_target_dir}")
79
80  # Distribute the examples as python packages.
81  create_python_package(
82    ${swig_target}
83    ${lldb_python_target_dir}
84    "formatters/cpp"
85    FILES "${LLDB_SOURCE_DIR}/examples/synthetic/gnu_libstdcpp.py"
86          "${LLDB_SOURCE_DIR}/examples/synthetic/libcxx.py")
87
88  create_python_package(
89    ${swig_target}
90    ${lldb_python_target_dir}
91    "formatters"
92    FILES "${LLDB_SOURCE_DIR}/examples/summaries/cocoa/cache.py"
93          "${LLDB_SOURCE_DIR}/examples/summaries/synth.py"
94          "${LLDB_SOURCE_DIR}/examples/summaries/cocoa/metrics.py"
95          "${LLDB_SOURCE_DIR}/examples/summaries/cocoa/attrib_fromdict.py"
96          "${LLDB_SOURCE_DIR}/examples/summaries/cocoa/Logger.py")
97
98  create_python_package(
99    ${swig_target}
100    ${lldb_python_target_dir}
101    "utils"
102    FILES "${LLDB_SOURCE_DIR}/examples/python/in_call_stack.py"
103          "${LLDB_SOURCE_DIR}/examples/python/symbolication.py")
104
105  create_python_package(
106    ${swig_target}
107    ${lldb_python_target_dir}
108    "plugins"
109    FILES
110    "${LLDB_SOURCE_DIR}/examples/python/scripted_process/scripted_process.py")
111
112  if(APPLE)
113    create_python_package(
114      ${swig_target}
115      ${lldb_python_target_dir} "macosx"
116      FILES "${LLDB_SOURCE_DIR}/examples/python/crashlog.py"
117            "${LLDB_SOURCE_DIR}/examples/darwin/heap_find/heap.py")
118
119    create_python_package(
120      ${swig_target}
121      ${lldb_python_target_dir} "macosx/heap"
122      FILES "${LLDB_SOURCE_DIR}/examples/darwin/heap_find/heap/heap_find.cpp"
123            "${LLDB_SOURCE_DIR}/examples/darwin/heap_find/heap/Makefile"
124            NOINIT)
125
126    create_python_package(
127      ${swig_target}
128      ${lldb_python_target_dir} "diagnose"
129      FILES "${LLDB_SOURCE_DIR}/examples/python/diagnose_unwind.py"
130            "${LLDB_SOURCE_DIR}/examples/python/diagnose_nsstring.py")
131  endif()
132
133  if(LLDB_BUILD_FRAMEWORK)
134    set(LIBLLDB_SYMLINK_DEST "${LLDB_FRAMEWORK_ABSOLUTE_BUILD_DIR}/LLDB.framework/LLDB")
135  else()
136    set(LIBLLDB_SYMLINK_DEST "${LLVM_SHLIB_OUTPUT_INTDIR}/liblldb${CMAKE_SHARED_LIBRARY_SUFFIX}")
137  endif()
138  set(LIBLLDB_SYMLINK_OUTPUT_FILE "_lldb${LLDB_PYTHON_EXT_SUFFIX}")
139  create_relative_symlink(${swig_target} ${LIBLLDB_SYMLINK_DEST}
140                          ${lldb_python_target_dir} ${LIBLLDB_SYMLINK_OUTPUT_FILE})
141
142
143  if (NOT WIN32)
144  add_dependencies(${swig_target} lldb-python-wrapper)
145  endif()
146
147  if(NOT LLDB_BUILD_FRAMEWORK)
148    set(LLDB_ARGDUMPER_FILENAME "lldb-argdumper${CMAKE_EXECUTABLE_SUFFIX}")
149    create_relative_symlink(${swig_target} "${LLVM_RUNTIME_OUTPUT_INTDIR}/${LLDB_ARGDUMPER_FILENAME}"
150                            ${lldb_python_target_dir} ${LLDB_ARGDUMPER_FILENAME})
151  endif()
152
153  add_dependencies(${swig_target} swig_wrapper_python liblldb lldb-argdumper)
154  set_target_properties(${swig_target} swig_wrapper_python PROPERTIES FOLDER "lldb misc")
155
156  # Ensure we do the python post-build step when building lldb.
157  add_dependencies(lldb ${swig_target})
158
159  # Install the LLDB python module
160  if(LLDB_BUILD_FRAMEWORK)
161    set(LLDB_PYTHON_INSTALL_PATH ${LLDB_FRAMEWORK_INSTALL_DIR}/LLDB.framework/Versions/${LLDB_FRAMEWORK_VERSION}/Resources/Python)
162  else()
163    set(LLDB_PYTHON_INSTALL_PATH ${LLDB_PYTHON_RELATIVE_PATH})
164  endif()
165  if (NOT CMAKE_CFG_INTDIR STREQUAL  ".")
166    string(REPLACE ${CMAKE_CFG_INTDIR} "\$\{CMAKE_INSTALL_CONFIG_NAME\}" LLDB_PYTHON_INSTALL_PATH ${LLDB_PYTHON_INSTALL_PATH})
167    string(REPLACE ${CMAKE_CFG_INTDIR} "\$\{CMAKE_INSTALL_CONFIG_NAME\}" lldb_python_target_dir ${lldb_python_target_dir})
168  endif()
169  set(python_scripts_target "${swig_target}-scripts")
170  set(python_scripts_install_target "install-${python_scripts_target}")
171  add_custom_target(${python_scripts_target})
172  add_dependencies(${python_scripts_target} ${swig_target})
173  install(DIRECTORY ${lldb_python_target_dir}/../
174          DESTINATION ${LLDB_PYTHON_INSTALL_PATH}
175          COMPONENT ${python_scripts_target})
176  if (NOT LLVM_ENABLE_IDE)
177    add_llvm_install_targets(${python_scripts_install_target}
178                             COMPONENT ${python_scripts_target}
179                             DEPENDS ${python_scripts_target})
180  endif()
181
182  # Add a Post-Build Event to copy the custom Python DLL to the lldb binaries dir so that Windows can find it when launching
183  # lldb.exe or any other executables that were linked with liblldb.
184  if (WIN32 AND NOT "${PYTHON_DLL}" STREQUAL "")
185    # When using the Visual Studio CMake generator the lldb binaries end up in Release/bin, Debug/bin etc.
186    file(TO_NATIVE_PATH "${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin" LLDB_BIN_DIR)
187    file(TO_NATIVE_PATH "${PYTHON_DLL}" PYTHON_DLL_NATIVE_PATH)
188    add_custom_command(
189      TARGET ${swig_target}
190      POST_BUILD
191      COMMAND ${CMAKE_COMMAND} -E copy ${PYTHON_DLL_NATIVE_PATH} ${LLDB_BIN_DIR} VERBATIM
192      COMMENT "Copying Python DLL to LLDB binaries directory.")
193  endif()
194endfunction()
195