1include(CMakePushCheckState)
2include(CheckSymbolExists)
3
4# Because compiler-rt spends a lot of time setting up custom compile flags,
5# define a handy helper function for it. The compile flags setting in CMake
6# has serious issues that make its syntax challenging at best.
7function(set_target_compile_flags target)
8  set(argstring "")
9  foreach(arg ${ARGN})
10    set(argstring "${argstring} ${arg}")
11  endforeach()
12  set_property(TARGET ${target} PROPERTY COMPILE_FLAGS "${argstring}")
13endfunction()
14
15function(set_target_link_flags target)
16  set(argstring "")
17  foreach(arg ${ARGN})
18    set(argstring "${argstring} ${arg}")
19  endforeach()
20  set_property(TARGET ${target} PROPERTY LINK_FLAGS "${argstring}")
21endfunction()
22
23# Set the variable var_PYBOOL to True if var holds a true-ish string,
24# otherwise set it to False.
25macro(pythonize_bool var)
26  if (${var})
27    set(${var}_PYBOOL True)
28  else()
29    set(${var}_PYBOOL False)
30  endif()
31endmacro()
32
33# Appends value to all lists in ARGN, if the condition is true.
34macro(append_list_if condition value)
35  if(${condition})
36    foreach(list ${ARGN})
37      list(APPEND ${list} ${value})
38    endforeach()
39  endif()
40endmacro()
41
42# Appends value to all strings in ARGN, if the condition is true.
43macro(append_string_if condition value)
44  if(${condition})
45    foreach(str ${ARGN})
46      set(${str} "${${str}} ${value}")
47    endforeach()
48  endif()
49endmacro()
50
51macro(append_rtti_flag polarity list)
52  if(${polarity})
53    append_list_if(COMPILER_RT_HAS_FRTTI_FLAG -frtti ${list})
54    append_list_if(COMPILER_RT_HAS_GR_FLAG /GR ${list})
55  else()
56    append_list_if(COMPILER_RT_HAS_FNO_RTTI_FLAG -fno-rtti ${list})
57    append_list_if(COMPILER_RT_HAS_GR_FLAG /GR- ${list})
58  endif()
59endmacro()
60
61macro(append_have_file_definition filename varname list)
62  check_include_file("${filename}" "${varname}")
63  if (NOT ${varname})
64    set("${varname}" 0)
65  endif()
66  list(APPEND ${list} "${varname}=${${varname}}")
67endmacro()
68
69macro(list_intersect output input1 input2)
70  set(${output})
71  foreach(it ${${input1}})
72    list(FIND ${input2} ${it} index)
73    if( NOT (index EQUAL -1))
74      list(APPEND ${output} ${it})
75    endif()
76  endforeach()
77endmacro()
78
79function(list_replace input_list old new)
80  set(replaced_list)
81  foreach(item ${${input_list}})
82    if(${item} STREQUAL ${old})
83      list(APPEND replaced_list ${new})
84    else()
85      list(APPEND replaced_list ${item})
86    endif()
87  endforeach()
88  set(${input_list} "${replaced_list}" PARENT_SCOPE)
89endfunction()
90
91# Takes ${ARGN} and puts only supported architectures in @out_var list.
92function(filter_available_targets out_var)
93  set(archs ${${out_var}})
94  foreach(arch ${ARGN})
95    list(FIND COMPILER_RT_SUPPORTED_ARCH ${arch} ARCH_INDEX)
96    if(NOT (ARCH_INDEX EQUAL -1) AND CAN_TARGET_${arch})
97      list(APPEND archs ${arch})
98    endif()
99  endforeach()
100  set(${out_var} ${archs} PARENT_SCOPE)
101endfunction()
102
103# Add $arch as supported with no additional flags.
104macro(add_default_target_arch arch)
105  set(TARGET_${arch}_CFLAGS "")
106  set(CAN_TARGET_${arch} 1)
107  list(APPEND COMPILER_RT_SUPPORTED_ARCH ${arch})
108endmacro()
109
110function(check_compile_definition def argstring out_var)
111  if("${def}" STREQUAL "")
112    set(${out_var} TRUE PARENT_SCOPE)
113    return()
114  endif()
115  cmake_push_check_state()
116  set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} ${argstring}")
117  check_symbol_exists(${def} "" ${out_var})
118  cmake_pop_check_state()
119endfunction()
120
121# test_target_arch(<arch> <def> <target flags...>)
122# Checks if architecture is supported: runs host compiler with provided
123# flags to verify that:
124#   1) <def> is defined (if non-empty)
125#   2) simple file can be successfully built.
126# If successful, saves target flags for this architecture.
127macro(test_target_arch arch def)
128  set(TARGET_${arch}_CFLAGS ${ARGN})
129  set(TARGET_${arch}_LINK_FLAGS ${ARGN})
130  set(argstring "")
131  foreach(arg ${ARGN})
132    set(argstring "${argstring} ${arg}")
133  endforeach()
134  check_compile_definition("${def}" "${argstring}" HAS_${arch}_DEF)
135  if(NOT DEFINED CAN_TARGET_${arch})
136    if(NOT HAS_${arch}_DEF)
137      set(CAN_TARGET_${arch} FALSE)
138    elseif(TEST_COMPILE_ONLY)
139      try_compile_only(CAN_TARGET_${arch} ${TARGET_${arch}_CFLAGS})
140    else()
141      set(FLAG_NO_EXCEPTIONS "")
142      if(COMPILER_RT_HAS_FNO_EXCEPTIONS_FLAG)
143        set(FLAG_NO_EXCEPTIONS " -fno-exceptions ")
144      endif()
145      set(SAVED_CMAKE_EXE_LINKER_FLAGS ${CMAKE_EXE_LINKER_FLAGS})
146      set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${argstring}")
147      try_compile(CAN_TARGET_${arch} ${CMAKE_BINARY_DIR} ${SIMPLE_SOURCE}
148                  COMPILE_DEFINITIONS "${TARGET_${arch}_CFLAGS} ${FLAG_NO_EXCEPTIONS}"
149                  OUTPUT_VARIABLE TARGET_${arch}_OUTPUT)
150      set(CMAKE_EXE_LINKER_FLAGS ${SAVED_CMAKE_EXE_LINKER_FLAGS})
151    endif()
152  endif()
153  if(${CAN_TARGET_${arch}})
154    list(APPEND COMPILER_RT_SUPPORTED_ARCH ${arch})
155  elseif("${COMPILER_RT_DEFAULT_TARGET_ARCH}" STREQUAL "${arch}" AND
156         COMPILER_RT_HAS_EXPLICIT_DEFAULT_TARGET_TRIPLE)
157    # Bail out if we cannot target the architecture we plan to test.
158    message(FATAL_ERROR "Cannot compile for ${arch}:\n${TARGET_${arch}_OUTPUT}")
159  endif()
160endmacro()
161
162macro(detect_target_arch)
163  check_symbol_exists(__arm__ "" __ARM)
164  check_symbol_exists(__aarch64__ "" __AARCH64)
165  check_symbol_exists(__x86_64__ "" __X86_64)
166  check_symbol_exists(__i386__ "" __I386)
167  check_symbol_exists(__mips__ "" __MIPS)
168  check_symbol_exists(__mips64__ "" __MIPS64)
169  check_symbol_exists(__s390x__ "" __S390X)
170  check_symbol_exists(__wasm32__ "" __WEBASSEMBLY32)
171  check_symbol_exists(__wasm64__ "" __WEBASSEMBLY64)
172  if(__ARM)
173    add_default_target_arch(arm)
174  elseif(__AARCH64)
175    add_default_target_arch(aarch64)
176  elseif(__X86_64)
177    add_default_target_arch(x86_64)
178  elseif(__I386)
179    add_default_target_arch(i386)
180  elseif(__MIPS64) # must be checked before __MIPS
181    add_default_target_arch(mips64)
182  elseif(__MIPS)
183    add_default_target_arch(mips)
184  elseif(__S390X)
185    add_default_target_arch(s390x)
186  elseif(__WEBASSEMBLY32)
187    add_default_target_arch(wasm32)
188  elseif(__WEBASSEMBLY64)
189    add_default_target_arch(wasm64)
190  endif()
191endmacro()
192
193macro(load_llvm_config)
194  if (NOT LLVM_CONFIG_PATH)
195    find_program(LLVM_CONFIG_PATH "llvm-config"
196                 DOC "Path to llvm-config binary")
197    if (NOT LLVM_CONFIG_PATH)
198      message(FATAL_ERROR "llvm-config not found: specify LLVM_CONFIG_PATH")
199    endif()
200  endif()
201  execute_process(
202    COMMAND ${LLVM_CONFIG_PATH} "--obj-root" "--bindir" "--libdir" "--src-root"
203    RESULT_VARIABLE HAD_ERROR
204    OUTPUT_VARIABLE CONFIG_OUTPUT)
205  if (HAD_ERROR)
206    message(FATAL_ERROR "llvm-config failed with status ${HAD_ERROR}")
207  endif()
208  string(REGEX REPLACE "[ \t]*[\r\n]+[ \t]*" ";" CONFIG_OUTPUT ${CONFIG_OUTPUT})
209  list(GET CONFIG_OUTPUT 0 BINARY_DIR)
210  list(GET CONFIG_OUTPUT 1 TOOLS_BINARY_DIR)
211  list(GET CONFIG_OUTPUT 2 LIBRARY_DIR)
212  list(GET CONFIG_OUTPUT 3 MAIN_SRC_DIR)
213
214  set(LLVM_BINARY_DIR ${BINARY_DIR} CACHE PATH "Path to LLVM build tree")
215  set(LLVM_TOOLS_BINARY_DIR ${TOOLS_BINARY_DIR} CACHE PATH "Path to llvm/bin")
216  set(LLVM_LIBRARY_DIR ${LIBRARY_DIR} CACHE PATH "Path to llvm/lib")
217  set(LLVM_MAIN_SRC_DIR ${MAIN_SRC_DIR} CACHE PATH "Path to LLVM source tree")
218
219  # Make use of LLVM CMake modules.
220  # --cmakedir is supported since llvm r291218 (4.0 release)
221  execute_process(
222    COMMAND ${LLVM_CONFIG_PATH} --cmakedir
223    RESULT_VARIABLE HAD_ERROR
224    OUTPUT_VARIABLE CONFIG_OUTPUT)
225  if(NOT HAD_ERROR)
226    string(STRIP "${CONFIG_OUTPUT}" LLVM_CMAKE_PATH_FROM_LLVM_CONFIG)
227    file(TO_CMAKE_PATH ${LLVM_CMAKE_PATH_FROM_LLVM_CONFIG} LLVM_CMAKE_PATH)
228  else()
229    file(TO_CMAKE_PATH ${LLVM_BINARY_DIR} LLVM_BINARY_DIR_CMAKE_STYLE)
230    set(LLVM_CMAKE_PATH "${LLVM_BINARY_DIR_CMAKE_STYLE}/lib${LLVM_LIBDIR_SUFFIX}/cmake/llvm")
231  endif()
232
233  list(APPEND CMAKE_MODULE_PATH "${LLVM_CMAKE_PATH}")
234  # Get some LLVM variables from LLVMConfig.
235  include("${LLVM_CMAKE_PATH}/LLVMConfig.cmake")
236
237  set(LLVM_LIBRARY_OUTPUT_INTDIR
238    ${LLVM_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
239endmacro()
240
241macro(construct_compiler_rt_default_triple)
242  if(COMPILER_RT_DEFAULT_TARGET_ONLY)
243    if(DEFINED COMPILER_RT_DEFAULT_TARGET_TRIPLE)
244      message(FATAL_ERROR "COMPILER_RT_DEFAULT_TARGET_TRIPLE isn't supported when building for default target only")
245    endif()
246    set(COMPILER_RT_DEFAULT_TARGET_TRIPLE ${CMAKE_C_COMPILER_TARGET})
247  else()
248    set(COMPILER_RT_DEFAULT_TARGET_TRIPLE ${TARGET_TRIPLE} CACHE STRING
249          "Default triple for which compiler-rt runtimes will be built.")
250  endif()
251
252  if(DEFINED COMPILER_RT_TEST_TARGET_TRIPLE)
253    # Backwards compatibility: this variable used to be called
254    # COMPILER_RT_TEST_TARGET_TRIPLE.
255    set(COMPILER_RT_DEFAULT_TARGET_TRIPLE ${COMPILER_RT_TEST_TARGET_TRIPLE})
256  endif()
257
258  string(REPLACE "-" ";" TARGET_TRIPLE_LIST ${COMPILER_RT_DEFAULT_TARGET_TRIPLE})
259  list(GET TARGET_TRIPLE_LIST 0 COMPILER_RT_DEFAULT_TARGET_ARCH)
260  list(GET TARGET_TRIPLE_LIST 1 COMPILER_RT_DEFAULT_TARGET_OS)
261  list(LENGTH TARGET_TRIPLE_LIST TARGET_TRIPLE_LIST_LENGTH)
262  if(TARGET_TRIPLE_LIST_LENGTH GREATER 2)
263    list(GET TARGET_TRIPLE_LIST 2 COMPILER_RT_DEFAULT_TARGET_ABI)
264  endif()
265  # Determine if test target triple is specified explicitly, and doesn't match the
266  # default.
267  if(NOT COMPILER_RT_DEFAULT_TARGET_TRIPLE STREQUAL TARGET_TRIPLE)
268    set(COMPILER_RT_HAS_EXPLICIT_DEFAULT_TARGET_TRIPLE TRUE)
269  else()
270    set(COMPILER_RT_HAS_EXPLICIT_DEFAULT_TARGET_TRIPLE FALSE)
271  endif()
272endmacro()
273
274# Filter out generic versions of routines that are re-implemented in
275# architecture specific manner.  This prevents multiple definitions of the
276# same symbols, making the symbol selection non-deterministic.
277function(filter_builtin_sources output_var exclude_or_include excluded_list)
278  if(exclude_or_include STREQUAL "EXCLUDE")
279    set(filter_action GREATER)
280    set(filter_value -1)
281  elseif(exclude_or_include STREQUAL "INCLUDE")
282    set(filter_action LESS)
283    set(filter_value 0)
284  else()
285    message(FATAL_ERROR "filter_builtin_sources called without EXCLUDE|INCLUDE")
286  endif()
287
288  set(intermediate ${ARGN})
289  foreach (_file ${intermediate})
290    get_filename_component(_name_we ${_file} NAME_WE)
291    list(FIND ${excluded_list} ${_name_we} _found)
292    if(_found ${filter_action} ${filter_value})
293      list(REMOVE_ITEM intermediate ${_file})
294    elseif(${_file} MATCHES ".*/.*\\.S" OR ${_file} MATCHES ".*/.*\\.c")
295      get_filename_component(_name ${_file} NAME)
296      string(REPLACE ".S" ".c" _cname "${_name}")
297      list(REMOVE_ITEM intermediate ${_cname})
298    endif ()
299  endforeach ()
300  set(${output_var} ${intermediate} PARENT_SCOPE)
301endfunction()
302