1# On Windows, CMAKE_*_FLAGS are built for MSVC but we use the GCC clang.exe,
2# which uses completely different flags. Translate some common flag types, and
3# drop the rest.
4function(translate_msvc_cflags out_flags msvc_flags)
5  # Insert an empty string in the list to simplify processing.
6  set(msvc_flags ";${msvc_flags}")
7
8  # Canonicalize /flag to -flag.
9  string(REPLACE ";/" ";-" msvc_flags "${msvc_flags}")
10
11  # Make space separated -D and -U flags into joined flags.
12  string(REGEX REPLACE ";-\([DU]\);" ";-\\1" msvc_flags "${msvc_flags}")
13
14  set(clang_flags "")
15  foreach(flag ${msvc_flags})
16    if ("${flag}" MATCHES "^-[DU]")
17      # Pass through basic command line macro definitions (-DNDEBUG).
18      list(APPEND clang_flags "${flag}")
19    elseif ("${flag}" MATCHES "^-O[2x]")
20      # Canonicalize normal optimization flags to -O2.
21      list(APPEND clang_flags "-O2")
22    endif()
23  endforeach()
24  set(${out_flags} "${clang_flags}" PARENT_SCOPE)
25endfunction()
26
27if (APPLE)
28  # On Darwin if /usr/include doesn't exist, the user probably has Xcode but not
29  # the command line tools. If this is the case, we need to find the OS X
30  # sysroot to pass to clang.
31  if(NOT EXISTS /usr/include)
32    execute_process(COMMAND xcodebuild -version -sdk macosx Path
33       OUTPUT_VARIABLE OSX_SYSROOT
34       ERROR_QUIET
35       OUTPUT_STRIP_TRAILING_WHITESPACE)
36    set(OSX_SYSROOT_FLAG "-isysroot${OSX_SYSROOT}")
37  endif()
38endif()
39
40# Compile a source into an object file with COMPILER_RT_TEST_COMPILER using
41# a provided compile flags and dependenices.
42# clang_compile(<object> <source>
43#               CFLAGS <list of compile flags>
44#               DEPS <list of dependencies>)
45macro(clang_compile object_file source)
46  cmake_parse_arguments(SOURCE "" "" "CFLAGS;DEPS" ${ARGN})
47  get_filename_component(source_rpath ${source} REALPATH)
48  if(NOT COMPILER_RT_STANDALONE_BUILD)
49    list(APPEND SOURCE_DEPS clang compiler-rt-headers)
50  endif()
51  if (TARGET CompilerRTUnitTestCheckCxx)
52    list(APPEND SOURCE_DEPS CompilerRTUnitTestCheckCxx)
53  endif()
54  string(REGEX MATCH "[.](cc|cpp)$" is_cxx ${source_rpath})
55  if(is_cxx)
56    string(REPLACE " " ";" global_flags "${CMAKE_CXX_FLAGS}")
57  else()
58    string(REPLACE " " ";" global_flags "${CMAKE_C_FLAGS}")
59  endif()
60
61  if (MSVC)
62    translate_msvc_cflags(global_flags "${global_flags}")
63  endif()
64
65  if (APPLE)
66    set(global_flags ${OSX_SYSROOT_FLAG} ${global_flags})
67  endif()
68
69  # Ignore unknown warnings. CMAKE_CXX_FLAGS may contain GCC-specific options
70  # which are not supported by Clang.
71  list(APPEND global_flags -Wno-unknown-warning-option)
72  set(compile_flags ${global_flags} ${SOURCE_CFLAGS})
73  add_custom_command(
74    OUTPUT ${object_file}
75    COMMAND ${COMPILER_RT_TEST_COMPILER} ${compile_flags} -c
76            -o "${object_file}"
77            ${source_rpath}
78    MAIN_DEPENDENCY ${source}
79    DEPENDS ${SOURCE_DEPS})
80endmacro()
81
82# On Darwin, there are no system-wide C++ headers and the just-built clang is
83# therefore not able to compile C++ files unless they are copied/symlinked into
84# ${LLVM_BINARY_DIR}/include/c++
85# The just-built clang is used to build compiler-rt unit tests. Let's detect
86# this before we try to build the tests and print out a suggestion how to fix
87# it.
88# On other platforms, this is currently not an issue.
89macro(clang_compiler_add_cxx_check)
90  if (APPLE)
91    set(CMD
92      "echo '#include <iostream>' | ${COMPILER_RT_TEST_COMPILER} ${OSX_SYSROOT_FLAG} -E -x c++ - > /dev/null"
93      "if [ $? != 0 ] "
94      "  then echo"
95      "  echo 'Your just-built clang cannot find C++ headers, which are needed to build and run compiler-rt tests.'"
96      "  echo 'You should copy or symlink your system C++ headers into ${LLVM_BINARY_DIR}/include/c++'"
97      "  if [ -d $(dirname $(dirname $(xcrun -f clang)))/include/c++ ]"
98      "    then echo 'e.g. with:'"
99      "    echo '  cp -r' $(dirname $(dirname $(xcrun -f clang)))/include/c++ '${LLVM_BINARY_DIR}/include/'"
100      "  elif [ -d $(dirname $(dirname $(xcrun -f clang)))/lib/c++ ]"
101      "    then echo 'e.g. with:'"
102      "    echo '  cp -r' $(dirname $(dirname $(xcrun -f clang)))/lib/c++ '${LLVM_BINARY_DIR}/include/'"
103      "  fi"
104      "  echo 'This can also be fixed by checking out the libcxx project from llvm.org and installing the headers'"
105      "  echo 'into your build directory:'"
106      "  echo '  cd ${LLVM_SOURCE_DIR}/projects && svn co http://llvm.org/svn/llvm-project/libcxx/trunk libcxx'"
107      "  echo '  cd ${LLVM_BINARY_DIR} && make -C ${LLVM_SOURCE_DIR}/projects/libcxx installheaders HEADER_DIR=${LLVM_BINARY_DIR}/include'"
108      "  echo"
109      "  false"
110      "fi"
111      )
112    add_custom_target(CompilerRTUnitTestCheckCxx
113      COMMAND bash -c "${CMD}"
114      COMMENT "Checking that just-built clang can find C++ headers..."
115      VERBATIM)
116    if (TARGET clang)
117      ADD_DEPENDENCIES(CompilerRTUnitTestCheckCxx clang)
118    endif()
119  endif()
120endmacro()
121