1include(ExternalProject)
2include(CompilerRTUtils)
3
4# Tries to add an "object library" target for a given list of OSs and/or
5# architectures with name "<name>.<arch>" for non-Darwin platforms if
6# architecture can be targeted, and "<name>.<os>" for Darwin platforms.
7# add_compiler_rt_object_libraries(<name>
8#                                  OS <os names>
9#                                  ARCHS <architectures>
10#                                  SOURCES <source files>
11#                                  CFLAGS <compile flags>
12#                                  DEFS <compile definitions>)
13function(add_compiler_rt_object_libraries name)
14  cmake_parse_arguments(LIB "" "" "OS;ARCHS;SOURCES;CFLAGS;DEFS" ${ARGN})
15  set(libnames)
16  if(APPLE)
17    foreach(os ${LIB_OS})
18      set(libname "${name}.${os}")
19      set(libnames ${libnames} ${libname})
20      set(extra_cflags_${libname} ${DARWIN_${os}_CFLAGS})
21      list_intersect(LIB_ARCHS_${libname} DARWIN_${os}_ARCHS LIB_ARCHS)
22    endforeach()
23  else()
24    foreach(arch ${LIB_ARCHS})
25      set(libname "${name}.${arch}")
26      set(libnames ${libnames} ${libname})
27      set(extra_cflags_${libname} ${TARGET_${arch}_CFLAGS})
28      if(NOT CAN_TARGET_${arch})
29        message(FATAL_ERROR "Architecture ${arch} can't be targeted")
30        return()
31      endif()
32    endforeach()
33  endif()
34
35  foreach(libname ${libnames})
36    add_library(${libname} OBJECT ${LIB_SOURCES})
37    set_target_compile_flags(${libname}
38      ${CMAKE_CXX_FLAGS} ${extra_cflags_${libname}} ${LIB_CFLAGS})
39    set_property(TARGET ${libname} APPEND PROPERTY
40      COMPILE_DEFINITIONS ${LIB_DEFS})
41    if(APPLE)
42      set_target_properties(${libname} PROPERTIES
43        OSX_ARCHITECTURES "${LIB_ARCHS_${libname}}")
44    endif()
45  endforeach()
46endfunction()
47
48# Takes a list of object library targets, and a suffix and appends the proper
49# TARGET_OBJECTS string to the output variable.
50# format_object_libs(<output> <suffix> ...)
51macro(format_object_libs output suffix)
52  foreach(lib ${ARGN})
53    list(APPEND ${output} $<TARGET_OBJECTS:${lib}.${suffix}>)
54  endforeach()
55endmacro()
56
57# Adds static or shared runtime for a list of architectures and operating
58# systems and puts it in the proper directory in the build and install trees.
59# add_compiler_rt_runtime(<name>
60#                         {STATIC|SHARED}
61#                         ARCHS <architectures>
62#                         OS <os list>
63#                         SOURCES <source files>
64#                         CFLAGS <compile flags>
65#                         LINKFLAGS <linker flags>
66#                         DEFS <compile definitions>
67#                         LINK_LIBS <linked libraries> (only for shared library)
68#                         OBJECT_LIBS <object libraries to use as sources>
69#                         PARENT_TARGET <convenience parent target>)
70function(add_compiler_rt_runtime name type)
71  if(NOT type MATCHES "^(STATIC|SHARED)$")
72    message(FATAL_ERROR "type argument must be STATIC or SHARED")
73    return()
74  endif()
75  cmake_parse_arguments(LIB
76    ""
77    "PARENT_TARGET"
78    "OS;ARCHS;SOURCES;CFLAGS;LINKFLAGS;DEFS;LINK_LIBS;OBJECT_LIBS"
79    ${ARGN})
80  set(libnames)
81  if(APPLE)
82    foreach(os ${LIB_OS})
83      if(type STREQUAL "STATIC")
84        set(libname "${name}_${os}")
85      else()
86        set(libname "${name}_${os}_dynamic")
87        set(extra_linkflags_${libname} ${DARWIN_${os}_LINKFLAGS} ${LIB_LINKFLAGS})
88      endif()
89      list_intersect(LIB_ARCHS_${libname} DARWIN_${os}_ARCHS LIB_ARCHS)
90      if(LIB_ARCHS_${libname})
91        list(APPEND libnames ${libname})
92        set(extra_cflags_${libname} ${DARWIN_${os}_CFLAGS} ${LIB_CFLAGS})
93        set(output_name_${libname} ${libname}${COMPILER_RT_OS_SUFFIX})
94        set(sources_${libname} ${LIB_SOURCES})
95        format_object_libs(sources_${libname} ${os} ${LIB_OBJECT_LIBS})
96      endif()
97    endforeach()
98  else()
99    foreach(arch ${LIB_ARCHS})
100      if(NOT CAN_TARGET_${arch})
101        message(FATAL_ERROR "Architecture ${arch} can't be targeted")
102        return()
103      endif()
104      if(type STREQUAL "STATIC")
105        set(libname "${name}-${arch}")
106        set(output_name_${libname} ${libname}${COMPILER_RT_OS_SUFFIX})
107      else()
108        set(libname "${name}-dynamic-${arch}")
109        set(extra_linkflags_${libname} ${TARGET_${arch}_CFLAGS} ${LIB_CFLAGS} ${LIB_LINKFLAGS})
110        if(WIN32)
111          set(output_name_${libname} ${name}_dynamic-${arch}${COMPILER_RT_OS_SUFFIX})
112        else()
113          set(output_name_${libname} ${name}-${arch}${COMPILER_RT_OS_SUFFIX})
114        endif()
115      endif()
116      set(sources_${libname} ${LIB_SOURCES})
117      format_object_libs(sources_${libname} ${arch} ${LIB_OBJECT_LIBS})
118      set(libnames ${libnames} ${libname})
119      set(extra_cflags_${libname} ${TARGET_${arch}_CFLAGS} ${LIB_CFLAGS})
120    endforeach()
121  endif()
122
123  if(NOT libnames)
124    return()
125  endif()
126
127  if(LIB_PARENT_TARGET)
128    set(COMPONENT_OPTION COMPONENT ${LIB_PARENT_TARGET})
129  endif()
130
131  foreach(libname ${libnames})
132    add_library(${libname} ${type} ${sources_${libname}})
133    set_target_compile_flags(${libname} ${extra_cflags_${libname}})
134    set_target_link_flags(${libname} ${extra_linkflags_${libname}})
135    set_property(TARGET ${libname} APPEND PROPERTY
136                COMPILE_DEFINITIONS ${LIB_DEFS})
137    set_target_properties(${libname} PROPERTIES
138        ARCHIVE_OUTPUT_DIRECTORY ${COMPILER_RT_LIBRARY_OUTPUT_DIR}
139        LIBRARY_OUTPUT_DIRECTORY ${COMPILER_RT_LIBRARY_OUTPUT_DIR}
140        RUNTIME_OUTPUT_DIRECTORY ${COMPILER_RT_LIBRARY_OUTPUT_DIR})
141    set_target_properties(${libname} PROPERTIES
142        OUTPUT_NAME ${output_name_${libname}})
143    if(LIB_LINK_LIBS AND ${type} STREQUAL "SHARED")
144      target_link_libraries(${libname} ${LIB_LINK_LIBS})
145    endif()
146    install(TARGETS ${libname}
147      ARCHIVE DESTINATION ${COMPILER_RT_LIBRARY_INSTALL_DIR}
148              ${COMPONENT_OPTION}
149      LIBRARY DESTINATION ${COMPILER_RT_LIBRARY_INSTALL_DIR}
150              ${COMPONENT_OPTION}
151      RUNTIME DESTINATION ${COMPILER_RT_LIBRARY_INSTALL_DIR}
152              ${COMPONENT_OPTION})
153    if(APPLE)
154      set_target_properties(${libname} PROPERTIES
155      OSX_ARCHITECTURES "${LIB_ARCHS_${libname}}")
156    endif()
157
158    if(type STREQUAL "SHARED")
159      rt_externalize_debuginfo(${libname})
160    endif()
161  endforeach()
162  if(LIB_PARENT_TARGET)
163    add_dependencies(${LIB_PARENT_TARGET} ${libnames})
164  endif()
165endfunction()
166
167# when cross compiling, COMPILER_RT_TEST_COMPILER_CFLAGS help
168# in compilation and linking of unittests.
169string(REPLACE " " ";" COMPILER_RT_UNITTEST_CFLAGS "${COMPILER_RT_TEST_COMPILER_CFLAGS}")
170set(COMPILER_RT_UNITTEST_LINKFLAGS ${COMPILER_RT_UNITTEST_CFLAGS})
171
172# Unittests support.
173set(COMPILER_RT_GTEST_PATH ${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest)
174set(COMPILER_RT_GTEST_SOURCE ${COMPILER_RT_GTEST_PATH}/src/gtest-all.cc)
175set(COMPILER_RT_GTEST_CFLAGS
176  -DGTEST_NO_LLVM_RAW_OSTREAM=1
177  -DGTEST_HAS_RTTI=0
178  -I${COMPILER_RT_GTEST_PATH}/include
179  -I${COMPILER_RT_GTEST_PATH}
180)
181
182append_list_if(COMPILER_RT_DEBUG -DSANITIZER_DEBUG=1 COMPILER_RT_UNITTEST_CFLAGS)
183
184if(MSVC)
185  # clang doesn't support exceptions on Windows yet.
186  list(APPEND COMPILER_RT_UNITTEST_CFLAGS -D_HAS_EXCEPTIONS=0)
187
188  # We should teach clang to understand "#pragma intrinsic", see PR19898.
189  list(APPEND COMPILER_RT_UNITTEST_CFLAGS -Wno-undefined-inline)
190
191  # Clang doesn't support SEH on Windows yet.
192  list(APPEND COMPILER_RT_GTEST_CFLAGS -DGTEST_HAS_SEH=0)
193
194  # gtest use a lot of stuff marked as deprecated on Windows.
195  list(APPEND COMPILER_RT_GTEST_CFLAGS -Wno-deprecated-declarations)
196
197  # Visual Studio 2012 only supports up to 8 template parameters in
198  # std::tr1::tuple by default, but gtest requires 10
199  if(MSVC_VERSION EQUAL 1700)
200    list(APPEND COMPILER_RT_GTEST_CFLAGS -D_VARIADIC_MAX=10)
201  endif()
202endif()
203
204# Link objects into a single executable with COMPILER_RT_TEST_COMPILER,
205# using specified link flags. Make executable a part of provided
206# test_suite.
207# add_compiler_rt_test(<test_suite> <test_name>
208#                      SUBDIR <subdirectory for binary>
209#                      OBJECTS <object files>
210#                      DEPS <deps (e.g. runtime libs)>
211#                      LINK_FLAGS <link flags>)
212macro(add_compiler_rt_test test_suite test_name)
213  cmake_parse_arguments(TEST "" "SUBDIR" "OBJECTS;DEPS;LINK_FLAGS" "" ${ARGN})
214  if(TEST_SUBDIR)
215    set(output_bin "${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUBDIR}/${test_name}")
216  else()
217    set(output_bin "${CMAKE_CURRENT_BINARY_DIR}/${test_name}")
218  endif()
219  if(MSVC)
220    set(output_bin "${output_bin}.exe")
221  endif()
222  # Use host compiler in a standalone build, and just-built Clang otherwise.
223  if(NOT COMPILER_RT_STANDALONE_BUILD)
224    list(APPEND TEST_DEPS clang)
225  endif()
226  # If we're not on MSVC, include the linker flags from CMAKE but override them
227  # with the provided link flags. This ensures that flags which are required to
228  # link programs at all are included, but the changes needed for the test
229  # trump. With MSVC we can't do that because CMake is set up to run link.exe
230  # when linking, not the compiler. Here, we hack it to use the compiler
231  # because we want to use -fsanitize flags.
232  if(NOT MSVC)
233    set(TEST_LINK_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${TEST_LINK_FLAGS}")
234    separate_arguments(TEST_LINK_FLAGS)
235  endif()
236  add_custom_target(${test_name}
237    COMMAND ${COMPILER_RT_TEST_COMPILER} ${TEST_OBJECTS}
238            -o "${output_bin}"
239            ${TEST_LINK_FLAGS}
240    DEPENDS ${TEST_DEPS})
241  # Make the test suite depend on the binary.
242  add_dependencies(${test_suite} ${test_name})
243endmacro()
244
245macro(add_compiler_rt_resource_file target_name file_name)
246  set(src_file "${CMAKE_CURRENT_SOURCE_DIR}/${file_name}")
247  set(dst_file "${COMPILER_RT_OUTPUT_DIR}/${file_name}")
248  add_custom_command(OUTPUT ${dst_file}
249    DEPENDS ${src_file}
250    COMMAND ${CMAKE_COMMAND} -E copy_if_different ${src_file} ${dst_file}
251    COMMENT "Copying ${file_name}...")
252  add_custom_target(${target_name} DEPENDS ${dst_file})
253  # Install in Clang resource directory.
254  install(FILES ${file_name} DESTINATION ${COMPILER_RT_INSTALL_PATH})
255endmacro()
256
257macro(add_compiler_rt_script name)
258  set(dst ${COMPILER_RT_EXEC_OUTPUT_DIR}/${name})
259  set(src ${CMAKE_CURRENT_SOURCE_DIR}/${name})
260  add_custom_command(OUTPUT ${dst}
261    DEPENDS ${src}
262    COMMAND ${CMAKE_COMMAND} -E copy_if_different ${src} ${dst}
263    COMMENT "Copying ${name}...")
264  add_custom_target(${name} DEPENDS ${dst})
265  install(FILES ${dst}
266    PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE
267    DESTINATION ${COMPILER_RT_INSTALL_PATH}/bin)
268endmacro(add_compiler_rt_script src name)
269
270# Builds custom version of libc++ and installs it in <prefix>.
271# Can be used to build sanitized versions of libc++ for running unit tests.
272# add_custom_libcxx(<name> <prefix>
273#                   DEPS <list of build deps>
274#                   CFLAGS <list of compile flags>)
275macro(add_custom_libcxx name prefix)
276  if(NOT COMPILER_RT_HAS_LIBCXX_SOURCES)
277    message(FATAL_ERROR "libcxx not found!")
278  endif()
279
280  cmake_parse_arguments(LIBCXX "" "" "DEPS;CFLAGS" ${ARGN})
281  foreach(flag ${LIBCXX_CFLAGS})
282    set(flagstr "${flagstr} ${flag}")
283  endforeach()
284  set(LIBCXX_CFLAGS ${flagstr})
285
286  if(NOT COMPILER_RT_STANDALONE_BUILD)
287    list(APPEND LIBCXX_DEPS clang)
288  endif()
289
290  ExternalProject_Add(${name}
291    PREFIX ${prefix}
292    SOURCE_DIR ${COMPILER_RT_LIBCXX_PATH}
293    CMAKE_ARGS -DCMAKE_MAKE_PROGRAM:STRING=${CMAKE_MAKE_PROGRAM}
294               -DCMAKE_C_COMPILER=${COMPILER_RT_TEST_COMPILER}
295               -DCMAKE_CXX_COMPILER=${COMPILER_RT_TEST_CXX_COMPILER}
296               -DCMAKE_C_FLAGS=${LIBCXX_CFLAGS}
297               -DCMAKE_CXX_FLAGS=${LIBCXX_CFLAGS}
298               -DCMAKE_BUILD_TYPE=Release
299               -DCMAKE_INSTALL_PREFIX:PATH=<INSTALL_DIR>
300               -DLLVM_PATH=${LLVM_MAIN_SRC_DIR}
301    LOG_BUILD 1
302    LOG_CONFIGURE 1
303    LOG_INSTALL 1
304    )
305  set_target_properties(${name} PROPERTIES EXCLUDE_FROM_ALL TRUE)
306
307  ExternalProject_Add_Step(${name} force-reconfigure
308    DEPENDERS configure
309    ALWAYS 1
310    )
311
312  ExternalProject_Add_Step(${name} clobber
313    COMMAND ${CMAKE_COMMAND} -E remove_directory <BINARY_DIR>
314    COMMAND ${CMAKE_COMMAND} -E make_directory <BINARY_DIR>
315    COMMENT "Clobberring ${name} build directory..."
316    DEPENDERS configure
317    DEPENDS ${LIBCXX_DEPS}
318    )
319endmacro()
320
321function(rt_externalize_debuginfo name)
322  if(NOT COMPILER_RT_EXTERNALIZE_DEBUGINFO)
323    return()
324  endif()
325
326  if(APPLE)
327    if(CMAKE_CXX_FLAGS MATCHES "-flto"
328      OR CMAKE_CXX_FLAGS_${uppercase_CMAKE_BUILD_TYPE} MATCHES "-flto")
329
330      set(lto_object ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/${name}-lto.o)
331      set_property(TARGET ${name} APPEND_STRING PROPERTY
332        LINK_FLAGS " -Wl,-object_path_lto -Wl,${lto_object}")
333    endif()
334    add_custom_command(TARGET ${name} POST_BUILD
335      COMMAND xcrun dsymutil $<TARGET_FILE:${name}>
336      COMMAND xcrun strip -Sl $<TARGET_FILE:${name}>)
337  else()
338    message(FATAL_ERROR "COMPILER_RT_EXTERNALIZE_DEBUGINFO isn't implemented for non-darwin platforms!")
339  endif()
340endfunction()
341