xref: /dpdk/config/meson.build (revision 02edbfab) 
1# SPDX-License-Identifier: BSD-3-Clause
2# Copyright(c) 2017-2019 Intel Corporation
3
4# check the OS is supported, rather than going any further
5supported_exec_envs = ['freebsd', 'linux', 'windows']
6exec_env = host_machine.system()
7if not supported_exec_envs.contains(exec_env)
8    error('unsupported system type "@0@"'.format(exec_env))
9endif
10
11# define a handy variable for checking which OS we have.
12# gives us "is_windows", "is_freebsd" and "is_linux"
13foreach env:supported_exec_envs
14    set_variable('is_' + env, exec_env == env)
15endforeach
16
17# MS linker requires special treatment.
18# TODO: use cc.get_linker_id() with Meson >= 0.54
19is_ms_linker = is_windows and (cc.get_id() == 'clang')
20
21# set the major version, which might be used by drivers and libraries
22# depending on the configuration options
23pver = meson.project_version().split('.')
24major_version = '@0@.@1@'.format(pver.get(0), pver.get(1))
25abi_version = run_command(find_program('cat', 'more'), abi_version_file).stdout().strip()
26
27# Libraries have the abi_version as the filename extension
28# and have the soname be all but the final part of the abi_version.
29# e.g. v20.1 => librte_foo.so.20.1
30#    sonames => librte_foo.so.20
31so_version = abi_version.split('.')[0]
32
33# extract all version information into the build configuration
34dpdk_conf.set('RTE_VER_YEAR', pver.get(0).to_int())
35dpdk_conf.set('RTE_VER_MONTH', pver.get(1).to_int())
36if pver.get(2).contains('-rc')
37    rc_ver = pver.get(2).split('-rc')
38    dpdk_conf.set('RTE_VER_MINOR', rc_ver.get(0).to_int())
39    dpdk_conf.set_quoted('RTE_VER_SUFFIX', '-rc')
40    dpdk_conf.set('RTE_VER_RELEASE', rc_ver.get(1).to_int())
41else
42    dpdk_conf.set('RTE_VER_MINOR', pver.get(2).to_int())
43    dpdk_conf.set_quoted('RTE_VER_SUFFIX', '')
44# for actual, non-rc releases, set the release value to 99 to ensure releases
45# have higher version numbers than their respective release candidates
46    dpdk_conf.set('RTE_VER_RELEASE', 99)
47endif
48
49pmd_subdir_opt = get_option('drivers_install_subdir')
50if pmd_subdir_opt.contains('<VERSION>')
51    pmd_subdir_opt = abi_version.join(pmd_subdir_opt.split('<VERSION>'))
52endif
53driver_install_path = join_paths(get_option('libdir'), pmd_subdir_opt)
54eal_pmd_path = join_paths(get_option('prefix'), driver_install_path)
55
56# driver .so files often depend upon the bus drivers for their connect bus,
57# e.g. ixgbe depends on librte_bus_pci. This means that the bus drivers need
58# to be in the library path, so symlink the drivers from the main lib directory.
59if not is_windows
60    meson.add_install_script('../buildtools/symlink-drivers-solibs.sh',
61            get_option('libdir'), pmd_subdir_opt)
62endif
63
64# init disable/enable driver lists that will be populated in different places
65disable_drivers = ''
66enable_drivers = ''
67
68# set the machine type and cflags for it
69if meson.is_cross_build()
70    machine = host_machine.cpu()
71else
72    machine = get_option('machine')
73endif
74
75# machine type 'generic' is special, it selects the per arch agreed common
76# minimal baseline needed for DPDK. Machine type 'default' is also supported
77# with the same meaning for backwards compatibility.
78# That might not be the most optimized, but the most portable version while
79# still being able to support the CPU features required for DPDK.
80# This can be bumped up by the DPDK project, but it can never be an
81# invariant like 'native'
82if machine == 'default' or machine == 'generic'
83    if host_machine.cpu_family().startswith('x86')
84        # matches the old pre-meson build systems generic machine
85        machine = 'corei7'
86    elif host_machine.cpu_family().startswith('arm')
87        machine = 'armv7-a'
88    elif host_machine.cpu_family().startswith('aarch')
89        # arm64 manages generic config in config/arm/meson.build
90        machine = 'generic'
91    elif host_machine.cpu_family().startswith('ppc')
92        machine = 'power8'
93    endif
94endif
95
96dpdk_conf.set('RTE_MACHINE', machine)
97machine_args = []
98
99# ppc64 does not support -march= at all, use -mcpu and -mtune for that
100if host_machine.cpu_family().startswith('ppc')
101    machine_args += '-mcpu=' + machine
102    machine_args += '-mtune=' + machine
103else
104    machine_args += '-march=' + machine
105endif
106
107toolchain = cc.get_id()
108dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
109dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
110
111dpdk_conf.set('RTE_ARCH_64', cc.sizeof('void *') == 8)
112dpdk_conf.set('RTE_ARCH_32', cc.sizeof('void *') == 4)
113
114if not is_windows
115    add_project_link_arguments('-Wl,--no-as-needed', language: 'c')
116endif
117
118# use pthreads if available for the platform
119if not is_windows
120    add_project_link_arguments('-pthread', language: 'c')
121    dpdk_extra_ldflags += '-pthread'
122endif
123
124# on some OS, maths functions are in a separate library
125if cc.find_library('m', required : false).found()
126    # some libs depend on maths lib
127    add_project_link_arguments('-lm', language: 'c')
128    dpdk_extra_ldflags += '-lm'
129endif
130
131if is_linux
132    link_lib = 'dl'
133else
134    link_lib = ''
135endif
136
137# if link_lib is empty, do not add it to project properties
138if link_lib != ''
139    add_project_link_arguments('-l' + link_lib, language: 'c')
140    dpdk_extra_ldflags += '-l' + link_lib
141endif
142
143# check for libraries used in multiple places in DPDK
144has_libnuma = 0
145find_libnuma = true
146if meson.is_cross_build() and not meson.get_cross_property('numa', true)
147    # don't look for libnuma if explicitly disabled in cross build
148    find_libnuma = false
149endif
150if find_libnuma
151    numa_dep = cc.find_library('numa', required: false)
152    if numa_dep.found() and cc.has_header('numaif.h')
153        dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
154        has_libnuma = 1
155        add_project_link_arguments('-lnuma', language: 'c')
156        dpdk_extra_ldflags += '-lnuma'
157    endif
158endif
159
160has_libfdt = 0
161fdt_dep = cc.find_library('libfdt', required: false)
162if fdt_dep.found() and cc.has_header('fdt.h')
163    dpdk_conf.set10('RTE_HAS_LIBFDT', true)
164    has_libfdt = 1
165    add_project_link_arguments('-lfdt', language: 'c')
166    dpdk_extra_ldflags += '-lfdt'
167endif
168
169libexecinfo = cc.find_library('libexecinfo', required: false)
170if libexecinfo.found() and cc.has_header('execinfo.h')
171    add_project_link_arguments('-lexecinfo', language: 'c')
172    dpdk_extra_ldflags += '-lexecinfo'
173endif
174
175libarchive = dependency('libarchive', required: false, method: 'pkg-config')
176if libarchive.found()
177    dpdk_conf.set('RTE_HAS_LIBARCHIVE', 1)
178    # Push libarchive link dependency at the project level to support
179    # statically linking dpdk apps. Details at:
180    # https://inbox.dpdk.org/dev/20210605004024.660267a1@sovereign/
181    add_project_link_arguments('-larchive', language: 'c')
182    dpdk_extra_ldflags += '-larchive'
183endif
184
185# check for libbsd
186libbsd = dependency('libbsd', required: false, method: 'pkg-config')
187if libbsd.found()
188    dpdk_conf.set('RTE_USE_LIBBSD', 1)
189endif
190
191# check for pcap
192pcap_dep = dependency('libpcap', required: false, method: 'pkg-config')
193pcap_lib = is_windows ? 'wpcap' : 'pcap'
194if not pcap_dep.found()
195    # pcap got a pkg-config file only in 1.9.0
196    pcap_dep = cc.find_library(pcap_lib, required: false)
197endif
198if pcap_dep.found() and cc.has_header('pcap.h', dependencies: pcap_dep)
199    dpdk_conf.set('RTE_PORT_PCAP', 1)
200    dpdk_extra_ldflags += '-l@0@'.format(pcap_lib)
201endif
202
203# for clang 32-bit compiles we need libatomic for 64-bit atomic ops
204if cc.get_id() == 'clang' and dpdk_conf.get('RTE_ARCH_64') == false
205    atomic_dep = cc.find_library('atomic', required: true)
206    add_project_link_arguments('-latomic', language: 'c')
207    dpdk_extra_ldflags += '-latomic'
208endif
209
210# add -include rte_config to cflags
211add_project_arguments('-include', 'rte_config.h', language: 'c')
212
213# enable extra warnings and disable any unwanted warnings
214warning_flags = [
215        # -Wall is added by meson by default, so add -Wextra only
216        '-Wextra',
217
218        # additional warnings in alphabetical order
219        '-Wcast-qual',
220        '-Wdeprecated',
221        '-Wformat',
222        '-Wformat-nonliteral',
223        '-Wformat-security',
224        '-Wmissing-declarations',
225        '-Wmissing-prototypes',
226        '-Wnested-externs',
227        '-Wold-style-definition',
228        '-Wpointer-arith',
229        '-Wsign-compare',
230        '-Wstrict-prototypes',
231        '-Wundef',
232        '-Wwrite-strings',
233
234        # globally disabled warnings
235        '-Wno-address-of-packed-member',
236        '-Wno-packed-not-aligned',
237        '-Wno-missing-field-initializers',
238]
239if cc.get_id() == 'gcc' and cc.version().version_compare('>=10.0')
240# FIXME: Bugzilla 396
241    warning_flags += '-Wno-zero-length-bounds'
242endif
243if not dpdk_conf.get('RTE_ARCH_64')
244# for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
245    warning_flags += '-Wno-pointer-to-int-cast'
246endif
247if cc.get_id() == 'intel'
248    warning_ids = [181, 188, 2203, 2279, 2557, 3179, 3656]
249    foreach i:warning_ids
250        warning_flags += '-diag-disable=@0@'.format(i)
251    endforeach
252endif
253foreach arg: warning_flags
254    if cc.has_argument(arg)
255        add_project_arguments(arg, language: 'c')
256    endif
257endforeach
258
259# set other values pulled from the build options
260dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
261dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
262dpdk_conf.set('RTE_MAX_ETHPORTS', get_option('max_ethports'))
263dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
264dpdk_conf.set('RTE_ENABLE_TRACE_FP', get_option('enable_trace_fp'))
265# values which have defaults which may be overridden
266dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
267dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
268dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
269if dpdk_conf.get('RTE_ARCH_64')
270    dpdk_conf.set('RTE_MAX_MEM_MB', 524288)
271else # for 32-bit we need smaller reserved memory areas
272    dpdk_conf.set('RTE_MAX_MEM_MB', 2048)
273endif
274
275
276compile_time_cpuflags = []
277subdir(arch_subdir)
278dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
279
280# apply cross-specific options
281if meson.is_cross_build()
282    # configure RTE_MAX_LCORE and RTE_MAX_NUMA_NODES from cross file
283    cross_max_lcores = meson.get_cross_property('max_lcores', 0)
284    if cross_max_lcores != 0
285        message('Setting RTE_MAX_LCORE from cross file')
286        dpdk_conf.set('RTE_MAX_LCORE', cross_max_lcores)
287    endif
288    cross_max_numa_nodes = meson.get_cross_property('max_numa_nodes', 0)
289    if cross_max_numa_nodes != 0
290        message('Setting RTE_MAX_NUMA_NODES from cross file')
291        dpdk_conf.set('RTE_MAX_NUMA_NODES', cross_max_numa_nodes)
292    endif
293endif
294
295# set the install path for the drivers
296dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
297
298install_headers(['rte_config.h'],
299        subdir: get_option('include_subdir_arch'))
300
301# enable VFIO only if it is linux OS
302dpdk_conf.set('RTE_EAL_VFIO', is_linux)
303
304# specify -D_GNU_SOURCE unconditionally
305add_project_arguments('-D_GNU_SOURCE', language: 'c')
306
307# specify -D__BSD_VISIBLE for FreeBSD
308if is_freebsd
309    add_project_arguments('-D__BSD_VISIBLE', language: 'c')
310endif
311
312if is_windows
313    # VirtualAlloc2() is available since Windows 10 / Server 2016.
314    add_project_arguments('-D_WIN32_WINNT=0x0A00', language: 'c')
315
316    # Use MinGW-w64 stdio, because DPDK assumes ANSI-compliant formatting.
317    if cc.get_id() == 'gcc'
318        add_project_arguments('-D__USE_MINGW_ANSI_STDIO', language: 'c')
319    endif
320
321    # Disable secure CRT deprecated warnings for clang
322    if cc.get_id() == 'clang'
323        add_project_arguments('-D_CRT_SECURE_NO_WARNINGS', language: 'c')
324    endif
325
326    add_project_link_arguments('-lws2_32', language: 'c')
327
328    # Contrary to docs, VirtualAlloc2() is exported by mincore.lib
329    # in Windows SDK, while MinGW exports it by advapi32.a.
330    if is_ms_linker
331        add_project_link_arguments('-lmincore', language: 'c')
332    endif
333
334    add_project_link_arguments('-ladvapi32', '-lsetupapi', language: 'c')
335    add_project_link_arguments('-ldbghelp', language: 'c')
336endif
337
338if get_option('b_lto')
339    if cc.has_argument('-ffat-lto-objects')
340        add_project_arguments('-ffat-lto-objects', language: 'c')
341    else
342        error('compiler does not support fat LTO objects - please turn LTO off')
343    endif
344    # workaround for gcc bug 81440
345    if cc.get_id() == 'gcc' and cc.version().version_compare('<8.0')
346        add_project_arguments('-Wno-lto-type-mismatch', language: 'c')
347        add_project_link_arguments('-Wno-lto-type-mismatch', language: 'c')
348    endif
349endif
350
351if get_option('default_library') == 'both'
352    error( '''
353 Unsupported value "both" for "default_library" option.
354
355 NOTE: DPDK always builds both shared and static libraries.  Please set
356 "default_library" to either "static" or "shared" to select default linkage
357 for apps and any examples.''')
358endif
359