1include(CMakePushCheckState)
2include(CheckSymbolExists)
3
4# Because compiler-rt spends a lot of time setting up custom compile flags,
5# define a handy helper function for it. The compile flags setting in CMake
6# has serious issues that make its syntax challenging at best.
7function(set_target_compile_flags target)
8  set(argstring "")
9  foreach(arg ${ARGN})
10    set(argstring "${argstring} ${arg}")
11  endforeach()
12  set_property(TARGET ${target} PROPERTY COMPILE_FLAGS "${argstring}")
13endfunction()
14
15function(set_target_link_flags target)
16  set(argstring "")
17  foreach(arg ${ARGN})
18    set(argstring "${argstring} ${arg}")
19  endforeach()
20  set_property(TARGET ${target} PROPERTY LINK_FLAGS "${argstring}")
21endfunction()
22
23# Set the variable var_PYBOOL to True if var holds a true-ish string,
24# otherwise set it to False.
25macro(pythonize_bool var)
26  if (${var})
27    set(${var}_PYBOOL True)
28  else()
29    set(${var}_PYBOOL False)
30  endif()
31endmacro()
32
33# Appends value to all lists in ARGN, if the condition is true.
34macro(append_list_if condition value)
35  if(${condition})
36    foreach(list ${ARGN})
37      list(APPEND ${list} ${value})
38    endforeach()
39  endif()
40endmacro()
41
42# Appends value to all strings in ARGN, if the condition is true.
43macro(append_string_if condition value)
44  if(${condition})
45    foreach(str ${ARGN})
46      set(${str} "${${str}} ${value}")
47    endforeach()
48  endif()
49endmacro()
50
51macro(append_rtti_flag polarity list)
52  if(${polarity})
53    append_list_if(COMPILER_RT_HAS_FRTTI_FLAG -frtti ${list})
54    append_list_if(COMPILER_RT_HAS_GR_FLAG /GR ${list})
55  else()
56    append_list_if(COMPILER_RT_HAS_FNO_RTTI_FLAG -fno-rtti ${list})
57    append_list_if(COMPILER_RT_HAS_GR_FLAG /GR- ${list})
58  endif()
59endmacro()
60
61macro(append_have_file_definition filename varname list)
62  check_include_file("${filename}" "${varname}")
63  if (NOT ${varname})
64    set("${varname}" 0)
65  endif()
66  list(APPEND ${list} "${varname}=${${varname}}")
67endmacro()
68
69macro(list_intersect output input1 input2)
70  set(${output})
71  foreach(it ${${input1}})
72    list(FIND ${input2} ${it} index)
73    if( NOT (index EQUAL -1))
74      list(APPEND ${output} ${it})
75    endif()
76  endforeach()
77endmacro()
78
79function(list_replace input_list old new)
80  set(replaced_list)
81  foreach(item ${${input_list}})
82    if(${item} STREQUAL ${old})
83      list(APPEND replaced_list ${new})
84    else()
85      list(APPEND replaced_list ${item})
86    endif()
87  endforeach()
88  set(${input_list} "${replaced_list}" PARENT_SCOPE)
89endfunction()
90
91# Takes ${ARGN} and puts only supported architectures in @out_var list.
92function(filter_available_targets out_var)
93  set(archs ${${out_var}})
94  foreach(arch ${ARGN})
95    list(FIND COMPILER_RT_SUPPORTED_ARCH ${arch} ARCH_INDEX)
96    if(NOT (ARCH_INDEX EQUAL -1) AND CAN_TARGET_${arch})
97      list(APPEND archs ${arch})
98    endif()
99  endforeach()
100  set(${out_var} ${archs} PARENT_SCOPE)
101endfunction()
102
103# Add $arch as supported with no additional flags.
104macro(add_default_target_arch arch)
105  set(TARGET_${arch}_CFLAGS "")
106  set(CAN_TARGET_${arch} 1)
107  list(APPEND COMPILER_RT_SUPPORTED_ARCH ${arch})
108endmacro()
109
110function(check_compile_definition def argstring out_var)
111  if("${def}" STREQUAL "")
112    set(${out_var} TRUE PARENT_SCOPE)
113    return()
114  endif()
115  cmake_push_check_state()
116  set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} ${argstring}")
117  check_symbol_exists(${def} "" ${out_var})
118  cmake_pop_check_state()
119endfunction()
120
121# test_target_arch(<arch> <def> <target flags...>)
122# Checks if architecture is supported: runs host compiler with provided
123# flags to verify that:
124#   1) <def> is defined (if non-empty)
125#   2) simple file can be successfully built.
126# If successful, saves target flags for this architecture.
127macro(test_target_arch arch def)
128  set(TARGET_${arch}_CFLAGS ${ARGN})
129  set(TARGET_${arch}_LINK_FLAGS ${ARGN})
130  set(argstring "")
131  foreach(arg ${ARGN})
132    set(argstring "${argstring} ${arg}")
133  endforeach()
134  check_compile_definition("${def}" "${argstring}" HAS_${arch}_DEF)
135  if(NOT DEFINED CAN_TARGET_${arch})
136    if(NOT HAS_${arch}_DEF)
137      set(CAN_TARGET_${arch} FALSE)
138    elseif(TEST_COMPILE_ONLY)
139      try_compile_only(CAN_TARGET_${arch} ${TARGET_${arch}_CFLAGS})
140    else()
141      set(FLAG_NO_EXCEPTIONS "")
142      if(COMPILER_RT_HAS_FNO_EXCEPTIONS_FLAG)
143        set(FLAG_NO_EXCEPTIONS " -fno-exceptions ")
144      endif()
145      set(SAVED_CMAKE_EXE_LINKER_FLAGS ${CMAKE_EXE_LINKER_FLAGS})
146      set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${argstring}")
147      try_compile(CAN_TARGET_${arch} ${CMAKE_BINARY_DIR} ${SIMPLE_SOURCE}
148                  COMPILE_DEFINITIONS "${TARGET_${arch}_CFLAGS} ${FLAG_NO_EXCEPTIONS}"
149                  OUTPUT_VARIABLE TARGET_${arch}_OUTPUT)
150      set(CMAKE_EXE_LINKER_FLAGS ${SAVED_CMAKE_EXE_LINKER_FLAGS})
151    endif()
152  endif()
153  if(${CAN_TARGET_${arch}})
154    list(APPEND COMPILER_RT_SUPPORTED_ARCH ${arch})
155  elseif("${COMPILER_RT_DEFAULT_TARGET_ARCH}" STREQUAL "${arch}" AND
156         COMPILER_RT_HAS_EXPLICIT_DEFAULT_TARGET_TRIPLE)
157    # Bail out if we cannot target the architecture we plan to test.
158    message(FATAL_ERROR "Cannot compile for ${arch}:\n${TARGET_${arch}_OUTPUT}")
159  endif()
160endmacro()
161
162macro(detect_target_arch)
163  check_symbol_exists(__arm__ "" __ARM)
164  check_symbol_exists(__aarch64__ "" __AARCH64)
165  check_symbol_exists(__x86_64__ "" __X86_64)
166  check_symbol_exists(__i386__ "" __I386)
167  check_symbol_exists(__mips__ "" __MIPS)
168  check_symbol_exists(__mips64__ "" __MIPS64)
169  check_symbol_exists(__powerpc64__ "" __PPC64)
170  check_symbol_exists(__powerpc64le__ "" __PPC64LE)
171  check_symbol_exists(__s390x__ "" __S390X)
172  check_symbol_exists(__wasm32__ "" __WEBASSEMBLY32)
173  check_symbol_exists(__wasm64__ "" __WEBASSEMBLY64)
174  if(__ARM)
175    add_default_target_arch(arm)
176  elseif(__AARCH64)
177    add_default_target_arch(aarch64)
178  elseif(__X86_64)
179    add_default_target_arch(x86_64)
180  elseif(__I386)
181    add_default_target_arch(i386)
182  elseif(__MIPS64) # must be checked before __MIPS
183    add_default_target_arch(mips64)
184  elseif(__MIPS)
185    add_default_target_arch(mips)
186  elseif(__PPC64)
187    add_default_target_arch(powerpc64)
188  elseif(__PPC64LE)
189    add_default_target_arch(powerpc64le)
190  elseif(__S390X)
191    add_default_target_arch(s390x)
192  elseif(__WEBASSEMBLY32)
193    add_default_target_arch(wasm32)
194  elseif(__WEBASSEMBLY64)
195    add_default_target_arch(wasm64)
196  endif()
197endmacro()
198
199macro(load_llvm_config)
200  if (NOT LLVM_CONFIG_PATH)
201    find_program(LLVM_CONFIG_PATH "llvm-config"
202                 DOC "Path to llvm-config binary")
203    if (NOT LLVM_CONFIG_PATH)
204      message(FATAL_ERROR "llvm-config not found: specify LLVM_CONFIG_PATH")
205    endif()
206  endif()
207  execute_process(
208    COMMAND ${LLVM_CONFIG_PATH} "--obj-root" "--bindir" "--libdir" "--src-root"
209    RESULT_VARIABLE HAD_ERROR
210    OUTPUT_VARIABLE CONFIG_OUTPUT)
211  if (HAD_ERROR)
212    message(FATAL_ERROR "llvm-config failed with status ${HAD_ERROR}")
213  endif()
214  string(REGEX REPLACE "[ \t]*[\r\n]+[ \t]*" ";" CONFIG_OUTPUT ${CONFIG_OUTPUT})
215  list(GET CONFIG_OUTPUT 0 BINARY_DIR)
216  list(GET CONFIG_OUTPUT 1 TOOLS_BINARY_DIR)
217  list(GET CONFIG_OUTPUT 2 LIBRARY_DIR)
218  list(GET CONFIG_OUTPUT 3 MAIN_SRC_DIR)
219
220  set(LLVM_BINARY_DIR ${BINARY_DIR} CACHE PATH "Path to LLVM build tree")
221  set(LLVM_TOOLS_BINARY_DIR ${TOOLS_BINARY_DIR} CACHE PATH "Path to llvm/bin")
222  set(LLVM_LIBRARY_DIR ${LIBRARY_DIR} CACHE PATH "Path to llvm/lib")
223  set(LLVM_MAIN_SRC_DIR ${MAIN_SRC_DIR} CACHE PATH "Path to LLVM source tree")
224
225  # Make use of LLVM CMake modules.
226  # --cmakedir is supported since llvm r291218 (4.0 release)
227  execute_process(
228    COMMAND ${LLVM_CONFIG_PATH} --cmakedir
229    RESULT_VARIABLE HAD_ERROR
230    OUTPUT_VARIABLE CONFIG_OUTPUT)
231  if(NOT HAD_ERROR)
232    string(STRIP "${CONFIG_OUTPUT}" LLVM_CMAKE_PATH_FROM_LLVM_CONFIG)
233    file(TO_CMAKE_PATH ${LLVM_CMAKE_PATH_FROM_LLVM_CONFIG} LLVM_CMAKE_PATH)
234  else()
235    file(TO_CMAKE_PATH ${LLVM_BINARY_DIR} LLVM_BINARY_DIR_CMAKE_STYLE)
236    set(LLVM_CMAKE_PATH "${LLVM_BINARY_DIR_CMAKE_STYLE}/lib${LLVM_LIBDIR_SUFFIX}/cmake/llvm")
237  endif()
238
239  list(APPEND CMAKE_MODULE_PATH "${LLVM_CMAKE_PATH}")
240  # Get some LLVM variables from LLVMConfig.
241  include("${LLVM_CMAKE_PATH}/LLVMConfig.cmake")
242
243  set(LLVM_LIBRARY_OUTPUT_INTDIR
244    ${LLVM_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
245endmacro()
246
247macro(construct_compiler_rt_default_triple)
248  if(COMPILER_RT_DEFAULT_TARGET_ONLY)
249    if(DEFINED COMPILER_RT_DEFAULT_TARGET_TRIPLE)
250      message(FATAL_ERROR "COMPILER_RT_DEFAULT_TARGET_TRIPLE isn't supported when building for default target only")
251    endif()
252    set(COMPILER_RT_DEFAULT_TARGET_TRIPLE ${CMAKE_C_COMPILER_TARGET})
253  else()
254    set(COMPILER_RT_DEFAULT_TARGET_TRIPLE ${TARGET_TRIPLE} CACHE STRING
255          "Default triple for which compiler-rt runtimes will be built.")
256  endif()
257
258  if(DEFINED COMPILER_RT_TEST_TARGET_TRIPLE)
259    # Backwards compatibility: this variable used to be called
260    # COMPILER_RT_TEST_TARGET_TRIPLE.
261    set(COMPILER_RT_DEFAULT_TARGET_TRIPLE ${COMPILER_RT_TEST_TARGET_TRIPLE})
262  endif()
263
264  string(REPLACE "-" ";" TARGET_TRIPLE_LIST ${COMPILER_RT_DEFAULT_TARGET_TRIPLE})
265  list(GET TARGET_TRIPLE_LIST 0 COMPILER_RT_DEFAULT_TARGET_ARCH)
266  list(GET TARGET_TRIPLE_LIST 1 COMPILER_RT_DEFAULT_TARGET_OS)
267  list(LENGTH TARGET_TRIPLE_LIST TARGET_TRIPLE_LIST_LENGTH)
268  if(TARGET_TRIPLE_LIST_LENGTH GREATER 2)
269    list(GET TARGET_TRIPLE_LIST 2 COMPILER_RT_DEFAULT_TARGET_ABI)
270  endif()
271  # Determine if test target triple is specified explicitly, and doesn't match the
272  # default.
273  if(NOT COMPILER_RT_DEFAULT_TARGET_TRIPLE STREQUAL TARGET_TRIPLE)
274    set(COMPILER_RT_HAS_EXPLICIT_DEFAULT_TARGET_TRIPLE TRUE)
275  else()
276    set(COMPILER_RT_HAS_EXPLICIT_DEFAULT_TARGET_TRIPLE FALSE)
277  endif()
278endmacro()
279
280# Filter out generic versions of routines that are re-implemented in
281# architecture specific manner.  This prevents multiple definitions of the
282# same symbols, making the symbol selection non-deterministic.
283function(filter_builtin_sources output_var exclude_or_include excluded_list)
284  if(exclude_or_include STREQUAL "EXCLUDE")
285    set(filter_action GREATER)
286    set(filter_value -1)
287  elseif(exclude_or_include STREQUAL "INCLUDE")
288    set(filter_action LESS)
289    set(filter_value 0)
290  else()
291    message(FATAL_ERROR "filter_builtin_sources called without EXCLUDE|INCLUDE")
292  endif()
293
294  set(intermediate ${ARGN})
295  foreach (_file ${intermediate})
296    get_filename_component(_name_we ${_file} NAME_WE)
297    list(FIND ${excluded_list} ${_name_we} _found)
298    if(_found ${filter_action} ${filter_value})
299      list(REMOVE_ITEM intermediate ${_file})
300    elseif(${_file} MATCHES ".*/.*\\.S" OR ${_file} MATCHES ".*/.*\\.c")
301      get_filename_component(_name ${_file} NAME)
302      string(REPLACE ".S" ".c" _cname "${_name}")
303      list(REMOVE_ITEM intermediate ${_cname})
304    endif ()
305  endforeach ()
306  set(${output_var} ${intermediate} PARENT_SCOPE)
307endfunction()
308