1include(CMakePushCheckState)
2include(CheckSymbolExists)
3
4# Because compiler-rt spends a lot of time setting up custom compile flags,
5# define a handy helper function for it. The compile flags setting in CMake
6# has serious issues that make its syntax challenging at best.
7function(set_target_compile_flags target)
8  set(argstring "")
9  foreach(arg ${ARGN})
10    set(argstring "${argstring} ${arg}")
11  endforeach()
12  set_property(TARGET ${target} PROPERTY COMPILE_FLAGS "${argstring}")
13endfunction()
14
15function(set_target_link_flags target)
16  set(argstring "")
17  foreach(arg ${ARGN})
18    set(argstring "${argstring} ${arg}")
19  endforeach()
20  set_property(TARGET ${target} PROPERTY LINK_FLAGS "${argstring}")
21endfunction()
22
23# Set the variable var_PYBOOL to True if var holds a true-ish string,
24# otherwise set it to False.
25macro(pythonize_bool var)
26  if (${var})
27    set(${var}_PYBOOL True)
28  else()
29    set(${var}_PYBOOL False)
30  endif()
31endmacro()
32
33# Appends value to all lists in ARGN, if the condition is true.
34macro(append_list_if condition value)
35  if(${condition})
36    foreach(list ${ARGN})
37      list(APPEND ${list} ${value})
38    endforeach()
39  endif()
40endmacro()
41
42# Appends value to all strings in ARGN, if the condition is true.
43macro(append_string_if condition value)
44  if(${condition})
45    foreach(str ${ARGN})
46      set(${str} "${${str}} ${value}")
47    endforeach()
48  endif()
49endmacro()
50
51macro(append_rtti_flag polarity list)
52  if(${polarity})
53    append_list_if(COMPILER_RT_HAS_FRTTI_FLAG -frtti ${list})
54    append_list_if(COMPILER_RT_HAS_GR_FLAG /GR ${list})
55  else()
56    append_list_if(COMPILER_RT_HAS_FNO_RTTI_FLAG -fno-rtti ${list})
57    append_list_if(COMPILER_RT_HAS_GR_FLAG /GR- ${list})
58  endif()
59endmacro()
60
61macro(list_intersect output input1 input2)
62  set(${output})
63  foreach(it ${${input1}})
64    list(FIND ${input2} ${it} index)
65    if( NOT (index EQUAL -1))
66      list(APPEND ${output} ${it})
67    endif()
68  endforeach()
69endmacro()
70
71function(list_replace input_list old new)
72  set(replaced_list)
73  foreach(item ${${input_list}})
74    if(${item} STREQUAL ${old})
75      list(APPEND replaced_list ${new})
76    else()
77      list(APPEND replaced_list ${item})
78    endif()
79  endforeach()
80  set(${input_list} "${replaced_list}" PARENT_SCOPE)
81endfunction()
82
83# Takes ${ARGN} and puts only supported architectures in @out_var list.
84function(filter_available_targets out_var)
85  set(archs ${${out_var}})
86  foreach(arch ${ARGN})
87    list(FIND COMPILER_RT_SUPPORTED_ARCH ${arch} ARCH_INDEX)
88    if(NOT (ARCH_INDEX EQUAL -1) AND CAN_TARGET_${arch})
89      list(APPEND archs ${arch})
90    endif()
91  endforeach()
92  set(${out_var} ${archs} PARENT_SCOPE)
93endfunction()
94
95# Add $arch as supported with no additional flags.
96macro(add_default_target_arch arch)
97  set(TARGET_${arch}_CFLAGS "")
98  set(CAN_TARGET_${arch} 1)
99  list(APPEND COMPILER_RT_SUPPORTED_ARCH ${arch})
100endmacro()
101
102function(check_compile_definition def argstring out_var)
103  if("${def}" STREQUAL "")
104    set(${out_var} TRUE PARENT_SCOPE)
105    return()
106  endif()
107  cmake_push_check_state()
108  set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} ${argstring}")
109  check_symbol_exists(${def} "" ${out_var})
110  cmake_pop_check_state()
111endfunction()
112
113# test_target_arch(<arch> <def> <target flags...>)
114# Checks if architecture is supported: runs host compiler with provided
115# flags to verify that:
116#   1) <def> is defined (if non-empty)
117#   2) simple file can be successfully built.
118# If successful, saves target flags for this architecture.
119macro(test_target_arch arch def)
120  set(TARGET_${arch}_CFLAGS ${ARGN})
121  set(TARGET_${arch}_LINK_FLAGS ${ARGN})
122  set(argstring "")
123  foreach(arg ${ARGN})
124    set(argstring "${argstring} ${arg}")
125  endforeach()
126  check_compile_definition("${def}" "${argstring}" HAS_${arch}_DEF)
127  if(NOT DEFINED CAN_TARGET_${arch})
128    if(NOT HAS_${arch}_DEF)
129      set(CAN_TARGET_${arch} FALSE)
130    elseif(TEST_COMPILE_ONLY)
131      try_compile_only(CAN_TARGET_${arch} FLAGS ${TARGET_${arch}_CFLAGS})
132    else()
133      set(FLAG_NO_EXCEPTIONS "")
134      if(COMPILER_RT_HAS_FNO_EXCEPTIONS_FLAG)
135        set(FLAG_NO_EXCEPTIONS " -fno-exceptions ")
136      endif()
137      set(SAVED_CMAKE_EXE_LINKER_FLAGS ${CMAKE_EXE_LINKER_FLAGS})
138      set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${argstring}")
139      try_compile(CAN_TARGET_${arch} ${CMAKE_BINARY_DIR} ${SIMPLE_SOURCE}
140                  COMPILE_DEFINITIONS "${TARGET_${arch}_CFLAGS} ${FLAG_NO_EXCEPTIONS}"
141                  OUTPUT_VARIABLE TARGET_${arch}_OUTPUT)
142      set(CMAKE_EXE_LINKER_FLAGS ${SAVED_CMAKE_EXE_LINKER_FLAGS})
143    endif()
144  endif()
145  if(${CAN_TARGET_${arch}})
146    list(APPEND COMPILER_RT_SUPPORTED_ARCH ${arch})
147  elseif("${COMPILER_RT_DEFAULT_TARGET_ARCH}" STREQUAL "${arch}" AND
148         COMPILER_RT_HAS_EXPLICIT_DEFAULT_TARGET_TRIPLE)
149    # Bail out if we cannot target the architecture we plan to test.
150    message(FATAL_ERROR "Cannot compile for ${arch}:\n${TARGET_${arch}_OUTPUT}")
151  endif()
152endmacro()
153
154macro(load_llvm_config)
155  if (NOT LLVM_CONFIG_PATH)
156    find_program(LLVM_CONFIG_PATH "llvm-config"
157                 DOC "Path to llvm-config binary")
158    if (NOT LLVM_CONFIG_PATH)
159      message(WARNING "UNSUPPORTED COMPILER-RT CONFIGURATION DETECTED: "
160                      "llvm-config not found.\n"
161                      "Reconfigure with -DLLVM_CONFIG_PATH=path/to/llvm-config.")
162    endif()
163  endif()
164  if (LLVM_CONFIG_PATH)
165    execute_process(
166      COMMAND ${LLVM_CONFIG_PATH} "--obj-root" "--bindir" "--libdir" "--src-root" "--includedir"
167      RESULT_VARIABLE HAD_ERROR
168      OUTPUT_VARIABLE CONFIG_OUTPUT)
169    if (HAD_ERROR)
170      message(FATAL_ERROR "llvm-config failed with status ${HAD_ERROR}")
171    endif()
172    string(REGEX REPLACE "[ \t]*[\r\n]+[ \t]*" ";" CONFIG_OUTPUT ${CONFIG_OUTPUT})
173    list(GET CONFIG_OUTPUT 0 BINARY_DIR)
174    list(GET CONFIG_OUTPUT 1 TOOLS_BINARY_DIR)
175    list(GET CONFIG_OUTPUT 2 LIBRARY_DIR)
176    list(GET CONFIG_OUTPUT 3 MAIN_SRC_DIR)
177    list(GET CONFIG_OUTPUT 4 INCLUDE_DIR)
178
179    set(LLVM_BINARY_DIR ${BINARY_DIR} CACHE PATH "Path to LLVM build tree")
180    set(LLVM_LIBRARY_DIR ${LIBRARY_DIR} CACHE PATH "Path to llvm/lib")
181    set(LLVM_MAIN_SRC_DIR ${MAIN_SRC_DIR} CACHE PATH "Path to LLVM source tree")
182    set(LLVM_TOOLS_BINARY_DIR ${TOOLS_BINARY_DIR} CACHE PATH "Path to llvm/bin")
183    set(LLVM_INCLUDE_DIR ${INCLUDE_DIR} CACHE PATH "Paths to LLVM headers")
184
185    # Detect if we have the LLVMXRay and TestingSupport library installed and
186    # available from llvm-config.
187    execute_process(
188      COMMAND ${LLVM_CONFIG_PATH} "--ldflags" "--libs" "xray"
189      RESULT_VARIABLE HAD_ERROR
190      OUTPUT_VARIABLE CONFIG_OUTPUT
191      ERROR_QUIET)
192    if (HAD_ERROR)
193      message(WARNING "llvm-config finding xray failed with status ${HAD_ERROR}")
194      set(COMPILER_RT_HAS_LLVMXRAY FALSE)
195    else()
196      string(REGEX REPLACE "[ \t]*[\r\n]+[ \t]*" ";" CONFIG_OUTPUT ${CONFIG_OUTPUT})
197      list(GET CONFIG_OUTPUT 0 LDFLAGS)
198      list(GET CONFIG_OUTPUT 1 LIBLIST)
199      file(TO_CMAKE_PATH "${LDFLAGS}" LDFLAGS)
200      file(TO_CMAKE_PATH "${LIBLIST}" LIBLIST)
201      set(LLVM_XRAY_LDFLAGS ${LDFLAGS} CACHE STRING "Linker flags for LLVMXRay library")
202      set(LLVM_XRAY_LIBLIST ${LIBLIST} CACHE STRING "Library list for LLVMXRay")
203      set(COMPILER_RT_HAS_LLVMXRAY TRUE)
204    endif()
205
206    set(COMPILER_RT_HAS_LLVMTESTINGSUPPORT FALSE)
207    execute_process(
208      COMMAND ${LLVM_CONFIG_PATH} "--ldflags" "--libs" "testingsupport"
209      RESULT_VARIABLE HAD_ERROR
210      OUTPUT_VARIABLE CONFIG_OUTPUT
211      ERROR_QUIET)
212    if (HAD_ERROR)
213      message(WARNING "llvm-config finding testingsupport failed with status ${HAD_ERROR}")
214    elseif(COMPILER_RT_INCLUDE_TESTS)
215      string(REGEX REPLACE "[ \t]*[\r\n]+[ \t]*" ";" CONFIG_OUTPUT ${CONFIG_OUTPUT})
216      list(GET CONFIG_OUTPUT 0 LDFLAGS)
217      list(GET CONFIG_OUTPUT 1 LIBLIST)
218      if (LIBLIST STREQUAL "")
219        message(WARNING "testingsupport library not installed, some tests will be skipped")
220      else()
221        file(TO_CMAKE_PATH "${LDFLAGS}" LDFLAGS)
222        file(TO_CMAKE_PATH "${LIBLIST}" LIBLIST)
223        set(LLVM_TESTINGSUPPORT_LDFLAGS ${LDFLAGS} CACHE STRING "Linker flags for LLVMTestingSupport library")
224        set(LLVM_TESTINGSUPPORT_LIBLIST ${LIBLIST} CACHE STRING "Library list for LLVMTestingSupport")
225        set(COMPILER_RT_HAS_LLVMTESTINGSUPPORT TRUE)
226      endif()
227    endif()
228
229    # Make use of LLVM CMake modules.
230    # --cmakedir is supported since llvm r291218 (4.0 release)
231    execute_process(
232      COMMAND ${LLVM_CONFIG_PATH} --cmakedir
233      RESULT_VARIABLE HAD_ERROR
234      OUTPUT_VARIABLE CONFIG_OUTPUT)
235    if(NOT HAD_ERROR)
236      string(STRIP "${CONFIG_OUTPUT}" LLVM_CMAKE_PATH_FROM_LLVM_CONFIG)
237      file(TO_CMAKE_PATH ${LLVM_CMAKE_PATH_FROM_LLVM_CONFIG} LLVM_CMAKE_PATH)
238    else()
239      file(TO_CMAKE_PATH ${LLVM_BINARY_DIR} LLVM_BINARY_DIR_CMAKE_STYLE)
240      set(LLVM_CMAKE_PATH "${LLVM_BINARY_DIR_CMAKE_STYLE}/lib${LLVM_LIBDIR_SUFFIX}/cmake/llvm")
241    endif()
242
243    list(APPEND CMAKE_MODULE_PATH "${LLVM_CMAKE_PATH}")
244    # Get some LLVM variables from LLVMConfig.
245    include("${LLVM_CMAKE_PATH}/LLVMConfig.cmake")
246
247    set(LLVM_LIBRARY_OUTPUT_INTDIR
248      ${LLVM_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
249  endif()
250endmacro()
251
252macro(construct_compiler_rt_default_triple)
253  if(COMPILER_RT_DEFAULT_TARGET_ONLY)
254    if(DEFINED COMPILER_RT_DEFAULT_TARGET_TRIPLE)
255      message(FATAL_ERROR "COMPILER_RT_DEFAULT_TARGET_TRIPLE isn't supported when building for default target only")
256    endif()
257    set(COMPILER_RT_DEFAULT_TARGET_TRIPLE ${CMAKE_C_COMPILER_TARGET})
258  else()
259    set(COMPILER_RT_DEFAULT_TARGET_TRIPLE ${TARGET_TRIPLE} CACHE STRING
260          "Default triple for which compiler-rt runtimes will be built.")
261  endif()
262
263  if(DEFINED COMPILER_RT_TEST_TARGET_TRIPLE)
264    # Backwards compatibility: this variable used to be called
265    # COMPILER_RT_TEST_TARGET_TRIPLE.
266    set(COMPILER_RT_DEFAULT_TARGET_TRIPLE ${COMPILER_RT_TEST_TARGET_TRIPLE})
267  endif()
268
269  string(REPLACE "-" ";" TARGET_TRIPLE_LIST ${COMPILER_RT_DEFAULT_TARGET_TRIPLE})
270  list(GET TARGET_TRIPLE_LIST 0 COMPILER_RT_DEFAULT_TARGET_ARCH)
271  # Determine if test target triple is specified explicitly, and doesn't match the
272  # default.
273  if(NOT COMPILER_RT_DEFAULT_TARGET_TRIPLE STREQUAL TARGET_TRIPLE)
274    set(COMPILER_RT_HAS_EXPLICIT_DEFAULT_TARGET_TRIPLE TRUE)
275  else()
276    set(COMPILER_RT_HAS_EXPLICIT_DEFAULT_TARGET_TRIPLE FALSE)
277  endif()
278endmacro()
279
280# Filter out generic versions of routines that are re-implemented in an
281# architecture specific manner. This prevents multiple definitions of the same
282# symbols, making the symbol selection non-deterministic.
283#
284# We follow the convention that a source file that exists in a sub-directory
285# (e.g. `ppc/divtc3.c`) is architecture-specific and that if a generic
286# implementation exists it will be a top-level source file with the same name
287# modulo the file extension (e.g. `divtc3.c`).
288function(filter_builtin_sources inout_var name)
289  set(intermediate ${${inout_var}})
290  foreach(_file ${intermediate})
291    get_filename_component(_file_dir ${_file} DIRECTORY)
292    if (NOT "${_file_dir}" STREQUAL "")
293      # Architecture specific file. If a generic version exists, print a notice
294      # and ensure that it is removed from the file list.
295      get_filename_component(_name ${_file} NAME)
296      string(REGEX REPLACE "\\.S$" ".c" _cname "${_name}")
297      if(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/${_cname}")
298        message(STATUS "For ${name} builtins preferring ${_file} to ${_cname}")
299        list(REMOVE_ITEM intermediate ${_cname})
300      endif()
301    endif()
302  endforeach()
303  set(${inout_var} ${intermediate} PARENT_SCOPE)
304endfunction()
305
306function(get_compiler_rt_target arch variable)
307  string(FIND ${COMPILER_RT_DEFAULT_TARGET_TRIPLE} "-" dash_index)
308  string(SUBSTRING ${COMPILER_RT_DEFAULT_TARGET_TRIPLE} ${dash_index} -1 triple_suffix)
309  if(COMPILER_RT_DEFAULT_TARGET_ONLY)
310    # Use exact spelling when building only for the target specified to CMake.
311    set(target "${COMPILER_RT_DEFAULT_TARGET_TRIPLE}")
312  elseif(ANDROID AND ${arch} STREQUAL "i386")
313    set(target "i686${triple_suffix}")
314  else()
315    set(target "${arch}${triple_suffix}")
316  endif()
317  set(${variable} ${target} PARENT_SCOPE)
318endfunction()
319
320function(get_compiler_rt_install_dir arch install_dir)
321  if(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR AND NOT APPLE)
322    get_compiler_rt_target(${arch} target)
323    set(${install_dir} ${COMPILER_RT_INSTALL_PATH}/lib/${target} PARENT_SCOPE)
324  else()
325    set(${install_dir} ${COMPILER_RT_LIBRARY_INSTALL_DIR} PARENT_SCOPE)
326  endif()
327endfunction()
328
329function(get_compiler_rt_output_dir arch output_dir)
330  if(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR AND NOT APPLE)
331    get_compiler_rt_target(${arch} target)
332    set(${output_dir} ${COMPILER_RT_OUTPUT_DIR}/lib/${target} PARENT_SCOPE)
333  else()
334    set(${output_dir} ${COMPILER_RT_LIBRARY_OUTPUT_DIR} PARENT_SCOPE)
335  endif()
336endfunction()
337
338# compiler_rt_process_sources(
339#   <OUTPUT_VAR>
340#   <SOURCE_FILE> ...
341#  [ADDITIONAL_HEADERS <header> ...]
342# )
343#
344# Process the provided sources and write the list of new sources
345# into `<OUTPUT_VAR>`.
346#
347# ADDITIONAL_HEADERS     - Adds the supplied header to list of sources for IDEs.
348#
349# This function is very similar to `llvm_process_sources()` but exists here
350# because we need to support standalone builds of compiler-rt.
351function(compiler_rt_process_sources OUTPUT_VAR)
352  cmake_parse_arguments(
353    ARG
354    ""
355    ""
356    "ADDITIONAL_HEADERS"
357    ${ARGN}
358  )
359  set(sources ${ARG_UNPARSED_ARGUMENTS})
360  set(headers "")
361  if (XCODE OR MSVC_IDE OR CMAKE_EXTRA_GENERATOR)
362    # For IDEs we need to tell CMake about header files.
363    # Otherwise they won't show up in UI.
364    set(headers ${ARG_ADDITIONAL_HEADERS})
365    list(LENGTH headers headers_length)
366    if (${headers_length} GREATER 0)
367      set_source_files_properties(${headers}
368        PROPERTIES HEADER_FILE_ONLY ON)
369    endif()
370  endif()
371  set("${OUTPUT_VAR}" ${sources} ${headers} PARENT_SCOPE)
372endfunction()
373
374# Create install targets for a library and its parent component (if specified).
375function(add_compiler_rt_install_targets name)
376  cmake_parse_arguments(ARG "" "PARENT_TARGET" "" ${ARGN})
377
378  if(ARG_PARENT_TARGET AND NOT TARGET install-${ARG_PARENT_TARGET})
379    # The parent install target specifies the parent component to scrape up
380    # anything not installed by the individual install targets, and to handle
381    # installation when running the multi-configuration generators.
382    add_custom_target(install-${ARG_PARENT_TARGET}
383                      DEPENDS ${ARG_PARENT_TARGET}
384                      COMMAND "${CMAKE_COMMAND}"
385                              -DCMAKE_INSTALL_COMPONENT=${ARG_PARENT_TARGET}
386                              -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
387    add_custom_target(install-${ARG_PARENT_TARGET}-stripped
388                      DEPENDS ${ARG_PARENT_TARGET}
389                      COMMAND "${CMAKE_COMMAND}"
390                              -DCMAKE_INSTALL_COMPONENT=${ARG_PARENT_TARGET}
391                              -DCMAKE_INSTALL_DO_STRIP=1
392                              -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
393    set_target_properties(install-${ARG_PARENT_TARGET} PROPERTIES
394                          FOLDER "Compiler-RT Misc")
395    set_target_properties(install-${ARG_PARENT_TARGET}-stripped PROPERTIES
396                          FOLDER "Compiler-RT Misc")
397    add_dependencies(install-compiler-rt install-${ARG_PARENT_TARGET})
398    add_dependencies(install-compiler-rt-stripped install-${ARG_PARENT_TARGET}-stripped)
399  endif()
400
401  # We only want to generate per-library install targets if you aren't using
402  # an IDE because the extra targets get cluttered in IDEs.
403  if(NOT CMAKE_CONFIGURATION_TYPES)
404    add_custom_target(install-${name}
405                      DEPENDS ${name}
406                      COMMAND "${CMAKE_COMMAND}"
407                              -DCMAKE_INSTALL_COMPONENT=${name}
408                              -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
409    add_custom_target(install-${name}-stripped
410                      DEPENDS ${name}
411                      COMMAND "${CMAKE_COMMAND}"
412                              -DCMAKE_INSTALL_COMPONENT=${name}
413                              -DCMAKE_INSTALL_DO_STRIP=1
414                              -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
415    # If you have a parent target specified, we bind the new install target
416    # to the parent install target.
417    if(LIB_PARENT_TARGET)
418      add_dependencies(install-${LIB_PARENT_TARGET} install-${name})
419      add_dependencies(install-${LIB_PARENT_TARGET}-stripped install-${name}-stripped)
420    endif()
421  endif()
422endfunction()
423