xref: /linux-6.15/scripts/checkstack.pl (revision d089622b) 
1#!/usr/bin/env perl
2# SPDX-License-Identifier: GPL-2.0
3
4#	Check the stack usage of functions
5#
6#	Copyright Joern Engel <[email protected]>
7#	Inspired by Linus Torvalds
8#	Original idea maybe from Keith Owens
9#	s390 port and big speedup by Arnd Bergmann <[email protected]>
10#	Mips port by Juan Quintela <[email protected]>
11#	IA64 port via Andreas Dilger
12#	Arm port by Holger Schurig
13#	Random bits by Matt Mackall <[email protected]>
14#	M68k port by Geert Uytterhoeven and Andreas Schwab
15#	AArch64, PARISC ports by Kyle McMartin
16#	sparc port by Martin Habets <[email protected]>
17#	ppc64le port by Breno Leitao <[email protected]>
18#	riscv port by Wadim Mueller <[email protected]>
19#	loongarch port by Youling Tang <[email protected]>
20#
21#	Usage:
22#	objdump -d vmlinux | scripts/checkstack.pl [arch]
23#
24#	TODO :	Port to all architectures (one regex per arch)
25
26use strict;
27
28# check for arch
29#
30# $re is used for two matches:
31# $& (whole re) matches the complete objdump line with the stack growth
32# $1 (first bracket) matches the size of the stack growth
33#
34# $dre is similar, but for dynamic stack redutions:
35# $& (whole re) matches the complete objdump line with the stack growth
36# $1 (first bracket) matches the dynamic amount of the stack growth
37#
38# $sub: subroutine for special handling to check stack usage.
39#
40# use anything else and feel the pain ;)
41my (@stack, $re, $dre, $sub, $x, $xs, $funcre, $min_stack);
42{
43	my $arch = shift;
44	if ($arch eq "") {
45		$arch = `uname -m`;
46		chomp($arch);
47	}
48
49	$min_stack = shift;
50	if ($min_stack eq "" || $min_stack !~ /^\d+$/) {
51		$min_stack = 100;
52	}
53
54	$x	= "[0-9a-f]";	# hex character
55	$xs	= "[0-9a-f ]";	# hex character or space
56	$funcre = qr/^$x* <(.*)>:$/;
57	if ($arch =~ '^(aarch|arm)64$') {
58		#ffffffc0006325cc:       a9bb7bfd        stp     x29, x30, [sp, #-80]!
59		#a110:       d11643ff        sub     sp, sp, #0x590
60		$re = qr/^.*stp.*sp, \#-([0-9]{1,8})\]\!/o;
61		$dre = qr/^.*sub.*sp, sp, #(0x$x{1,8})/o;
62	} elsif ($arch eq 'arm') {
63		#c0008ffc:	e24dd064	sub	sp, sp, #100	; 0x64
64		$re = qr/.*sub.*sp, sp, #([0-9]{1,4})/o;
65		$sub = \&arm_push_handling;
66	} elsif ($arch =~ /^x86(_64)?$/ || $arch =~ /^i[3456]86$/) {
67		#c0105234:       81 ec ac 05 00 00       sub    $0x5ac,%esp
68		# or
69		#    2f60:    48 81 ec e8 05 00 00       sub    $0x5e8,%rsp
70		$re = qr/^.*[as][du][db]    \$(0x$x{1,8}),\%(e|r)sp$/o;
71		$dre = qr/^.*[as][du][db]    (%.*),\%(e|r)sp$/o;
72	} elsif ($arch eq 'ia64') {
73		#e0000000044011fc:       01 0f fc 8c     adds r12=-384,r12
74		$re = qr/.*adds.*r12=-(([0-9]{2}|[3-9])[0-9]{2}),r12/o;
75	} elsif ($arch eq 'm68k') {
76		#    2b6c:       4e56 fb70       linkw %fp,#-1168
77		#  1df770:       defc ffe4       addaw #-28,%sp
78		$re = qr/.*(?:linkw %fp,|addaw )#-([0-9]{1,4})(?:,%sp)?$/o;
79	} elsif ($arch eq 'mips64') {
80		#8800402c:       67bdfff0        daddiu  sp,sp,-16
81		$re = qr/.*daddiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
82	} elsif ($arch eq 'mips') {
83		#88003254:       27bdffe0        addiu   sp,sp,-32
84		$re = qr/.*addiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
85	} elsif ($arch eq 'nios2') {
86		#25a8:	defffb04 	addi	sp,sp,-20
87		$re = qr/.*addi.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
88	} elsif ($arch eq 'openrisc') {
89		# c000043c:       9c 21 fe f0     l.addi r1,r1,-272
90		$re = qr/.*l\.addi.*r1,r1,-(([0-9]{2}|[3-9])[0-9]{2})/o;
91	} elsif ($arch eq 'parisc' || $arch eq 'parisc64') {
92		$re = qr/.*ldo ($x{1,8})\(sp\),sp/o;
93	} elsif ($arch eq 'powerpc' || $arch =~ /^ppc(64)?(le)?$/ ) {
94		# powerpc    : 94 21 ff 30     stwu    r1,-208(r1)
95		# ppc64(le)  : 81 ff 21 f8     stdu    r1,-128(r1)
96		$re = qr/.*st[dw]u.*r1,-($x{1,8})\(r1\)/o;
97	} elsif ($arch =~ /^s390x?$/) {
98		#   11160:       a7 fb ff 60             aghi   %r15,-160
99		# or
100		#  100092:	 e3 f0 ff c8 ff 71	 lay	 %r15,-56(%r15)
101		$re = qr/.*(?:lay|ag?hi).*\%r15,-([0-9]+)(?:\(\%r15\))?$/o;
102	} elsif ($arch eq 'sparc' || $arch eq 'sparc64') {
103		# f0019d10:       9d e3 bf 90     save  %sp, -112, %sp
104		$re = qr/.*save.*%sp, -(([0-9]{2}|[3-9])[0-9]{2}), %sp/o;
105	} elsif ($arch =~ /^riscv(64)?$/) {
106		#ffffffff8036e868:	c2010113          	addi	sp,sp,-992
107		$re = qr/.*addi.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
108	} elsif ($arch =~ /^loongarch(32|64)?$/) {
109		#9000000000224708:	02ff4063		addi.d  $sp, $sp, -48(0xfd0)
110		$re = qr/.*addi\..*sp, .*sp, -([0-9]{1,8}).*/o;
111	} else {
112		print("wrong or unknown architecture \"$arch\"\n");
113		exit
114	}
115}
116
117#
118# To count stack usage of push {*, fp, ip, lr, pc} instruction in ARM,
119# if FRAME POINTER is enabled.
120# e.g. c01f0d48: e92ddff0 push {r4, r5, r6, r7, r8, r9, sl, fp, ip, lr, pc}
121#
122sub arm_push_handling {
123	my $regex = qr/.*push.*fp, ip, lr, pc}/o;
124	my $size = 0;
125	my $line_arg = shift;
126
127	if ($line_arg =~ m/$regex/) {
128		$size = $line_arg =~ tr/,//;
129		$size = ($size + 1) * 4;
130	}
131
132	return $size;
133}
134
135#
136# main()
137#
138my ($func, $file, $lastslash, $total_size, $addr, $intro);
139
140$total_size = 0;
141
142while (my $line = <STDIN>) {
143	if ($line =~ m/$funcre/) {
144		$func = $1;
145		next if $line !~ m/^($x*)/;
146		if ($total_size > $min_stack) {
147			push @stack, "$intro$total_size\n";
148		}
149		$addr = "0x$1";
150		$intro = "$addr $func [$file]:";
151		my $padlen = 56 - length($intro);
152		while ($padlen > 0) {
153			$intro .= '	';
154			$padlen -= 8;
155		}
156
157		$total_size = 0;
158	}
159	elsif ($line =~ m/(.*):\s*file format/) {
160		$file = $1;
161		$file =~ s/\.ko//;
162		$lastslash = rindex($file, "/");
163		if ($lastslash != -1) {
164			$file = substr($file, $lastslash + 1);
165		}
166	}
167	elsif ($line =~ m/$re/) {
168		my $size = $1;
169		$size = hex($size) if ($size =~ /^0x/);
170
171		if ($size > 0xf0000000) {
172			$size = - $size;
173			$size += 0x80000000;
174			$size += 0x80000000;
175		}
176		next if ($size > 0x10000000);
177
178		$total_size += $size;
179	}
180	elsif (defined $dre && $line =~ m/$dre/) {
181		my $size = $1;
182
183		$size = hex($size) if ($size =~ /^0x/);
184		$total_size += $size;
185	}
186	elsif (defined $sub) {
187		my $size = &$sub($line);
188
189		$total_size += $size;
190	}
191}
192if ($total_size > $min_stack) {
193	push @stack, "$intro$total_size\n";
194}
195
196# Sort output by size (last field) and function name if size is the same
197sub sort_lines {
198	my ($a, $b) = @_;
199
200	my $num_a = $1 if $a =~ /:\t*(\d+)$/;
201	my $num_b = $1 if $b =~ /:\t*(\d+)$/;
202	my $func_a = $1 if $a =~ / (.*):/;
203	my $func_b = $1 if $b =~ / (.*):/;
204
205	if ($num_a != $num_b) {
206		return $num_b <=> $num_a;
207	} else {
208		return $func_a cmp $func_b;
209	}
210}
211
212print sort { sort_lines($a, $b) } @stack;
213