1// Test overlapping assignment of derived type arrays with allocatable components.
2// This requires initializing the allocatable components to an unallocated status
3// before they can be used in component assignments, and to deallocate the components
4// that may have been allocated in the end.
5
6// RUN: fir-opt --array-value-copy %s | FileCheck %s
7
8
9!t_with_alloc_comp = type !fir.type<t{i:!fir.box<!fir.heap<!fir.array<?xi32>>>}>
10func.func private @custom_assign(!fir.ref<!t_with_alloc_comp>, !fir.ref<!t_with_alloc_comp>)
11func.func @test_overlap_with_alloc_components(%arg0: !fir.ref<!fir.array<10x!t_with_alloc_comp>>) {
12  %0 = fir.alloca !fir.box<!t_with_alloc_comp>
13  %c10 = arith.constant 10 : index
14  %c9 = arith.constant 9 : index
15  %c1 = arith.constant 1 : index
16  %c-1 = arith.constant -1 : index
17  %c0 = arith.constant 0 : index
18  %1 = fir.shape %c10 : (index) -> !fir.shape<1>
19  %6 = fir.slice %c10, %c1, %c-1 : (index, index, index) -> !fir.slice<1>
20  %2 = fir.array_load %arg0(%1) : (!fir.ref<!fir.array<10x!t_with_alloc_comp>>, !fir.shape<1>) -> !fir.array<10x!t_with_alloc_comp>
21  %7 = fir.array_load %arg0(%1) [%6] : (!fir.ref<!fir.array<10x!t_with_alloc_comp>>, !fir.shape<1>, !fir.slice<1>) -> !fir.array<10x!t_with_alloc_comp>
22  %9 = fir.do_loop %arg1 = %c0 to %c9 step %c1 unordered iter_args(%arg2 = %2) -> (!fir.array<10x!t_with_alloc_comp>) {
23    %10 = fir.array_access %7, %arg1 : (!fir.array<10x!t_with_alloc_comp>, index) -> !fir.ref<!t_with_alloc_comp>
24    %11 = fir.array_access %arg2, %arg1 : (!fir.array<10x!t_with_alloc_comp>, index) -> !fir.ref<!t_with_alloc_comp>
25    fir.call @custom_assign(%11, %10) : (!fir.ref<!t_with_alloc_comp>, !fir.ref<!t_with_alloc_comp>) -> none
26    %19 = fir.array_amend %arg2, %11 : (!fir.array<10x!t_with_alloc_comp>, !fir.ref<!t_with_alloc_comp>) -> !fir.array<10x!t_with_alloc_comp>
27    fir.result %19 : !fir.array<10x!t_with_alloc_comp>
28  }
29  fir.array_merge_store %2, %9 to %arg0 : !fir.array<10x!t_with_alloc_comp>, !fir.array<10x!t_with_alloc_comp>, !fir.ref<!fir.array<10x!t_with_alloc_comp>>
30  return
31}
32
33// CHECK-LABEL: func @test_overlap_with_alloc_components(
34// CHECK-SAME:  %[[VAL_0:.*]]: !fir.ref<!fir.array<10x!fir.type<t{i:!fir.box<!fir.heap<!fir.array<?xi32>>>}>>>) {
35// CHECK:   %[[VAL_4:.*]] = arith.constant 10 : index
36// CHECK:   %[[VAL_6:.*]] = arith.constant 1 : index
37// CHECK:   %[[VAL_7:.*]] = arith.constant -1 : index
38// CHECK:   %[[VAL_9:.*]] = fir.shape %[[VAL_4]] : (index) -> !fir.shape<1>
39// CHECK:   %[[VAL_10:.*]] = fir.slice %[[VAL_4]], %[[VAL_6]], %[[VAL_7]] : (index, index, index) -> !fir.slice<1>
40// CHECK:   %[[VAL_11:.*]] = fir.allocmem !fir.array<10x!fir.type<t{i:!fir.box<!fir.heap<!fir.array<?xi32>>>}>>
41// CHECK:   %[[VAL_12:.*]] = fir.embox %[[VAL_11]](%[[VAL_9]]) : (!fir.heap<!fir.array<10x!fir.type<t{i:!fir.box<!fir.heap<!fir.array<?xi32>>>}>>>, !fir.shape<1>) -> !fir.box<!fir.ref<!fir.array<10x!fir.type<t{i:!fir.box<!fir.heap<!fir.array<?xi32>>>}>>>>
42// CHECK:   %[[VAL_16:.*]] = fir.convert %[[VAL_12]] : (!fir.box<!fir.ref<!fir.array<10x!fir.type<t{i:!fir.box<!fir.heap<!fir.array<?xi32>>>}>>>>) -> !fir.box<none>
43// CHECK:   fir.call @_FortranAInitialize(%[[VAL_16]], %{{.*}}, %{{.*}}) : (!fir.box<none>, !fir.ref<i8>, i32) -> none
44// CHECK:   fir.do_loop {{.*}} {
45// CHECK:     fir.call @_FortranAAssign
46// CHECK:   }
47// CHECK:   fir.do_loop {{.*}} {
48// CHECK:     fir.call @custom_assign
49// CHECK:   }
50// CHECK:   fir.do_loop %{{.*}} {
51// CHECK:     fir.call @_FortranAAssign
52// CHECK:   }
53// CHECK:   %[[VAL_72:.*]] = fir.convert %[[VAL_12]] : (!fir.box<!fir.ref<!fir.array<10x!fir.type<t{i:!fir.box<!fir.heap<!fir.array<?xi32>>>}>>>>) -> !fir.box<none>
54// CHECK:   %[[VAL_73:.*]] = fir.call @_FortranADestroy(%[[VAL_72]]) : (!fir.box<none>) -> none
55// CHECK:   fir.freemem %[[VAL_11]]
56