1set(OBJECT_LIBRARY_TARGET_TYPE "OBJECT_LIBRARY")
2
3# Rule which is essentially a wrapper over add_library to compile a set of
4# sources to object files.
5# Usage:
6#     add_object_library(
7#       <target_name>
8#       HDRS <list of header files>
9#       SRCS <list of source files>
10#       DEPENDS <list of dependencies>
11#       COMPILE_OPTIONS <optional list of special compile options for this target>
12function(add_object_library target_name)
13  cmake_parse_arguments(
14    "ADD_OBJECT"
15    "" # No option arguments
16    "" # Single value arguments
17    "SRCS;HDRS;COMPILE_OPTIONS;DEPENDS" # Multivalue arguments
18    ${ARGN}
19  )
20
21  if(NOT ADD_OBJECT_SRCS)
22    message(FATAL_ERROR "'add_object_library' rule requires SRCS to be specified.")
23  endif()
24
25  get_fq_target_name(${target_name} fq_target_name)
26  add_library(
27    ${fq_target_name}
28    OBJECT
29    ${ADD_OBJECT_SRCS}
30    ${ADD_OBJECT_HDRS}
31  )
32  target_include_directories(
33    ${fq_target_name}
34    PRIVATE
35      ${LIBC_BUILD_DIR}/include
36      ${LIBC_SOURCE_DIR}
37      ${LIBC_BUILD_DIR}
38  )
39  if(ADD_OBJECT_COMPILE_OPTIONS)
40    target_compile_options(
41      ${fq_target_name}
42      PRIVATE ${ADD_OBJECT_COMPILE_OPTIONS}
43    )
44  endif()
45
46  get_fq_deps_list(fq_deps_list ${ADD_OBJECT_DEPENDS})
47  if(fq_deps_list)
48    add_dependencies(${fq_target_name} ${fq_deps_list})
49  endif()
50
51  set_target_properties(
52    ${fq_target_name}
53    PROPERTIES
54      "TARGET_TYPE" ${OBJECT_LIBRARY_TARGET_TYPE}
55      "OBJECT_FILES" "$<TARGET_OBJECTS:${fq_target_name}>"
56      "DEPS" "${fq_deps_list}"
57  )
58endfunction(add_object_library)
59
60set(ENTRYPOINT_OBJ_TARGET_TYPE "ENTRYPOINT_OBJ")
61
62# A rule for entrypoint object targets.
63# Usage:
64#     add_entrypoint_object(
65#       <target_name>
66#       [ALIAS|REDIRECTED] # Specified if the entrypoint is redirected or an alias.
67#       [NAME] <the C name of the entrypoint if different from target_name>
68#       SRCS <list of .cpp files>
69#       HDRS <list of .h files>
70#       DEPENDS <list of dependencies>
71#       COMPILE_OPTIONS <optional list of special compile options for this target>
72#       SPECIAL_OBJECTS <optional list of special object targets added by the rule `add_object`>
73#     )
74function(add_entrypoint_object target_name)
75  cmake_parse_arguments(
76    "ADD_ENTRYPOINT_OBJ"
77    "ALIAS;REDIRECTED" # Optional argument
78    "NAME" # Single value arguments
79    "SRCS;HDRS;DEPENDS;COMPILE_OPTIONS"  # Multi value arguments
80    ${ARGN}
81  )
82
83  get_fq_target_name(${target_name} fq_target_name)
84
85  if(ADD_ENTRYPOINT_OBJ_ALIAS)
86    # Alias targets help one add aliases to other entrypoint object targets.
87    # One can use alias targets setup OS/machine independent entrypoint targets.
88    list(LENGTH ADD_ENTRYPOINT_OBJ_DEPENDS deps_size)
89    if(NOT (${deps_size} EQUAL "1"))
90      message(FATAL_ERROR "An entrypoint alias should have exactly one dependency.")
91    endif()
92    list(GET ADD_ENTRYPOINT_OBJ_DEPENDS 0 dep_target)
93    get_fq_dep_name(fq_dep_name ${dep_target})
94    if(NOT TARGET ${fq_dep_name})
95      message(WARNING "Aliasee ${fq_dep_name} for entrypoint alias ${target_name} missing; "
96                      "Target ${target_name} will be ignored.")
97      return()
98    endif()
99
100    get_target_property(obj_type ${fq_dep_name} "TARGET_TYPE")
101    if((NOT obj_type) OR (NOT (${obj_type} STREQUAL ${ENTRYPOINT_OBJ_TARGET_TYPE})))
102      message(FATAL_ERROR "The aliasee of an entrypoint alias should be an entrypoint.")
103    endif()
104
105    add_custom_target(${fq_target_name})
106    add_dependencies(${fq_target_name} ${fq_dep_name})
107    get_target_property(object_file ${fq_dep_name} "OBJECT_FILE")
108    get_target_property(object_file_raw ${fq_dep_name} "OBJECT_FILE_RAW")
109    set_target_properties(
110      ${fq_target_name}
111      PROPERTIES
112        "TARGET_TYPE" ${ENTRYPOINT_OBJ_TARGET_TYPE}
113        "OBJECT_FILE" ""
114        "OBJECT_FILE_RAW" ""
115        "DEPS" "${fq_dep_name}"
116    )
117    return()
118  endif()
119
120  if(NOT ADD_ENTRYPOINT_OBJ_SRCS)
121    message(FATAL_ERROR "`add_entrypoint_object` rule requires SRCS to be specified.")
122  endif()
123  if(NOT ADD_ENTRYPOINT_OBJ_HDRS)
124    message(FATAL_ERROR "`add_entrypoint_object` rule requires HDRS to be specified.")
125  endif()
126
127  set(entrypoint_name ${target_name})
128  if(ADD_ENTRYPOINT_OBJ_NAME)
129    set(entrypoint_name ${ADD_ENTRYPOINT_OBJ_NAME})
130  endif()
131
132  set(objects_target_name "${fq_target_name}_objects")
133
134  add_library(
135    ${objects_target_name}
136    # We want an object library as the objects will eventually get packaged into
137    # an archive (like libc.a).
138    OBJECT
139    ${ADD_ENTRYPOINT_OBJ_SRCS}
140    ${ADD_ENTRYPOINT_OBJ_HDRS}
141  )
142  target_compile_options(
143    ${objects_target_name}
144    BEFORE
145    PRIVATE
146      -fpie ${LLVM_CXX_STD_default}
147  )
148  target_include_directories(
149    ${objects_target_name}
150    PRIVATE
151      ${LIBC_BUILD_DIR}/include
152      ${LIBC_SOURCE_DIR}
153      ${LIBC_BUILD_DIR}
154  )
155  get_fq_deps_list(fq_deps_list ${ADD_ENTRYPOINT_OBJ_DEPENDS})
156  add_dependencies(
157    ${objects_target_name}
158    libc.src.__support.common
159    ${fq_deps_list}
160  )
161
162  if(ADD_ENTRYPOINT_OBJ_COMPILE_OPTIONS)
163    target_compile_options(
164      ${objects_target_name}
165      PRIVATE ${ADD_ENTRYPOINT_OBJ_COMPILE_OPTIONS}
166    )
167  endif()
168
169  set(object_file_raw "${CMAKE_CURRENT_BINARY_DIR}/${target_name}_raw.o")
170  set(object_file "${CMAKE_CURRENT_BINARY_DIR}/${target_name}.o")
171
172  set(input_objects $<TARGET_OBJECTS:${objects_target_name}>)
173  add_custom_command(
174    OUTPUT ${object_file_raw}
175    DEPENDS ${input_objects}
176    COMMAND ${CMAKE_LINKER} -r ${input_objects} -o ${object_file_raw}
177  )
178
179  set(alias_attributes "0,function,global")
180  if(ADD_ENTRYPOINT_OBJ_REDIRECTED)
181    set(alias_attributes "${alias_attributes},hidden")
182  endif()
183
184  add_custom_command(
185    OUTPUT ${object_file}
186    # We llvm-objcopy here as GNU-binutils objcopy does not support the 'hidden' flag.
187    DEPENDS ${object_file_raw} ${llvm-objcopy}
188    COMMAND $<TARGET_FILE:llvm-objcopy> --add-symbol
189            "${entrypoint_name}=.llvm.libc.entrypoint.${entrypoint_name}:${alias_attributes}"
190            ${object_file_raw} ${object_file}
191  )
192
193  add_custom_target(
194    ${fq_target_name}
195    ALL
196    DEPENDS ${object_file}
197  )
198  set_target_properties(
199    ${fq_target_name}
200    PROPERTIES
201      "TARGET_TYPE" ${ENTRYPOINT_OBJ_TARGET_TYPE}
202      "OBJECT_FILE" "${object_file}"
203      "OBJECT_FILE_RAW" "${object_file_raw}"
204      "DEPS" "${fq_deps_list}"
205  )
206
207  if(LLVM_LIBC_ENABLE_LINTING)
208    set(lint_timestamp "${CMAKE_CURRENT_BINARY_DIR}/.${target_name}.__lint_timestamp__")
209
210    add_custom_command(
211      OUTPUT ${lint_timestamp}
212      # --quiet is used to surpress warning statistics from clang-tidy like:
213      #     Suppressed X warnings (X in non-user code).
214      # There seems to be a bug in clang-tidy where by even with --quiet some
215      # messages from clang's own diagnostics engine leak through:
216      #     X warnings generated.
217      # Until this is fixed upstream, we use -fno-caret-diagnostics to surpress
218      # these.
219      COMMAND $<TARGET_FILE:clang-tidy> "--extra-arg=-fno-caret-diagnostics" --quiet
220              # Path to directory containing compile_commands.json
221              -p ${PROJECT_BINARY_DIR}
222              ${ADD_ENTRYPOINT_OBJ_SRCS}
223      # We have two options for running commands, add_custom_command and
224      # add_custom_target. We don't want to run the linter unless source files
225      # have changed. add_custom_target explicitly runs everytime therefore we
226      # use add_custom_command. This function requires an output file and since
227      # linting doesn't produce a file, we create a dummy file using a
228      # crossplatform touch.
229      COMMAND "${CMAKE_COMMAND}" -E touch ${lint_timestamp}
230      COMMENT "Linting... ${target_name}"
231      DEPENDS ${clang-tidy} ${objects_target_name} ${ADD_ENTRYPOINT_OBJ_SRCS}
232      WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
233    )
234
235    add_custom_target(${fq_target_name}.__lint__
236      DEPENDS ${lint_timestamp})
237    add_dependencies(lint-libc ${fq_target_name}.__lint__)
238    add_dependencies(${fq_target_name} ${fq_target_name}.__lint__)
239  endif()
240
241endfunction(add_entrypoint_object)
242
243# Rule build a redirector object file.
244function(add_redirector_object target_name)
245  cmake_parse_arguments(
246    "REDIRECTOR_OBJECT"
247    "" # No optional arguments
248    "SRC" # The cpp file in which the redirector is defined.
249    "" # No multivalue arguments
250    ${ARGN}
251  )
252  if(NOT REDIRECTOR_OBJECT_SRC)
253    message(FATAL_ERROR "'add_redirector_object' rule requires SRC option listing one source file.")
254  endif()
255
256  add_library(
257    ${target_name}
258    OBJECT
259    ${REDIRECTOR_OBJECT_SRC}
260  )
261  target_compile_options(
262    ${target_name}
263    BEFORE PRIVATE -fPIC
264  )
265endfunction(add_redirector_object)
266