1if (COMPILER_RT_BUILD_SANITIZERS)
2  set(SANITIZER_HEADERS
3    sanitizer/allocator_interface.h
4    sanitizer/asan_interface.h
5    sanitizer/common_interface_defs.h
6    sanitizer/coverage_interface.h
7    sanitizer/dfsan_interface.h
8    sanitizer/esan_interface.h
9    sanitizer/linux_syscall_hooks.h
10    sanitizer/lsan_interface.h
11    sanitizer/msan_interface.h
12    sanitizer/tsan_interface.h
13    sanitizer/tsan_interface_atomic.h)
14endif(COMPILER_RT_BUILD_SANITIZERS)
15
16if (COMPILER_RT_BUILD_XRAY)
17  set(XRAY_HEADERS
18    xray/xray_interface.h
19    xray/xray_log_interface.h)
20endif(COMPILER_RT_BUILD_XRAY)
21
22set(COMPILER_RT_HEADERS
23  ${SANITIZER_HEADERS}
24	${XRAY_HEADERS})
25
26set(output_dir ${COMPILER_RT_OUTPUT_DIR}/include)
27
28# Copy compiler-rt headers to the build tree.
29set(out_files)
30foreach( f ${COMPILER_RT_HEADERS} )
31  set( src ${CMAKE_CURRENT_SOURCE_DIR}/${f} )
32  set( dst ${output_dir}/${f} )
33  add_custom_command(OUTPUT ${dst}
34    DEPENDS ${src}
35    COMMAND ${CMAKE_COMMAND} -E copy_if_different ${src} ${dst}
36    COMMENT "Copying compiler-rt's ${f}...")
37  list(APPEND out_files ${dst})
38endforeach( f )
39
40add_custom_target(compiler-rt-headers ALL DEPENDS ${out_files})
41add_dependencies(compiler-rt compiler-rt-headers)
42set_target_properties(compiler-rt-headers PROPERTIES FOLDER "Compiler-RT Misc")
43
44# Install sanitizer headers.
45install(FILES ${SANITIZER_HEADERS}
46  PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ
47  DESTINATION ${COMPILER_RT_INSTALL_PATH}/include/sanitizer)
48# Install xray headers.
49install(FILES ${XRAY_HEADERS}
50  PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ
51  DESTINATION ${COMPILER_RT_INSTALL_PATH}/include/xray)
52