1# Because compiler-rt spends a lot of time setting up custom compile flags,
2# define a handy helper function for it. The compile flags setting in CMake
3# has serious issues that make its syntax challenging at best.
4function(set_target_compile_flags target)
5  set(argstring "")
6  foreach(arg ${ARGN})
7    set(argstring "${argstring} ${arg}")
8  endforeach()
9  set_property(TARGET ${target} PROPERTY COMPILE_FLAGS "${argstring}")
10endfunction()
11
12function(set_target_link_flags target)
13  set(argstring "")
14  foreach(arg ${ARGN})
15    set(argstring "${argstring} ${arg}")
16  endforeach()
17  set_property(TARGET ${target} PROPERTY LINK_FLAGS "${argstring}")
18endfunction()
19
20# Set the variable var_PYBOOL to True if var holds a true-ish string,
21# otherwise set it to False.
22macro(pythonize_bool var)
23  if (${var})
24    set(${var}_PYBOOL True)
25  else()
26    set(${var}_PYBOOL False)
27  endif()
28endmacro()
29
30# Appends value to all lists in ARGN, if the condition is true.
31macro(append_list_if condition value)
32  if(${condition})
33    foreach(list ${ARGN})
34      list(APPEND ${list} ${value})
35    endforeach()
36  endif()
37endmacro()
38
39# Appends value to all strings in ARGN, if the condition is true.
40macro(append_string_if condition value)
41  if(${condition})
42    foreach(str ${ARGN})
43      set(${str} "${${str}} ${value}")
44    endforeach()
45  endif()
46endmacro()
47
48macro(append_rtti_flag polarity list)
49  if(polarity)
50    append_list_if(COMPILER_RT_HAS_FRTTI_FLAG -frtti ${list})
51    append_list_if(COMPILER_RT_HAS_GR_FLAG /GR ${list})
52  else()
53    append_list_if(COMPILER_RT_HAS_FNO_RTTI_FLAG -fno-rtti ${list})
54    append_list_if(COMPILER_RT_HAS_GR_FLAG /GR- ${list})
55  endif()
56endmacro()
57
58macro(append_have_file_definition filename varname list)
59  check_include_file("${filename}" "${varname}")
60  if (NOT ${varname})
61    set("${varname}" 0)
62  endif()
63  list(APPEND ${list} "${varname}=${${varname}}")
64endmacro()
65
66macro(list_intersect output input1 input2)
67  set(${output})
68  foreach(it ${${input1}})
69    list(FIND ${input2} ${it} index)
70    if( NOT (index EQUAL -1))
71      list(APPEND ${output} ${it})
72    endif()
73  endforeach()
74endmacro()
75
76# Takes ${ARGN} and puts only supported architectures in @out_var list.
77function(filter_available_targets out_var)
78  set(archs ${${out_var}})
79  foreach(arch ${ARGN})
80    list(FIND COMPILER_RT_SUPPORTED_ARCH ${arch} ARCH_INDEX)
81    if(NOT (ARCH_INDEX EQUAL -1) AND CAN_TARGET_${arch})
82      list(APPEND archs ${arch})
83    endif()
84  endforeach()
85  set(${out_var} ${archs} PARENT_SCOPE)
86endfunction()
87
88function(check_compile_definition def argstring out_var)
89  if("${def}" STREQUAL "")
90    set(${out_var} TRUE PARENT_SCOPE)
91    return()
92  endif()
93  cmake_push_check_state()
94  set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} ${argstring}")
95  check_symbol_exists(${def} "" ${out_var})
96  cmake_pop_check_state()
97endfunction()
98
99# test_target_arch(<arch> <def> <target flags...>)
100# Checks if architecture is supported: runs host compiler with provided
101# flags to verify that:
102#   1) <def> is defined (if non-empty)
103#   2) simple file can be successfully built.
104# If successful, saves target flags for this architecture.
105macro(test_target_arch arch def)
106  set(TARGET_${arch}_CFLAGS ${ARGN})
107  set(argstring "")
108  foreach(arg ${ARGN})
109    set(argstring "${argstring} ${arg}")
110  endforeach()
111  check_compile_definition("${def}" "${argstring}" HAS_${arch}_DEF)
112  if(NOT HAS_${arch}_DEF)
113    set(CAN_TARGET_${arch} FALSE)
114  else()
115    set(argstring "${CMAKE_EXE_LINKER_FLAGS} ${argstring}")
116    try_compile(CAN_TARGET_${arch} ${CMAKE_BINARY_DIR} ${SIMPLE_SOURCE}
117                COMPILE_DEFINITIONS "${TARGET_${arch}_CFLAGS}"
118                OUTPUT_VARIABLE TARGET_${arch}_OUTPUT
119                CMAKE_FLAGS "-DCMAKE_EXE_LINKER_FLAGS:STRING=${argstring}")
120  endif()
121  if(${CAN_TARGET_${arch}})
122    list(APPEND COMPILER_RT_SUPPORTED_ARCH ${arch})
123  elseif("${COMPILER_RT_DEFAULT_TARGET_ARCH}" MATCHES "${arch}" AND
124         COMPILER_RT_HAS_EXPLICIT_DEFAULT_TARGET_TRIPLE)
125    # Bail out if we cannot target the architecture we plan to test.
126    message(FATAL_ERROR "Cannot compile for ${arch}:\n${TARGET_${arch}_OUTPUT}")
127  endif()
128endmacro()
129