xref: /linux-6.15/scripts/checkstack.pl (revision 572220aa) 
1#!/usr/bin/env perl
2# SPDX-License-Identifier: GPL-2.0
3
4#	Check the stack usage of functions
5#
6#	Copyright Joern Engel <[email protected]>
7#	Inspired by Linus Torvalds
8#	Original idea maybe from Keith Owens
9#	s390 port and big speedup by Arnd Bergmann <[email protected]>
10#	Mips port by Juan Quintela <[email protected]>
11#	IA64 port via Andreas Dilger
12#	Arm port by Holger Schurig
13#	sh64 port by Paul Mundt
14#	Random bits by Matt Mackall <[email protected]>
15#	M68k port by Geert Uytterhoeven and Andreas Schwab
16#	AArch64, PARISC ports by Kyle McMartin
17#	sparc port by Martin Habets <[email protected]>
18#	ppc64le port by Breno Leitao <[email protected]>
19#
20#	Usage:
21#	objdump -d vmlinux | scripts/checkstack.pl [arch]
22#
23#	TODO :	Port to all architectures (one regex per arch)
24
25use strict;
26
27# check for arch
28#
29# $re is used for two matches:
30# $& (whole re) matches the complete objdump line with the stack growth
31# $1 (first bracket) matches the size of the stack growth
32#
33# $dre is similar, but for dynamic stack redutions:
34# $& (whole re) matches the complete objdump line with the stack growth
35# $1 (first bracket) matches the dynamic amount of the stack growth
36#
37# use anything else and feel the pain ;)
38my (@stack, $re, $dre, $x, $xs, $funcre, $min_stack);
39{
40	my $arch = shift;
41	if ($arch eq "") {
42		$arch = `uname -m`;
43		chomp($arch);
44	}
45
46	$min_stack = shift;
47	if ($min_stack eq "" || $min_stack !~ /^\d+$/) {
48		$min_stack = 100;
49	}
50
51	$x	= "[0-9a-f]";	# hex character
52	$xs	= "[0-9a-f ]";	# hex character or space
53	$funcre = qr/^$x* <(.*)>:$/;
54	if ($arch =~ '^(aarch|arm)64$') {
55		#ffffffc0006325cc:       a9bb7bfd        stp     x29, x30, [sp, #-80]!
56		#a110:       d11643ff        sub     sp, sp, #0x590
57		$re = qr/^.*stp.*sp, \#-([0-9]{1,8})\]\!/o;
58		$dre = qr/^.*sub.*sp, sp, #(0x$x{1,8})/o;
59	} elsif ($arch eq 'arm') {
60		#c0008ffc:	e24dd064	sub	sp, sp, #100	; 0x64
61		$re = qr/.*sub.*sp, sp, #(([0-9]{2}|[3-9])[0-9]{2})/o;
62	} elsif ($arch =~ /^x86(_64)?$/ || $arch =~ /^i[3456]86$/) {
63		#c0105234:       81 ec ac 05 00 00       sub    $0x5ac,%esp
64		# or
65		#    2f60:    48 81 ec e8 05 00 00       sub    $0x5e8,%rsp
66		$re = qr/^.*[as][du][db]    \$(0x$x{1,8}),\%(e|r)sp$/o;
67		$dre = qr/^.*[as][du][db]    (%.*),\%(e|r)sp$/o;
68	} elsif ($arch eq 'ia64') {
69		#e0000000044011fc:       01 0f fc 8c     adds r12=-384,r12
70		$re = qr/.*adds.*r12=-(([0-9]{2}|[3-9])[0-9]{2}),r12/o;
71	} elsif ($arch eq 'm68k') {
72		#    2b6c:       4e56 fb70       linkw %fp,#-1168
73		#  1df770:       defc ffe4       addaw #-28,%sp
74		$re = qr/.*(?:linkw %fp,|addaw )#-([0-9]{1,4})(?:,%sp)?$/o;
75	} elsif ($arch eq 'mips64') {
76		#8800402c:       67bdfff0        daddiu  sp,sp,-16
77		$re = qr/.*daddiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
78	} elsif ($arch eq 'mips') {
79		#88003254:       27bdffe0        addiu   sp,sp,-32
80		$re = qr/.*addiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
81	} elsif ($arch eq 'nios2') {
82		#25a8:	defffb04 	addi	sp,sp,-20
83		$re = qr/.*addi.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
84	} elsif ($arch eq 'openrisc') {
85		# c000043c:       9c 21 fe f0     l.addi r1,r1,-272
86		$re = qr/.*l\.addi.*r1,r1,-(([0-9]{2}|[3-9])[0-9]{2})/o;
87	} elsif ($arch eq 'parisc' || $arch eq 'parisc64') {
88		$re = qr/.*ldo ($x{1,8})\(sp\),sp/o;
89	} elsif ($arch eq 'powerpc' || $arch =~ /^ppc(64)?(le)?$/ ) {
90		# powerpc    : 94 21 ff 30     stwu    r1,-208(r1)
91		# ppc64(le)  : 81 ff 21 f8     stdu    r1,-128(r1)
92		$re = qr/.*st[dw]u.*r1,-($x{1,8})\(r1\)/o;
93	} elsif ($arch =~ /^s390x?$/) {
94		#   11160:       a7 fb ff 60             aghi   %r15,-160
95		# or
96		#  100092:	 e3 f0 ff c8 ff 71	 lay	 %r15,-56(%r15)
97		$re = qr/.*(?:lay|ag?hi).*\%r15,-(([0-9]{2}|[3-9])[0-9]{2})
98		      (?:\(\%r15\))?$/ox;
99	} elsif ($arch =~ /^sh64$/) {
100		#XXX: we only check for the immediate case presently,
101		#     though we will want to check for the movi/sub
102		#     pair for larger users. -- PFM.
103		#a00048e0:       d4fc40f0        addi.l  r15,-240,r15
104		$re = qr/.*addi\.l.*r15,-(([0-9]{2}|[3-9])[0-9]{2}),r15/o;
105	} elsif ($arch eq 'sparc' || $arch eq 'sparc64') {
106		# f0019d10:       9d e3 bf 90     save  %sp, -112, %sp
107		$re = qr/.*save.*%sp, -(([0-9]{2}|[3-9])[0-9]{2}), %sp/o;
108	} else {
109		print("wrong or unknown architecture \"$arch\"\n");
110		exit
111	}
112}
113
114#
115# main()
116#
117my ($func, $file, $lastslash, $total_size, $addr, $intro);
118
119$total_size = 0;
120
121while (my $line = <STDIN>) {
122	if ($line =~ m/$funcre/) {
123		$func = $1;
124		next if $line !~ m/^($xs*)/;
125		if ($total_size > $min_stack) {
126			push @stack, "$intro$total_size\n";
127		}
128
129		$addr = $1;
130		$addr =~ s/ /0/g;
131		$addr = "0x$addr";
132
133		$intro = "$addr $func [$file]:";
134		my $padlen = 56 - length($intro);
135		while ($padlen > 0) {
136			$intro .= '	';
137			$padlen -= 8;
138		}
139
140		$total_size = 0;
141	}
142	elsif ($line =~ m/(.*):\s*file format/) {
143		$file = $1;
144		$file =~ s/\.ko//;
145		$lastslash = rindex($file, "/");
146		if ($lastslash != -1) {
147			$file = substr($file, $lastslash + 1);
148		}
149	}
150	elsif ($line =~ m/$re/) {
151		my $size = $1;
152		$size = hex($size) if ($size =~ /^0x/);
153
154		if ($size > 0xf0000000) {
155			$size = - $size;
156			$size += 0x80000000;
157			$size += 0x80000000;
158		}
159		next if ($size > 0x10000000);
160
161		$total_size += $size;
162	}
163	elsif (defined $dre && $line =~ m/$dre/) {
164		my $size = $1;
165
166		$size = hex($size) if ($size =~ /^0x/);
167		$total_size += $size;
168	}
169}
170if ($total_size > $min_stack) {
171	push @stack, "$intro$total_size\n";
172}
173
174# Sort output by size (last field)
175print sort { ($b =~ /:\t*(\d+)$/)[0] <=> ($a =~ /:\t*(\d+)$/)[0] } @stack;
176