1include(CMakePushCheckState)
2include(CheckSymbolExists)
3
4# Because compiler-rt spends a lot of time setting up custom compile flags,
5# define a handy helper function for it. The compile flags setting in CMake
6# has serious issues that make its syntax challenging at best.
7function(set_target_compile_flags target)
8  set(argstring "")
9  foreach(arg ${ARGN})
10    set(argstring "${argstring} ${arg}")
11  endforeach()
12  set_property(TARGET ${target} PROPERTY COMPILE_FLAGS "${argstring}")
13endfunction()
14
15function(set_target_link_flags target)
16  set(argstring "")
17  foreach(arg ${ARGN})
18    set(argstring "${argstring} ${arg}")
19  endforeach()
20  set_property(TARGET ${target} PROPERTY LINK_FLAGS "${argstring}")
21endfunction()
22
23# Set the variable var_PYBOOL to True if var holds a true-ish string,
24# otherwise set it to False.
25macro(pythonize_bool var)
26  if (${var})
27    set(${var}_PYBOOL True)
28  else()
29    set(${var}_PYBOOL False)
30  endif()
31endmacro()
32
33# Appends value to all lists in ARGN, if the condition is true.
34macro(append_list_if condition value)
35  if(${condition})
36    foreach(list ${ARGN})
37      list(APPEND ${list} ${value})
38    endforeach()
39  endif()
40endmacro()
41
42# Appends value to all strings in ARGN, if the condition is true.
43macro(append_string_if condition value)
44  if(${condition})
45    foreach(str ${ARGN})
46      set(${str} "${${str}} ${value}")
47    endforeach()
48  endif()
49endmacro()
50
51macro(append_rtti_flag polarity list)
52  if(${polarity})
53    append_list_if(COMPILER_RT_HAS_FRTTI_FLAG -frtti ${list})
54    append_list_if(COMPILER_RT_HAS_GR_FLAG /GR ${list})
55  else()
56    append_list_if(COMPILER_RT_HAS_FNO_RTTI_FLAG -fno-rtti ${list})
57    append_list_if(COMPILER_RT_HAS_GR_FLAG /GR- ${list})
58  endif()
59endmacro()
60
61macro(list_intersect output input1 input2)
62  set(${output})
63  foreach(it ${${input1}})
64    list(FIND ${input2} ${it} index)
65    if( NOT (index EQUAL -1))
66      list(APPEND ${output} ${it})
67    endif()
68  endforeach()
69endmacro()
70
71function(list_replace input_list old new)
72  set(replaced_list)
73  foreach(item ${${input_list}})
74    if(${item} STREQUAL ${old})
75      list(APPEND replaced_list ${new})
76    else()
77      list(APPEND replaced_list ${item})
78    endif()
79  endforeach()
80  set(${input_list} "${replaced_list}" PARENT_SCOPE)
81endfunction()
82
83# Takes ${ARGN} and puts only supported architectures in @out_var list.
84function(filter_available_targets out_var)
85  set(archs ${${out_var}})
86  foreach(arch ${ARGN})
87    list(FIND COMPILER_RT_SUPPORTED_ARCH ${arch} ARCH_INDEX)
88    if(NOT (ARCH_INDEX EQUAL -1) AND CAN_TARGET_${arch})
89      list(APPEND archs ${arch})
90    endif()
91  endforeach()
92  set(${out_var} ${archs} PARENT_SCOPE)
93endfunction()
94
95# Add $arch as supported with no additional flags.
96macro(add_default_target_arch arch)
97  set(TARGET_${arch}_CFLAGS "")
98  set(CAN_TARGET_${arch} 1)
99  list(APPEND COMPILER_RT_SUPPORTED_ARCH ${arch})
100endmacro()
101
102function(check_compile_definition def argstring out_var)
103  if("${def}" STREQUAL "")
104    set(${out_var} TRUE PARENT_SCOPE)
105    return()
106  endif()
107  cmake_push_check_state()
108  set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} ${argstring}")
109  check_symbol_exists(${def} "" ${out_var})
110  cmake_pop_check_state()
111endfunction()
112
113# test_target_arch(<arch> <def> <target flags...>)
114# Checks if architecture is supported: runs host compiler with provided
115# flags to verify that:
116#   1) <def> is defined (if non-empty)
117#   2) simple file can be successfully built.
118# If successful, saves target flags for this architecture.
119macro(test_target_arch arch def)
120  set(TARGET_${arch}_CFLAGS ${ARGN})
121  set(TARGET_${arch}_LINK_FLAGS ${ARGN})
122  set(argstring "")
123  foreach(arg ${ARGN})
124    set(argstring "${argstring} ${arg}")
125  endforeach()
126  check_compile_definition("${def}" "${argstring}" HAS_${arch}_DEF)
127  if(NOT DEFINED CAN_TARGET_${arch})
128    if(NOT HAS_${arch}_DEF)
129      set(CAN_TARGET_${arch} FALSE)
130    elseif(TEST_COMPILE_ONLY)
131      try_compile_only(CAN_TARGET_${arch} ${TARGET_${arch}_CFLAGS})
132    else()
133      set(FLAG_NO_EXCEPTIONS "")
134      if(COMPILER_RT_HAS_FNO_EXCEPTIONS_FLAG)
135        set(FLAG_NO_EXCEPTIONS " -fno-exceptions ")
136      endif()
137      set(SAVED_CMAKE_EXE_LINKER_FLAGS ${CMAKE_EXE_LINKER_FLAGS})
138      set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${argstring}")
139      try_compile(CAN_TARGET_${arch} ${CMAKE_BINARY_DIR} ${SIMPLE_SOURCE}
140                  COMPILE_DEFINITIONS "${TARGET_${arch}_CFLAGS} ${FLAG_NO_EXCEPTIONS}"
141                  OUTPUT_VARIABLE TARGET_${arch}_OUTPUT)
142      set(CMAKE_EXE_LINKER_FLAGS ${SAVED_CMAKE_EXE_LINKER_FLAGS})
143    endif()
144  endif()
145  if(${CAN_TARGET_${arch}})
146    list(APPEND COMPILER_RT_SUPPORTED_ARCH ${arch})
147  elseif("${COMPILER_RT_DEFAULT_TARGET_ARCH}" STREQUAL "${arch}" AND
148         COMPILER_RT_HAS_EXPLICIT_DEFAULT_TARGET_TRIPLE)
149    # Bail out if we cannot target the architecture we plan to test.
150    message(FATAL_ERROR "Cannot compile for ${arch}:\n${TARGET_${arch}_OUTPUT}")
151  endif()
152endmacro()
153
154macro(detect_target_arch)
155  check_symbol_exists(__arm__ "" __ARM)
156  check_symbol_exists(__aarch64__ "" __AARCH64)
157  check_symbol_exists(__x86_64__ "" __X86_64)
158  check_symbol_exists(__i386__ "" __I386)
159  check_symbol_exists(__mips__ "" __MIPS)
160  check_symbol_exists(__mips64__ "" __MIPS64)
161  check_symbol_exists(__powerpc64__ "" __PPC64)
162  check_symbol_exists(__powerpc64le__ "" __PPC64LE)
163  check_symbol_exists(__riscv "" __RISCV)
164  check_symbol_exists(__s390x__ "" __S390X)
165  check_symbol_exists(__wasm32__ "" __WEBASSEMBLY32)
166  check_symbol_exists(__wasm64__ "" __WEBASSEMBLY64)
167  if(__ARM)
168    add_default_target_arch(arm)
169  elseif(__AARCH64)
170    add_default_target_arch(aarch64)
171  elseif(__X86_64)
172    add_default_target_arch(x86_64)
173  elseif(__I386)
174    add_default_target_arch(i386)
175  elseif(__MIPS64) # must be checked before __MIPS
176    add_default_target_arch(mips64)
177  elseif(__MIPS)
178    add_default_target_arch(mips)
179  elseif(__PPC64)
180    add_default_target_arch(powerpc64)
181  elseif(__PPC64LE)
182    add_default_target_arch(powerpc64le)
183  elseif(__RISCV)
184    if(CMAKE_SIZEOF_VOID_P EQUAL "4")
185      add_default_target_arch(riscv32)
186    elseif(CMAKE_SIZEOF_VOID_P EQUAL "8")
187      add_default_target_arch(riscv64)
188    else()
189      message(FATAL_ERROR "Unsupport XLEN for RISC-V")
190    endif()
191  elseif(__S390X)
192    add_default_target_arch(s390x)
193  elseif(__WEBASSEMBLY32)
194    add_default_target_arch(wasm32)
195  elseif(__WEBASSEMBLY64)
196    add_default_target_arch(wasm64)
197  endif()
198endmacro()
199
200macro(load_llvm_config)
201  if (NOT LLVM_CONFIG_PATH)
202    find_program(LLVM_CONFIG_PATH "llvm-config"
203                 DOC "Path to llvm-config binary")
204    if (NOT LLVM_CONFIG_PATH)
205      message(WARNING "UNSUPPORTED COMPILER-RT CONFIGURATION DETECTED: "
206                      "llvm-config not found.\n"
207                      "Reconfigure with -DLLVM_CONFIG_PATH=path/to/llvm-config.")
208    endif()
209  endif()
210  if (LLVM_CONFIG_PATH)
211    execute_process(
212      COMMAND ${LLVM_CONFIG_PATH} "--obj-root" "--bindir" "--libdir" "--src-root" "--includedir"
213      RESULT_VARIABLE HAD_ERROR
214      OUTPUT_VARIABLE CONFIG_OUTPUT)
215    if (HAD_ERROR)
216      message(FATAL_ERROR "llvm-config failed with status ${HAD_ERROR}")
217    endif()
218    string(REGEX REPLACE "[ \t]*[\r\n]+[ \t]*" ";" CONFIG_OUTPUT ${CONFIG_OUTPUT})
219    list(GET CONFIG_OUTPUT 0 BINARY_DIR)
220    list(GET CONFIG_OUTPUT 1 TOOLS_BINARY_DIR)
221    list(GET CONFIG_OUTPUT 2 LIBRARY_DIR)
222    list(GET CONFIG_OUTPUT 3 MAIN_SRC_DIR)
223    list(GET CONFIG_OUTPUT 4 INCLUDE_DIR)
224
225    set(LLVM_BINARY_DIR ${BINARY_DIR} CACHE PATH "Path to LLVM build tree")
226    set(LLVM_LIBRARY_DIR ${LIBRARY_DIR} CACHE PATH "Path to llvm/lib")
227    set(LLVM_MAIN_SRC_DIR ${MAIN_SRC_DIR} CACHE PATH "Path to LLVM source tree")
228    set(LLVM_TOOLS_BINARY_DIR ${TOOLS_BINARY_DIR} CACHE PATH "Path to llvm/bin")
229    set(LLVM_INCLUDE_DIR ${INCLUDE_DIR} CACHE PATH "Paths to LLVM headers")
230
231    # Detect if we have the LLVMXRay and TestingSupport library installed and
232    # available from llvm-config.
233    execute_process(
234      COMMAND ${LLVM_CONFIG_PATH} "--ldflags" "--libs" "xray"
235      RESULT_VARIABLE HAD_ERROR
236      OUTPUT_VARIABLE CONFIG_OUTPUT
237      ERROR_QUIET)
238    if (HAD_ERROR)
239      message(WARNING "llvm-config finding xray failed with status ${HAD_ERROR}")
240      set(COMPILER_RT_HAS_LLVMXRAY FALSE)
241    else()
242      string(REGEX REPLACE "[ \t]*[\r\n]+[ \t]*" ";" CONFIG_OUTPUT ${CONFIG_OUTPUT})
243      list(GET CONFIG_OUTPUT 0 LDFLAGS)
244      list(GET CONFIG_OUTPUT 1 LIBLIST)
245      set(LLVM_XRAY_LDFLAGS ${LDFLAGS} CACHE STRING "Linker flags for LLVMXRay library")
246      set(LLVM_XRAY_LIBLIST ${LIBLIST} CACHE STRING "Library list for LLVMXRay")
247      set(COMPILER_RT_HAS_LLVMXRAY TRUE)
248    endif()
249
250    set(COMPILER_RT_HAS_LLVMTESTINGSUPPORT FALSE)
251    execute_process(
252      COMMAND ${LLVM_CONFIG_PATH} "--ldflags" "--libs" "testingsupport"
253      RESULT_VARIABLE HAD_ERROR
254      OUTPUT_VARIABLE CONFIG_OUTPUT
255      ERROR_QUIET)
256    if (HAD_ERROR)
257      message(WARNING "llvm-config finding testingsupport failed with status ${HAD_ERROR}")
258    else()
259      string(REGEX REPLACE "[ \t]*[\r\n]+[ \t]*" ";" CONFIG_OUTPUT ${CONFIG_OUTPUT})
260      list(GET CONFIG_OUTPUT 0 LDFLAGS)
261      list(GET CONFIG_OUTPUT 1 LIBLIST)
262      if (LIBLIST STREQUAL "")
263        message(WARNING "testingsupport library not installed, some tests will be skipped")
264      else()
265        set(LLVM_TESTINGSUPPORT_LDFLAGS ${LDFLAGS} CACHE STRING "Linker flags for LLVMTestingSupport library")
266        set(LLVM_TESTINGSUPPORT_LIBLIST ${LIBLIST} CACHE STRING "Library list for LLVMTestingSupport")
267        set(COMPILER_RT_HAS_LLVMTESTINGSUPPORT TRUE)
268      endif()
269    endif()
270
271    # Make use of LLVM CMake modules.
272    # --cmakedir is supported since llvm r291218 (4.0 release)
273    execute_process(
274      COMMAND ${LLVM_CONFIG_PATH} --cmakedir
275      RESULT_VARIABLE HAD_ERROR
276      OUTPUT_VARIABLE CONFIG_OUTPUT)
277    if(NOT HAD_ERROR)
278      string(STRIP "${CONFIG_OUTPUT}" LLVM_CMAKE_PATH_FROM_LLVM_CONFIG)
279      file(TO_CMAKE_PATH ${LLVM_CMAKE_PATH_FROM_LLVM_CONFIG} LLVM_CMAKE_PATH)
280    else()
281      file(TO_CMAKE_PATH ${LLVM_BINARY_DIR} LLVM_BINARY_DIR_CMAKE_STYLE)
282      set(LLVM_CMAKE_PATH "${LLVM_BINARY_DIR_CMAKE_STYLE}/lib${LLVM_LIBDIR_SUFFIX}/cmake/llvm")
283    endif()
284
285    list(APPEND CMAKE_MODULE_PATH "${LLVM_CMAKE_PATH}")
286    # Get some LLVM variables from LLVMConfig.
287    include("${LLVM_CMAKE_PATH}/LLVMConfig.cmake")
288
289    set(LLVM_LIBRARY_OUTPUT_INTDIR
290      ${LLVM_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
291  endif()
292endmacro()
293
294macro(construct_compiler_rt_default_triple)
295  if(COMPILER_RT_DEFAULT_TARGET_ONLY)
296    if(DEFINED COMPILER_RT_DEFAULT_TARGET_TRIPLE)
297      message(FATAL_ERROR "COMPILER_RT_DEFAULT_TARGET_TRIPLE isn't supported when building for default target only")
298    endif()
299    set(COMPILER_RT_DEFAULT_TARGET_TRIPLE ${CMAKE_C_COMPILER_TARGET})
300  else()
301    set(COMPILER_RT_DEFAULT_TARGET_TRIPLE ${TARGET_TRIPLE} CACHE STRING
302          "Default triple for which compiler-rt runtimes will be built.")
303  endif()
304
305  if(DEFINED COMPILER_RT_TEST_TARGET_TRIPLE)
306    # Backwards compatibility: this variable used to be called
307    # COMPILER_RT_TEST_TARGET_TRIPLE.
308    set(COMPILER_RT_DEFAULT_TARGET_TRIPLE ${COMPILER_RT_TEST_TARGET_TRIPLE})
309  endif()
310
311  string(REPLACE "-" ";" TARGET_TRIPLE_LIST ${COMPILER_RT_DEFAULT_TARGET_TRIPLE})
312  list(GET TARGET_TRIPLE_LIST 0 COMPILER_RT_DEFAULT_TARGET_ARCH)
313  # Determine if test target triple is specified explicitly, and doesn't match the
314  # default.
315  if(NOT COMPILER_RT_DEFAULT_TARGET_TRIPLE STREQUAL TARGET_TRIPLE)
316    set(COMPILER_RT_HAS_EXPLICIT_DEFAULT_TARGET_TRIPLE TRUE)
317  else()
318    set(COMPILER_RT_HAS_EXPLICIT_DEFAULT_TARGET_TRIPLE FALSE)
319  endif()
320endmacro()
321
322# Filter out generic versions of routines that are re-implemented in
323# architecture specific manner.  This prevents multiple definitions of the
324# same symbols, making the symbol selection non-deterministic.
325function(filter_builtin_sources output_var exclude_or_include excluded_list)
326  if(exclude_or_include STREQUAL "EXCLUDE")
327    set(filter_action GREATER)
328    set(filter_value -1)
329  elseif(exclude_or_include STREQUAL "INCLUDE")
330    set(filter_action LESS)
331    set(filter_value 0)
332  else()
333    message(FATAL_ERROR "filter_builtin_sources called without EXCLUDE|INCLUDE")
334  endif()
335
336  set(intermediate ${ARGN})
337  foreach (_file ${intermediate})
338    get_filename_component(_name_we ${_file} NAME_WE)
339    list(FIND ${excluded_list} ${_name_we} _found)
340    if(_found ${filter_action} ${filter_value})
341      list(REMOVE_ITEM intermediate ${_file})
342    elseif(${_file} MATCHES ".*/.*\\.S" OR ${_file} MATCHES ".*/.*\\.c")
343      get_filename_component(_name ${_file} NAME)
344      string(REPLACE ".S" ".c" _cname "${_name}")
345      list(REMOVE_ITEM intermediate ${_cname})
346    endif ()
347  endforeach ()
348  set(${output_var} ${intermediate} PARENT_SCOPE)
349endfunction()
350
351function(get_compiler_rt_target arch variable)
352  string(FIND ${COMPILER_RT_DEFAULT_TARGET_TRIPLE} "-" dash_index)
353  string(SUBSTRING ${COMPILER_RT_DEFAULT_TARGET_TRIPLE} ${dash_index} -1 triple_suffix)
354  if(COMPILER_RT_DEFAULT_TARGET_ONLY)
355    # Use exact spelling when building only for the target specified to CMake.
356    set(target "${COMPILER_RT_DEFAULT_TARGET_TRIPLE}")
357  elseif(ANDROID AND ${arch} STREQUAL "i386")
358    set(target "i686${COMPILER_RT_OS_SUFFIX}${triple_suffix}")
359  else()
360    set(target "${arch}${triple_suffix}")
361  endif()
362  set(${variable} ${target} PARENT_SCOPE)
363endfunction()
364
365function(get_compiler_rt_install_dir arch install_dir)
366  if(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR AND NOT APPLE)
367    get_compiler_rt_target(${arch} target)
368    set(${install_dir} ${COMPILER_RT_INSTALL_PATH}/${target}/lib PARENT_SCOPE)
369  else()
370    set(${install_dir} ${COMPILER_RT_LIBRARY_INSTALL_DIR} PARENT_SCOPE)
371  endif()
372endfunction()
373
374function(get_compiler_rt_output_dir arch output_dir)
375  if(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR AND NOT APPLE)
376    get_compiler_rt_target(${arch} target)
377    set(${output_dir} ${COMPILER_RT_OUTPUT_DIR}/${target}/lib PARENT_SCOPE)
378  else()
379    set(${output_dir} ${COMPILER_RT_LIBRARY_OUTPUT_DIR} PARENT_SCOPE)
380  endif()
381endfunction()
382
383# compiler_rt_process_sources(
384#   <OUTPUT_VAR>
385#   <SOURCE_FILE> ...
386#  [ADDITIONAL_HEADERS <header> ...]
387# )
388#
389# Process the provided sources and write the list of new sources
390# into `<OUTPUT_VAR>`.
391#
392# ADDITIONAL_HEADERS     - Adds the supplied header to list of sources for IDEs.
393#
394# This function is very similar to `llvm_process_sources()` but exists here
395# because we need to support standalone builds of compiler-rt.
396function(compiler_rt_process_sources OUTPUT_VAR)
397  cmake_parse_arguments(
398    ARG
399    ""
400    ""
401    "ADDITIONAL_HEADERS"
402    ${ARGN}
403  )
404  set(sources ${ARG_UNPARSED_ARGUMENTS})
405  set(headers "")
406  if (XCODE OR MSVC_IDE OR CMAKE_EXTRA_GENERATOR)
407    # For IDEs we need to tell CMake about header files.
408    # Otherwise they won't show up in UI.
409    set(headers ${ARG_ADDITIONAL_HEADERS})
410    list(LENGTH headers headers_length)
411    if (${headers_length} GREATER 0)
412      set_source_files_properties(${headers}
413        PROPERTIES HEADER_FILE_ONLY ON)
414    endif()
415  endif()
416  set("${OUTPUT_VAR}" ${sources} ${headers} PARENT_SCOPE)
417endfunction()
418