xref: /dpdk/config/meson.build (revision 4bcb9b76) 
1# SPDX-License-Identifier: BSD-3-Clause
2# Copyright(c) 2017 Intel Corporation
3
4# set the machine type and cflags for it
5if meson.is_cross_build()
6	machine = host_machine.cpu()
7else
8	machine = get_option('machine')
9endif
10
11# machine type 'default' is special, it defaults to the per arch agreed common
12# minimal baseline needed for DPDK.
13# That might not be the most optimized, but the most portable version while
14# still being able to support the CPU features required for DPDK.
15# This can be bumped up by the DPDK project, but it can never be an
16# invariant like 'native'
17if machine == 'default'
18	if host_machine.cpu_family().startswith('x86')
19		# matches the old pre-meson build systems default
20		machine = 'corei7'
21	elif host_machine.cpu_family().startswith('arm')
22		machine = 'armv7-a'
23	elif host_machine.cpu_family().startswith('aarch')
24		# arm64 manages defaults in config/arm/meson.build
25		machine = 'default'
26	elif host_machine.cpu_family().startswith('ppc')
27		machine = 'power8'
28	endif
29endif
30
31dpdk_conf.set('RTE_MACHINE', machine)
32machine_args = []
33
34# ppc64 does not support -march= at all, use -mcpu and -mtune for that
35if host_machine.cpu_family().startswith('ppc')
36	machine_args += '-mcpu=' + machine
37	machine_args += '-mtune=' + machine
38else
39	machine_args += '-march=' + machine
40endif
41
42toolchain = cc.get_id()
43dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
44dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
45
46dpdk_conf.set('RTE_ARCH_64', cc.sizeof('void *') == 8)
47
48add_project_link_arguments('-Wl,--no-as-needed', language: 'c')
49dpdk_extra_ldflags += '-Wl,--no-as-needed'
50
51# use pthreads
52add_project_link_arguments('-pthread', language: 'c')
53dpdk_extra_ldflags += '-pthread'
54
55# some libs depend on maths lib
56add_project_link_arguments('-lm', language: 'c')
57dpdk_extra_ldflags += '-lm'
58
59# for linux link against dl, for bsd execinfo
60if host_machine.system() == 'linux'
61	link_lib = 'dl'
62else
63	link_lib = 'execinfo'
64endif
65add_project_link_arguments('-l' + link_lib, language: 'c')
66dpdk_extra_ldflags += '-l' + link_lib
67
68# check for libraries used in multiple places in DPDK
69has_libnuma = 0
70numa_dep = cc.find_library('numa', required: false)
71if numa_dep.found() and cc.has_header('numaif.h')
72	dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
73	has_libnuma = 1
74	add_project_link_arguments('-lnuma', language: 'c')
75	dpdk_extra_ldflags += '-lnuma'
76endif
77
78# check for strlcpy
79if host_machine.system() == 'linux'
80	libbsd = dependency('libbsd', required: false)
81	if libbsd.found()
82		dpdk_conf.set('RTE_USE_LIBBSD', 1)
83	endif
84endif
85
86# add -include rte_config to cflags
87add_project_arguments('-include', 'rte_config.h', language: 'c')
88
89# enable extra warnings and disable any unwanted warnings
90warning_flags = [
91	'-Wsign-compare',
92	'-Wcast-qual',
93	'-Wno-address-of-packed-member'
94]
95if not dpdk_conf.get('RTE_ARCH_64')
96# for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
97	warning_flags += '-Wno-pointer-to-int-cast'
98endif
99foreach arg: warning_flags
100	if cc.has_argument(arg)
101		add_project_arguments(arg, language: 'c')
102	endif
103endforeach
104
105# set other values pulled from the build options
106dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
107dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
108dpdk_conf.set('RTE_MAX_ETHPORTS', get_option('max_ethports'))
109dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
110dpdk_conf.set('RTE_EAL_ALLOW_INV_SOCKET_ID', get_option('allow_invalid_socket_id'))
111# values which have defaults which may be overridden
112dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
113dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
114dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
115
116
117compile_time_cpuflags = []
118if host_machine.cpu_family().startswith('x86')
119	arch_subdir = 'x86'
120elif host_machine.cpu_family().startswith('arm') or host_machine.cpu_family().startswith('aarch')
121	arch_subdir = 'arm'
122elif host_machine.cpu_family().startswith('ppc')
123	arch_subdir = 'ppc_64'
124endif
125subdir(arch_subdir)
126dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
127
128# set the install path for the drivers
129dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
130
131install_headers('rte_config.h', subdir: get_option('include_subdir_arch'))
132
133# enable VFIO only if it is linux OS
134dpdk_conf.set('RTE_EAL_VFIO', host_machine.system() == 'linux')
135