xref: /dpdk/config/meson.build (revision e5f7bd19) 
1# SPDX-License-Identifier: BSD-3-Clause
2# Copyright(c) 2017-2019 Intel Corporation
3
4# check the OS is supported, rather than going any further
5supported_exec_envs = ['freebsd', 'linux', 'windows']
6exec_env = host_machine.system()
7if not supported_exec_envs.contains(exec_env)
8	error('unsupported system type "@0@"'.format(exec_env))
9endif
10
11# define a handy variable for checking which OS we have.
12# gives us "is_windows", "is_freebsd" and "is_linux"
13foreach env:supported_exec_envs
14	set_variable('is_' + env, exec_env == env)
15endforeach
16
17# set the major version, which might be used by drivers and libraries
18# depending on the configuration options
19pver = meson.project_version().split('.')
20major_version = '@0@.@1@'.format(pver.get(0), pver.get(1))
21
22# extract all version information into the build configuration
23dpdk_conf.set('RTE_VER_YEAR', pver.get(0).to_int())
24dpdk_conf.set('RTE_VER_MONTH', pver.get(1).to_int())
25if pver.get(2).contains('-rc')
26	rc_ver = pver.get(2).split('-rc')
27	dpdk_conf.set('RTE_VER_MINOR', rc_ver.get(0).to_int())
28	dpdk_conf.set_quoted('RTE_VER_SUFFIX', '-rc')
29	dpdk_conf.set('RTE_VER_RELEASE', rc_ver.get(1).to_int())
30else
31	dpdk_conf.set('RTE_VER_MINOR', pver.get(2).to_int())
32	dpdk_conf.set_quoted('RTE_VER_SUFFIX', '')
33# for actual, non-rc releases, set the release value to 99 to ensure releases
34# have higher version numbers than their respective release candidates
35	dpdk_conf.set('RTE_VER_RELEASE', 99)
36endif
37
38pmd_subdir_opt = get_option('drivers_install_subdir')
39if pmd_subdir_opt.contains('<VERSION>')
40	pmd_subdir_opt = major_version.join(pmd_subdir_opt.split('<VERSION>'))
41endif
42driver_install_path = join_paths(get_option('libdir'), pmd_subdir_opt)
43eal_pmd_path = join_paths(get_option('prefix'), driver_install_path)
44
45# set the machine type and cflags for it
46if meson.is_cross_build()
47	machine = host_machine.cpu()
48else
49	machine = get_option('machine')
50endif
51
52# machine type 'default' is special, it defaults to the per arch agreed common
53# minimal baseline needed for DPDK.
54# That might not be the most optimized, but the most portable version while
55# still being able to support the CPU features required for DPDK.
56# This can be bumped up by the DPDK project, but it can never be an
57# invariant like 'native'
58if machine == 'default'
59	if host_machine.cpu_family().startswith('x86')
60		# matches the old pre-meson build systems default
61		machine = 'corei7'
62	elif host_machine.cpu_family().startswith('arm')
63		machine = 'armv7-a'
64	elif host_machine.cpu_family().startswith('aarch')
65		# arm64 manages defaults in config/arm/meson.build
66		machine = 'default'
67	elif host_machine.cpu_family().startswith('ppc')
68		machine = 'power8'
69	endif
70endif
71
72dpdk_conf.set('RTE_MACHINE', machine)
73machine_args = []
74
75# ppc64 does not support -march= at all, use -mcpu and -mtune for that
76if host_machine.cpu_family().startswith('ppc')
77	machine_args += '-mcpu=' + machine
78	machine_args += '-mtune=' + machine
79else
80	machine_args += '-march=' + machine
81endif
82
83toolchain = cc.get_id()
84dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
85dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
86
87dpdk_conf.set('RTE_ARCH_64', cc.sizeof('void *') == 8)
88
89add_project_link_arguments('-Wl,--no-as-needed', language: 'c')
90dpdk_extra_ldflags += '-Wl,--no-as-needed'
91
92# use pthreads
93add_project_link_arguments('-pthread', language: 'c')
94dpdk_extra_ldflags += '-pthread'
95
96# on some OS, maths functions are in a separate library
97if cc.find_library('libm', required : false).found()
98	# some libs depend on maths lib
99	add_project_link_arguments('-lm', language: 'c')
100	dpdk_extra_ldflags += '-lm'
101endif
102
103# for linux link against dl, for bsd execinfo
104if is_linux
105	link_lib = 'dl'
106elif is_freebsd
107	link_lib = 'execinfo'
108else
109	link_lib = ''
110endif
111
112# if link_lib is empty, do not add it to project properties
113if link_lib != ''
114	add_project_link_arguments('-l' + link_lib, language: 'c')
115	dpdk_extra_ldflags += '-l' + link_lib
116endif
117
118# check for libraries used in multiple places in DPDK
119has_libnuma = 0
120numa_dep = cc.find_library('numa', required: false)
121if numa_dep.found() and cc.has_header('numaif.h')
122	dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
123	has_libnuma = 1
124	add_project_link_arguments('-lnuma', language: 'c')
125	dpdk_extra_ldflags += '-lnuma'
126endif
127
128# check for strlcpy
129if is_linux
130	libbsd = dependency('libbsd', required: false)
131	if libbsd.found()
132		dpdk_conf.set('RTE_USE_LIBBSD', 1)
133	endif
134endif
135
136# add -include rte_config to cflags
137add_project_arguments('-include', 'rte_config.h', language: 'c')
138
139# enable extra warnings and disable any unwanted warnings
140warning_flags = [
141	'-Wsign-compare',
142	'-Wcast-qual',
143	'-Wno-address-of-packed-member'
144]
145if not dpdk_conf.get('RTE_ARCH_64')
146# for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
147	warning_flags += '-Wno-pointer-to-int-cast'
148endif
149foreach arg: warning_flags
150	if cc.has_argument(arg)
151		add_project_arguments(arg, language: 'c')
152	endif
153endforeach
154
155# set other values pulled from the build options
156dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
157dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
158dpdk_conf.set('RTE_MAX_ETHPORTS', get_option('max_ethports'))
159dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
160dpdk_conf.set('RTE_EAL_ALLOW_INV_SOCKET_ID', get_option('allow_invalid_socket_id'))
161# values which have defaults which may be overridden
162dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
163dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
164dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
165
166
167compile_time_cpuflags = []
168if host_machine.cpu_family().startswith('x86')
169	arch_subdir = 'x86'
170elif host_machine.cpu_family().startswith('arm') or host_machine.cpu_family().startswith('aarch')
171	arch_subdir = 'arm'
172elif host_machine.cpu_family().startswith('ppc')
173	arch_subdir = 'ppc_64'
174endif
175subdir(arch_subdir)
176dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
177
178# set the install path for the drivers
179dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
180
181install_headers('rte_config.h', subdir: get_option('include_subdir_arch'))
182
183# enable VFIO only if it is linux OS
184dpdk_conf.set('RTE_EAL_VFIO', is_linux)
185