1include(CMakePushCheckState)
2include(CheckSymbolExists)
3
4# Because compiler-rt spends a lot of time setting up custom compile flags,
5# define a handy helper function for it. The compile flags setting in CMake
6# has serious issues that make its syntax challenging at best.
7function(set_target_compile_flags target)
8  set(argstring "")
9  foreach(arg ${ARGN})
10    set(argstring "${argstring} ${arg}")
11  endforeach()
12  set_property(TARGET ${target} PROPERTY COMPILE_FLAGS "${argstring}")
13endfunction()
14
15function(set_target_link_flags target)
16  set(argstring "")
17  foreach(arg ${ARGN})
18    set(argstring "${argstring} ${arg}")
19  endforeach()
20  set_property(TARGET ${target} PROPERTY LINK_FLAGS "${argstring}")
21endfunction()
22
23# Set the variable var_PYBOOL to True if var holds a true-ish string,
24# otherwise set it to False.
25macro(pythonize_bool var)
26  if (${var})
27    set(${var}_PYBOOL True)
28  else()
29    set(${var}_PYBOOL False)
30  endif()
31endmacro()
32
33# Appends value to all lists in ARGN, if the condition is true.
34macro(append_list_if condition value)
35  if(${condition})
36    foreach(list ${ARGN})
37      list(APPEND ${list} ${value})
38    endforeach()
39  endif()
40endmacro()
41
42# Appends value to all strings in ARGN, if the condition is true.
43macro(append_string_if condition value)
44  if(${condition})
45    foreach(str ${ARGN})
46      set(${str} "${${str}} ${value}")
47    endforeach()
48  endif()
49endmacro()
50
51macro(append_rtti_flag polarity list)
52  if(${polarity})
53    append_list_if(COMPILER_RT_HAS_FRTTI_FLAG -frtti ${list})
54    append_list_if(COMPILER_RT_HAS_GR_FLAG /GR ${list})
55  else()
56    append_list_if(COMPILER_RT_HAS_FNO_RTTI_FLAG -fno-rtti ${list})
57    append_list_if(COMPILER_RT_HAS_GR_FLAG /GR- ${list})
58  endif()
59endmacro()
60
61macro(list_intersect output input1 input2)
62  set(${output})
63  foreach(it ${${input1}})
64    list(FIND ${input2} ${it} index)
65    if( NOT (index EQUAL -1))
66      list(APPEND ${output} ${it})
67    endif()
68  endforeach()
69endmacro()
70
71function(list_replace input_list old new)
72  set(replaced_list)
73  foreach(item ${${input_list}})
74    if(${item} STREQUAL ${old})
75      list(APPEND replaced_list ${new})
76    else()
77      list(APPEND replaced_list ${item})
78    endif()
79  endforeach()
80  set(${input_list} "${replaced_list}" PARENT_SCOPE)
81endfunction()
82
83# Takes ${ARGN} and puts only supported architectures in @out_var list.
84function(filter_available_targets out_var)
85  set(archs ${${out_var}})
86  foreach(arch ${ARGN})
87    list(FIND COMPILER_RT_SUPPORTED_ARCH ${arch} ARCH_INDEX)
88    if(NOT (ARCH_INDEX EQUAL -1) AND CAN_TARGET_${arch})
89      list(APPEND archs ${arch})
90    endif()
91  endforeach()
92  set(${out_var} ${archs} PARENT_SCOPE)
93endfunction()
94
95# Add $arch as supported with no additional flags.
96macro(add_default_target_arch arch)
97  set(TARGET_${arch}_CFLAGS "")
98  set(CAN_TARGET_${arch} 1)
99  list(APPEND COMPILER_RT_SUPPORTED_ARCH ${arch})
100endmacro()
101
102function(check_compile_definition def argstring out_var)
103  if("${def}" STREQUAL "")
104    set(${out_var} TRUE PARENT_SCOPE)
105    return()
106  endif()
107  cmake_push_check_state()
108  set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} ${argstring}")
109  check_symbol_exists(${def} "" ${out_var})
110  cmake_pop_check_state()
111endfunction()
112
113# test_target_arch(<arch> <def> <target flags...>)
114# Checks if architecture is supported: runs host compiler with provided
115# flags to verify that:
116#   1) <def> is defined (if non-empty)
117#   2) simple file can be successfully built.
118# If successful, saves target flags for this architecture.
119macro(test_target_arch arch def)
120  set(TARGET_${arch}_CFLAGS ${ARGN})
121  set(TARGET_${arch}_LINK_FLAGS ${ARGN})
122  set(argstring "")
123  foreach(arg ${ARGN})
124    set(argstring "${argstring} ${arg}")
125  endforeach()
126  check_compile_definition("${def}" "${argstring}" HAS_${arch}_DEF)
127  if(NOT DEFINED CAN_TARGET_${arch})
128    if(NOT HAS_${arch}_DEF)
129      set(CAN_TARGET_${arch} FALSE)
130    elseif(TEST_COMPILE_ONLY)
131      try_compile_only(CAN_TARGET_${arch} FLAGS ${TARGET_${arch}_CFLAGS})
132    else()
133      set(FLAG_NO_EXCEPTIONS "")
134      if(COMPILER_RT_HAS_FNO_EXCEPTIONS_FLAG)
135        set(FLAG_NO_EXCEPTIONS " -fno-exceptions ")
136      endif()
137      set(SAVED_CMAKE_EXE_LINKER_FLAGS ${CMAKE_EXE_LINKER_FLAGS})
138      set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${argstring}")
139      try_compile(CAN_TARGET_${arch} ${CMAKE_BINARY_DIR} ${SIMPLE_SOURCE}
140                  COMPILE_DEFINITIONS "${TARGET_${arch}_CFLAGS} ${FLAG_NO_EXCEPTIONS}"
141                  OUTPUT_VARIABLE TARGET_${arch}_OUTPUT)
142      set(CMAKE_EXE_LINKER_FLAGS ${SAVED_CMAKE_EXE_LINKER_FLAGS})
143    endif()
144  endif()
145  if(${CAN_TARGET_${arch}})
146    list(APPEND COMPILER_RT_SUPPORTED_ARCH ${arch})
147  elseif("${COMPILER_RT_DEFAULT_TARGET_ARCH}" STREQUAL "${arch}" AND
148         COMPILER_RT_HAS_EXPLICIT_DEFAULT_TARGET_TRIPLE)
149    # Bail out if we cannot target the architecture we plan to test.
150    message(FATAL_ERROR "Cannot compile for ${arch}:\n${TARGET_${arch}_OUTPUT}")
151  endif()
152endmacro()
153
154macro(detect_target_arch)
155  check_symbol_exists(__arm__ "" __ARM)
156  check_symbol_exists(__aarch64__ "" __AARCH64)
157  check_symbol_exists(__x86_64__ "" __X86_64)
158  check_symbol_exists(__i386__ "" __I386)
159  check_symbol_exists(__mips__ "" __MIPS)
160  check_symbol_exists(__mips64__ "" __MIPS64)
161  check_symbol_exists(__powerpc__ "" __PPC)
162  check_symbol_exists(__powerpc64__ "" __PPC64)
163  check_symbol_exists(__powerpc64le__ "" __PPC64LE)
164  check_symbol_exists(__riscv "" __RISCV)
165  check_symbol_exists(__s390x__ "" __S390X)
166  check_symbol_exists(__sparc "" __SPARC)
167  check_symbol_exists(__sparcv9 "" __SPARCV9)
168  check_symbol_exists(__wasm32__ "" __WEBASSEMBLY32)
169  check_symbol_exists(__wasm64__ "" __WEBASSEMBLY64)
170  check_symbol_exists(__ve__ "" __VE)
171  if(__ARM)
172    add_default_target_arch(arm)
173  elseif(__AARCH64)
174    add_default_target_arch(aarch64)
175  elseif(__X86_64)
176    add_default_target_arch(x86_64)
177  elseif(__I386)
178    add_default_target_arch(i386)
179  elseif(__MIPS64) # must be checked before __MIPS
180    add_default_target_arch(mips64)
181  elseif(__MIPS)
182    add_default_target_arch(mips)
183  elseif(__PPC64) # must be checked before __PPC
184    add_default_target_arch(powerpc64)
185  elseif(__PPC64LE)
186    add_default_target_arch(powerpc64le)
187  elseif(__PPC)
188    add_default_target_arch(powerpc)
189  elseif(__RISCV)
190    if(CMAKE_SIZEOF_VOID_P EQUAL "4")
191      add_default_target_arch(riscv32)
192    elseif(CMAKE_SIZEOF_VOID_P EQUAL "8")
193      add_default_target_arch(riscv64)
194    else()
195      message(FATAL_ERROR "Unsupport XLEN for RISC-V")
196    endif()
197  elseif(__S390X)
198    add_default_target_arch(s390x)
199  elseif(__SPARCV9)
200    add_default_target_arch(sparcv9)
201  elseif(__SPARC)
202    add_default_target_arch(sparc)
203  elseif(__WEBASSEMBLY32)
204    add_default_target_arch(wasm32)
205  elseif(__WEBASSEMBLY64)
206    add_default_target_arch(wasm64)
207  elseif(__VE)
208    add_default_target_arch(ve)
209  endif()
210endmacro()
211
212function(get_compiler_rt_root_source_dir ROOT_DIR_VAR)
213  # Compute the path to the root of the Compiler-RT source tree
214  # regardless of how the project was configured.
215  #
216  # This function is useful because using `${CMAKE_SOURCE_DIR}`
217  # is error prone due to the numerous ways Compiler-RT can be
218  # configured.
219  #
220  # `ROOT_DIR_VAR` - the name of the variable to write the result to.
221  #
222  # TODO(dliew): When CMake min version is 3.17 or newer use
223  # `CMAKE_CURRENT_FUNCTION_LIST_DIR` instead.
224  if ("${ROOT_DIR_VAR}" STREQUAL "")
225    message(FATAL_ERROR "ROOT_DIR_VAR cannot be empty")
226  endif()
227
228  # Compiler-rt supports different source root paths.
229  # Handle each case here.
230  set(PATH_TO_COMPILER_RT_SOURCE_ROOT "")
231  if (DEFINED CompilerRTBuiltins_SOURCE_DIR)
232    # Compiler-RT Builtins standalone build.
233    # `llvm-project/compiler-rt/lib/builtins`
234    set(PATH_TO_COMPILER_RT_SOURCE_ROOT "${CompilerRTBuiltins_SOURCE_DIR}/../../")
235  elseif(DEFINED CompilerRT_SOURCE_DIR)
236    # Compiler-RT standalone build.
237    # `llvm-project/compiler-rt`
238    set(PATH_TO_COMPILER_RT_SOURCE_ROOT "${CompilerRT_SOURCE_DIR}")
239  elseif (EXISTS "${CMAKE_SOURCE_DIR}/../compiler-rt")
240    # In tree build with LLVM as the root project.
241    # See `llvm-project/projects/`.
242    # Assumes monorepo layout.
243    set(PATH_TO_COMPILER_RT_SOURCE_ROOT "${CMAKE_SOURCE_DIR}/../compiler-rt")
244  else()
245    message(FATAL_ERROR "Unhandled Compiler-RT source root configuration.")
246  endif()
247
248  get_filename_component(ROOT_DIR "${PATH_TO_COMPILER_RT_SOURCE_ROOT}" ABSOLUTE)
249  if (NOT EXISTS "${ROOT_DIR}")
250    message(FATAL_ERROR "Path \"${ROOT_DIR}\" doesn't exist")
251  endif()
252
253  # Sanity check: Make sure we can locate the current source file via the
254  # computed path.
255  set(PATH_TO_CURRENT_FILE "${ROOT_DIR}/cmake/Modules/CompilerRTUtils.cmake")
256  if (NOT EXISTS "${PATH_TO_CURRENT_FILE}")
257    message(FATAL_ERROR "Could not find \"${PATH_TO_CURRENT_FILE}\"")
258  endif()
259
260  set("${ROOT_DIR_VAR}" "${ROOT_DIR}" PARENT_SCOPE)
261endfunction()
262
263macro(load_llvm_config)
264  if (NOT LLVM_CONFIG_PATH)
265    find_program(LLVM_CONFIG_PATH "llvm-config"
266                 DOC "Path to llvm-config binary")
267    if (NOT LLVM_CONFIG_PATH)
268      message(WARNING "UNSUPPORTED COMPILER-RT CONFIGURATION DETECTED: "
269                      "llvm-config not found.\n"
270                      "Reconfigure with -DLLVM_CONFIG_PATH=path/to/llvm-config.")
271    endif()
272  endif()
273
274  # Compute path to LLVM sources assuming the monorepo layout.
275  # We don't set `LLVM_MAIN_SRC_DIR` directly to avoid overriding a user provided
276  # CMake cache value.
277  get_compiler_rt_root_source_dir(COMPILER_RT_ROOT_SRC_PATH)
278  get_filename_component(LLVM_MAIN_SRC_DIR_DEFAULT "${COMPILER_RT_ROOT_SRC_PATH}/../llvm" ABSOLUTE)
279  if (NOT EXISTS "${LLVM_MAIN_SRC_DIR_DEFAULT}")
280    # TODO(dliew): Remove this legacy fallback path.
281    message(WARNING
282      "LLVM source tree not found at \"${LLVM_MAIN_SRC_DIR_DEFAULT}\". "
283      "You are not using the monorepo layout. This configuration is DEPRECATED.")
284  endif()
285
286  set(FOUND_LLVM_CMAKE_PATH FALSE)
287  if (LLVM_CONFIG_PATH)
288    execute_process(
289      COMMAND ${LLVM_CONFIG_PATH} "--obj-root" "--bindir" "--libdir" "--src-root" "--includedir"
290      RESULT_VARIABLE HAD_ERROR
291      OUTPUT_VARIABLE CONFIG_OUTPUT)
292    if (HAD_ERROR)
293      message(FATAL_ERROR "llvm-config failed with status ${HAD_ERROR}")
294    endif()
295    string(REGEX REPLACE "[ \t]*[\r\n]+[ \t]*" ";" CONFIG_OUTPUT ${CONFIG_OUTPUT})
296    list(GET CONFIG_OUTPUT 0 BINARY_DIR)
297    list(GET CONFIG_OUTPUT 1 TOOLS_BINARY_DIR)
298    list(GET CONFIG_OUTPUT 2 LIBRARY_DIR)
299    list(GET CONFIG_OUTPUT 3 MAIN_SRC_DIR)
300    list(GET CONFIG_OUTPUT 4 INCLUDE_DIR)
301
302    set(LLVM_BINARY_DIR ${BINARY_DIR} CACHE PATH "Path to LLVM build tree")
303    set(LLVM_LIBRARY_DIR ${LIBRARY_DIR} CACHE PATH "Path to llvm/lib")
304    set(LLVM_TOOLS_BINARY_DIR ${TOOLS_BINARY_DIR} CACHE PATH "Path to llvm/bin")
305    set(LLVM_INCLUDE_DIR ${INCLUDE_DIR} CACHE PATH "Paths to LLVM headers")
306
307    if (NOT EXISTS "${LLVM_MAIN_SRC_DIR_DEFAULT}")
308      # TODO(dliew): Remove this legacy fallback path.
309      message(WARNING
310        "Consulting llvm-config for the LLVM source path "
311        "as a fallback. This behavior will be removed in the future.")
312      # We don't set `LLVM_MAIN_SRC_DIR` directly to avoid overriding a user
313      # provided CMake cache value.
314      set(LLVM_MAIN_SRC_DIR_DEFAULT "${MAIN_SRC_DIR}")
315      message(STATUS "Using LLVM source path (${LLVM_MAIN_SRC_DIR_DEFAULT}) from llvm-config")
316    endif()
317
318    # Detect if we have the LLVMXRay and TestingSupport library installed and
319    # available from llvm-config.
320    execute_process(
321      COMMAND ${LLVM_CONFIG_PATH} "--ldflags" "--libs" "xray"
322      RESULT_VARIABLE HAD_ERROR
323      OUTPUT_VARIABLE CONFIG_OUTPUT
324      ERROR_QUIET)
325    if (HAD_ERROR)
326      message(WARNING "llvm-config finding xray failed with status ${HAD_ERROR}")
327      set(COMPILER_RT_HAS_LLVMXRAY FALSE)
328    else()
329      string(REGEX REPLACE "[ \t]*[\r\n]+[ \t]*" ";" CONFIG_OUTPUT ${CONFIG_OUTPUT})
330      list(GET CONFIG_OUTPUT 0 LDFLAGS)
331      list(GET CONFIG_OUTPUT 1 LIBLIST)
332      file(TO_CMAKE_PATH "${LDFLAGS}" LDFLAGS)
333      file(TO_CMAKE_PATH "${LIBLIST}" LIBLIST)
334      set(LLVM_XRAY_LDFLAGS ${LDFLAGS} CACHE STRING "Linker flags for LLVMXRay library")
335      set(LLVM_XRAY_LIBLIST ${LIBLIST} CACHE STRING "Library list for LLVMXRay")
336      set(COMPILER_RT_HAS_LLVMXRAY TRUE)
337    endif()
338
339    set(COMPILER_RT_HAS_LLVMTESTINGSUPPORT FALSE)
340    execute_process(
341      COMMAND ${LLVM_CONFIG_PATH} "--ldflags" "--libs" "testingsupport"
342      RESULT_VARIABLE HAD_ERROR
343      OUTPUT_VARIABLE CONFIG_OUTPUT
344      ERROR_QUIET)
345    if (HAD_ERROR)
346      message(WARNING "llvm-config finding testingsupport failed with status ${HAD_ERROR}")
347    elseif(COMPILER_RT_INCLUDE_TESTS)
348      string(REGEX REPLACE "[ \t]*[\r\n]+[ \t]*" ";" CONFIG_OUTPUT ${CONFIG_OUTPUT})
349      list(GET CONFIG_OUTPUT 0 LDFLAGS)
350      list(GET CONFIG_OUTPUT 1 LIBLIST)
351      if (LIBLIST STREQUAL "")
352        message(WARNING "testingsupport library not installed, some tests will be skipped")
353      else()
354        file(TO_CMAKE_PATH "${LDFLAGS}" LDFLAGS)
355        file(TO_CMAKE_PATH "${LIBLIST}" LIBLIST)
356        set(LLVM_TESTINGSUPPORT_LDFLAGS ${LDFLAGS} CACHE STRING "Linker flags for LLVMTestingSupport library")
357        set(LLVM_TESTINGSUPPORT_LIBLIST ${LIBLIST} CACHE STRING "Library list for LLVMTestingSupport")
358        set(COMPILER_RT_HAS_LLVMTESTINGSUPPORT TRUE)
359      endif()
360    endif()
361
362    # Make use of LLVM CMake modules.
363    # --cmakedir is supported since llvm r291218 (4.0 release)
364    execute_process(
365      COMMAND ${LLVM_CONFIG_PATH} --cmakedir
366      RESULT_VARIABLE HAD_ERROR
367      OUTPUT_VARIABLE CONFIG_OUTPUT)
368    if(NOT HAD_ERROR)
369      string(STRIP "${CONFIG_OUTPUT}" LLVM_CMAKE_PATH_FROM_LLVM_CONFIG)
370      file(TO_CMAKE_PATH ${LLVM_CMAKE_PATH_FROM_LLVM_CONFIG} LLVM_CMAKE_PATH)
371    else()
372      file(TO_CMAKE_PATH ${LLVM_BINARY_DIR} LLVM_BINARY_DIR_CMAKE_STYLE)
373      set(LLVM_CMAKE_PATH "${LLVM_BINARY_DIR_CMAKE_STYLE}/lib${LLVM_LIBDIR_SUFFIX}/cmake/llvm")
374    endif()
375
376    set(LLVM_CMAKE_INCLUDE_FILE "${LLVM_CMAKE_PATH}/LLVMConfig.cmake")
377    if (EXISTS "${LLVM_CMAKE_INCLUDE_FILE}")
378      list(APPEND CMAKE_MODULE_PATH "${LLVM_CMAKE_PATH}")
379      # Get some LLVM variables from LLVMConfig.
380      include("${LLVM_CMAKE_INCLUDE_FILE}")
381      set(FOUND_LLVM_CMAKE_PATH TRUE)
382    else()
383      set(FOUND_LLVM_CMAKE_PATH FALSE)
384      message(WARNING "LLVM CMake path (${LLVM_CMAKE_INCLUDE_FILE}) reported by llvm-config does not exist")
385    endif()
386    unset(LLVM_CMAKE_INCLUDE_FILE)
387
388    set(LLVM_LIBRARY_OUTPUT_INTDIR
389      ${LLVM_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
390  endif()
391
392  # Finally set the cache variable now that `llvm-config` has also had a chance
393  # to set `LLVM_MAIN_SRC_DIR_DEFAULT`.
394  set(LLVM_MAIN_SRC_DIR "${LLVM_MAIN_SRC_DIR_DEFAULT}" CACHE PATH "Path to LLVM source tree")
395  message(STATUS "LLVM_MAIN_SRC_DIR: \"${LLVM_MAIN_SRC_DIR}\"")
396  if (NOT EXISTS "${LLVM_MAIN_SRC_DIR}")
397    # TODO(dliew): Make this a hard error
398    message(WARNING "LLVM_MAIN_SRC_DIR (${LLVM_MAIN_SRC_DIR}) does not exist. "
399                    "You can override the inferred path by adding "
400                    "`-DLLVM_MAIN_SRC_DIR=<path_to_llvm_src>` to your CMake invocation "
401                    "where `<path_to_llvm_src>` is the path to the `llvm` directory in "
402                    "the `llvm-project` repo. "
403                    "This will be treated as error in the future.")
404  endif()
405
406  if (NOT FOUND_LLVM_CMAKE_PATH)
407    # This configuration tries to configure without the prescence of `LLVMConfig.cmake`. It is
408    # intended for testing purposes (generating the lit test suites) and will likely not support
409    # a build of the runtimes in compiler-rt.
410    include(CompilerRTMockLLVMCMakeConfig)
411    compiler_rt_mock_llvm_cmake_config()
412  endif()
413
414endmacro()
415
416macro(construct_compiler_rt_default_triple)
417  if(COMPILER_RT_DEFAULT_TARGET_ONLY)
418    if(DEFINED COMPILER_RT_DEFAULT_TARGET_TRIPLE)
419      message(FATAL_ERROR "COMPILER_RT_DEFAULT_TARGET_TRIPLE isn't supported when building for default target only")
420    endif()
421    set(COMPILER_RT_DEFAULT_TARGET_TRIPLE ${CMAKE_C_COMPILER_TARGET})
422  else()
423    set(COMPILER_RT_DEFAULT_TARGET_TRIPLE ${TARGET_TRIPLE} CACHE STRING
424          "Default triple for which compiler-rt runtimes will be built.")
425  endif()
426
427  if(DEFINED COMPILER_RT_TEST_TARGET_TRIPLE)
428    # Backwards compatibility: this variable used to be called
429    # COMPILER_RT_TEST_TARGET_TRIPLE.
430    set(COMPILER_RT_DEFAULT_TARGET_TRIPLE ${COMPILER_RT_TEST_TARGET_TRIPLE})
431  endif()
432
433  string(REPLACE "-" ";" TARGET_TRIPLE_LIST ${COMPILER_RT_DEFAULT_TARGET_TRIPLE})
434  list(GET TARGET_TRIPLE_LIST 0 COMPILER_RT_DEFAULT_TARGET_ARCH)
435
436  # Map various forms of the architecture names to the canonical forms
437  # (as they are used by clang, see getArchNameForCompilerRTLib).
438  if("${COMPILER_RT_DEFAULT_TARGET_ARCH}" MATCHES "^i.86$")
439    # Android uses i686, but that's remapped at a later stage.
440    set(COMPILER_RT_DEFAULT_TARGET_ARCH "i386")
441  endif()
442
443  # Determine if test target triple is specified explicitly, and doesn't match the
444  # default.
445  if(NOT COMPILER_RT_DEFAULT_TARGET_TRIPLE STREQUAL TARGET_TRIPLE)
446    set(COMPILER_RT_HAS_EXPLICIT_DEFAULT_TARGET_TRIPLE TRUE)
447  else()
448    set(COMPILER_RT_HAS_EXPLICIT_DEFAULT_TARGET_TRIPLE FALSE)
449  endif()
450endmacro()
451
452# Filter out generic versions of routines that are re-implemented in an
453# architecture specific manner. This prevents multiple definitions of the same
454# symbols, making the symbol selection non-deterministic.
455#
456# We follow the convention that a source file that exists in a sub-directory
457# (e.g. `ppc/divtc3.c`) is architecture-specific and that if a generic
458# implementation exists it will be a top-level source file with the same name
459# modulo the file extension (e.g. `divtc3.c`).
460function(filter_builtin_sources inout_var name)
461  set(intermediate ${${inout_var}})
462  foreach(_file ${intermediate})
463    get_filename_component(_file_dir ${_file} DIRECTORY)
464    if (NOT "${_file_dir}" STREQUAL "")
465      # Architecture specific file. If a generic version exists, print a notice
466      # and ensure that it is removed from the file list.
467      get_filename_component(_name ${_file} NAME)
468      string(REGEX REPLACE "\\.S$" ".c" _cname "${_name}")
469      if(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/${_cname}")
470        message(STATUS "For ${name} builtins preferring ${_file} to ${_cname}")
471        list(REMOVE_ITEM intermediate ${_cname})
472      endif()
473    endif()
474  endforeach()
475  set(${inout_var} ${intermediate} PARENT_SCOPE)
476endfunction()
477
478function(get_compiler_rt_target arch variable)
479  string(FIND ${COMPILER_RT_DEFAULT_TARGET_TRIPLE} "-" dash_index)
480  string(SUBSTRING ${COMPILER_RT_DEFAULT_TARGET_TRIPLE} ${dash_index} -1 triple_suffix)
481  if(COMPILER_RT_DEFAULT_TARGET_ONLY)
482    # Use exact spelling when building only for the target specified to CMake.
483    set(target "${COMPILER_RT_DEFAULT_TARGET_TRIPLE}")
484  elseif(ANDROID AND ${arch} STREQUAL "i386")
485    set(target "i686${triple_suffix}")
486  else()
487    set(target "${arch}${triple_suffix}")
488  endif()
489  set(${variable} ${target} PARENT_SCOPE)
490endfunction()
491
492function(get_compiler_rt_install_dir arch install_dir)
493  if(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR AND NOT APPLE)
494    get_compiler_rt_target(${arch} target)
495    set(${install_dir} ${COMPILER_RT_INSTALL_PATH}/lib/${target} PARENT_SCOPE)
496  else()
497    set(${install_dir} ${COMPILER_RT_LIBRARY_INSTALL_DIR} PARENT_SCOPE)
498  endif()
499endfunction()
500
501function(get_compiler_rt_output_dir arch output_dir)
502  if(LLVM_ENABLE_PER_TARGET_RUNTIME_DIR AND NOT APPLE)
503    get_compiler_rt_target(${arch} target)
504    set(${output_dir} ${COMPILER_RT_OUTPUT_DIR}/lib/${target} PARENT_SCOPE)
505  else()
506    set(${output_dir} ${COMPILER_RT_LIBRARY_OUTPUT_DIR} PARENT_SCOPE)
507  endif()
508endfunction()
509
510# compiler_rt_process_sources(
511#   <OUTPUT_VAR>
512#   <SOURCE_FILE> ...
513#  [ADDITIONAL_HEADERS <header> ...]
514# )
515#
516# Process the provided sources and write the list of new sources
517# into `<OUTPUT_VAR>`.
518#
519# ADDITIONAL_HEADERS     - Adds the supplied header to list of sources for IDEs.
520#
521# This function is very similar to `llvm_process_sources()` but exists here
522# because we need to support standalone builds of compiler-rt.
523function(compiler_rt_process_sources OUTPUT_VAR)
524  cmake_parse_arguments(
525    ARG
526    ""
527    ""
528    "ADDITIONAL_HEADERS"
529    ${ARGN}
530  )
531  set(sources ${ARG_UNPARSED_ARGUMENTS})
532  set(headers "")
533  if (XCODE OR MSVC_IDE OR CMAKE_EXTRA_GENERATOR)
534    # For IDEs we need to tell CMake about header files.
535    # Otherwise they won't show up in UI.
536    set(headers ${ARG_ADDITIONAL_HEADERS})
537    list(LENGTH headers headers_length)
538    if (${headers_length} GREATER 0)
539      set_source_files_properties(${headers}
540        PROPERTIES HEADER_FILE_ONLY ON)
541    endif()
542  endif()
543  set("${OUTPUT_VAR}" ${sources} ${headers} PARENT_SCOPE)
544endfunction()
545
546# Create install targets for a library and its parent component (if specified).
547function(add_compiler_rt_install_targets name)
548  cmake_parse_arguments(ARG "" "PARENT_TARGET" "" ${ARGN})
549
550  if(ARG_PARENT_TARGET AND NOT TARGET install-${ARG_PARENT_TARGET})
551    # The parent install target specifies the parent component to scrape up
552    # anything not installed by the individual install targets, and to handle
553    # installation when running the multi-configuration generators.
554    add_custom_target(install-${ARG_PARENT_TARGET}
555                      DEPENDS ${ARG_PARENT_TARGET}
556                      COMMAND "${CMAKE_COMMAND}"
557                              -DCMAKE_INSTALL_COMPONENT=${ARG_PARENT_TARGET}
558                              -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
559    add_custom_target(install-${ARG_PARENT_TARGET}-stripped
560                      DEPENDS ${ARG_PARENT_TARGET}
561                      COMMAND "${CMAKE_COMMAND}"
562                              -DCMAKE_INSTALL_COMPONENT=${ARG_PARENT_TARGET}
563                              -DCMAKE_INSTALL_DO_STRIP=1
564                              -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
565    set_target_properties(install-${ARG_PARENT_TARGET} PROPERTIES
566                          FOLDER "Compiler-RT Misc")
567    set_target_properties(install-${ARG_PARENT_TARGET}-stripped PROPERTIES
568                          FOLDER "Compiler-RT Misc")
569    add_dependencies(install-compiler-rt install-${ARG_PARENT_TARGET})
570    add_dependencies(install-compiler-rt-stripped install-${ARG_PARENT_TARGET}-stripped)
571  endif()
572
573  # We only want to generate per-library install targets if you aren't using
574  # an IDE because the extra targets get cluttered in IDEs.
575  if(NOT CMAKE_CONFIGURATION_TYPES)
576    add_custom_target(install-${name}
577                      DEPENDS ${name}
578                      COMMAND "${CMAKE_COMMAND}"
579                              -DCMAKE_INSTALL_COMPONENT=${name}
580                              -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
581    add_custom_target(install-${name}-stripped
582                      DEPENDS ${name}
583                      COMMAND "${CMAKE_COMMAND}"
584                              -DCMAKE_INSTALL_COMPONENT=${name}
585                              -DCMAKE_INSTALL_DO_STRIP=1
586                              -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
587    # If you have a parent target specified, we bind the new install target
588    # to the parent install target.
589    if(LIB_PARENT_TARGET)
590      add_dependencies(install-${LIB_PARENT_TARGET} install-${name})
591      add_dependencies(install-${LIB_PARENT_TARGET}-stripped install-${name}-stripped)
592    endif()
593  endif()
594endfunction()
595