1@echo off
2setlocal enabledelayedexpansion
3
4if "%1"=="" goto usage
5goto begin
6
7:usage
8echo Script for building the LLVM installer on Windows,
9echo used for the releases at https://github.com/llvm/llvm-project/releases
10echo.
11echo Usage: build_llvm_release.bat ^<version^>
12echo.
13echo Example: build_llvm_release.bat 14.0.4
14echo.
15exit /b 1
16
17:begin
18
19REM Note:
20REM   7zip versions 21.x and higher will try to extract the symlinks in
21REM   llvm's git archive, which requires running as administrator.
22
23REM Check 7-zip version and/or administrator permissions.
24for /f "delims=" %%i in ('7z.exe ^| findstr /r "2[1-9].[0-9][0-9]"') do set version=%%i
25if not "%version%"=="" (
26  REM Unique temporary filename to use by the 'mklink' command.
27  set "link_name=%temp%\%username%_%random%_%random%.tmp"
28
29  REM As the 'mklink' requires elevated permissions, the symbolic link
30  REM creation will fail if the script is not running as administrator.
31  mklink /d "!link_name!" . 1>nul 2>nul
32  if errorlevel 1 (
33    echo.
34    echo Script requires administrator permissions, or a 7-zip version 20.x or older.
35    echo Current version is "%version%"
36    exit /b 1
37  ) else (
38    REM Remove the temporary symbolic link.
39    rd "!link_name!"
40  )
41)
42
43REM Prerequisites:
44REM
45REM   Visual Studio 2019, CMake, Ninja, GNUWin32, SWIG, Python 3,
46REM   NSIS with the strlen_8192 patch,
47REM   Visual Studio 2019 SDK and Nuget (for the clang-format plugin),
48REM   Perl (for the OpenMP run-time).
49REM
50REM
51REM   For LLDB, SWIG version <= 3.0.8 needs to be used to work around
52REM   https://github.com/swig/swig/issues/769
53
54
55REM You need to modify the paths below:
56set vsdevcmd=C:\Program Files (x86)\Microsoft Visual Studio\2019\Professional\Common7\Tools\VsDevCmd.bat
57
58set python32_dir=C:\Users\%USERNAME%\AppData\Local\Programs\Python\Python310-32
59set python64_dir=C:\Users\%USERNAME%\AppData\Local\Programs\Python\Python310
60
61set revision=llvmorg-%1
62set package_version=%1
63set build_dir=%cd%\llvm_package_%package_version%
64
65echo Revision: %revision%
66echo Package version: %package_version%
67echo Build dir: %build_dir%
68echo.
69pause
70
71if exist %build_dir% (
72  echo Build directory already exists: %build_dir%
73  exit /b 1
74)
75mkdir %build_dir%
76cd %build_dir%
77
78echo Checking out %revision%
79curl -L https://github.com/llvm/llvm-project/archive/%revision%.zip -o src.zip || exit /b 1
807z x src.zip || exit /b 1
81mv llvm-project-* llvm-project || exit /b 1
82
83curl -O https://gitlab.gnome.org/GNOME/libxml2/-/archive/v2.9.12/libxml2-v2.9.12.tar.gz || exit /b 1
84tar zxf libxml2-v2.9.12.tar.gz
85
86REM Setting CMAKE_CL_SHOWINCLUDES_PREFIX to work around PR27226.
87REM Common flags for both 32/64 builds.
88set common_cmake_flags=^
89  -DCMAKE_BUILD_TYPE=Release ^
90  -DLLVM_ENABLE_ASSERTIONS=OFF ^
91  -DLLVM_INSTALL_TOOLCHAIN_ONLY=ON ^
92  -DLLVM_BUILD_LLVM_C_DYLIB=ON ^
93  -DCMAKE_INSTALL_UCRT_LIBRARIES=ON ^
94  -DPython3_FIND_REGISTRY=NEVER ^
95  -DPACKAGE_VERSION=%package_version% ^
96  -DLLDB_RELOCATABLE_PYTHON=1 ^
97  -DLLDB_EMBED_PYTHON_HOME=OFF ^
98  -DCMAKE_CL_SHOWINCLUDES_PREFIX="Note: including file: " ^
99  -DLLVM_ENABLE_LIBXML2=FORCE_ON ^
100  -DLLDB_ENABLE_LIBXML2=OFF ^
101  -DCMAKE_C_FLAGS="-DLIBXML_STATIC" ^
102  -DCMAKE_CXX_FLAGS="-DLIBXML_STATIC" ^
103  -DLLVM_ENABLE_PROJECTS="clang;clang-tools-extra;lld;compiler-rt;lldb;openmp"
104
105REM Preserve original path
106set OLDPATH=%PATH%
107
108REM Build the 32-bits and/or 64-bits binaries.
109call :do_build_32 || exit /b 1
110call :do_build_64 || exit /b 1
111exit /b 0
112
113::==============================================================================
114:: Build 32-bits binaries.
115::==============================================================================
116:do_build_32
117REM Restore original path
118set PATH=%OLDPATH%
119
120REM TODO: Run the "check-all" tests.
121
122REM Set Python environment
123set PYTHONHOME=%python32_dir%
124set PATH=%PYTHONHOME%;%PATH%
125
126set "VSCMD_START_DIR=%build_dir%"
127call "%vsdevcmd%" -arch=x86
128mkdir build32_stage0
129cd build32_stage0
130
131mkdir libxmlbuild
132cd libxmlbuild
133cmake -GNinja -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX=install -DBUILD_SHARED_LIBS=OFF -DLIBXML2_WITH_C14N=OFF -DLIBXML2_WITH_CATALOG=OFF -DLIBXML2_WITH_DEBUG=OFF -DLIBXML2_WITH_DOCB=OFF -DLIBXML2_WITH_FTP=OFF -DLIBXML2_WITH_HTML=OFF -DLIBXML2_WITH_HTTP=OFF -DLIBXML2_WITH_ICONV=OFF -DLIBXML2_WITH_ICU=OFF -DLIBXML2_WITH_ISO8859X=OFF -DLIBXML2_WITH_LEGACY=OFF -DLIBXML2_WITH_LZMA=OFF -DLIBXML2_WITH_MEM_DEBUG=OFF -DLIBXML2_WITH_MODULES=OFF -DLIBXML2_WITH_OUTPUT=ON -DLIBXML2_WITH_PATTERN=OFF -DLIBXML2_WITH_PROGRAMS=OFF -DLIBXML2_WITH_PUSH=OFF -DLIBXML2_WITH_PYTHON=OFF -DLIBXML2_WITH_READER=OFF -DLIBXML2_WITH_REGEXPS=OFF -DLIBXML2_WITH_RUN_DEBUG=OFF -DLIBXML2_WITH_SAX1=OFF -DLIBXML2_WITH_SCHEMAS=OFF -DLIBXML2_WITH_SCHEMATRON=OFF -DLIBXML2_WITH_TESTS=OFF -DLIBXML2_WITH_THREADS=ON -DLIBXML2_WITH_THREAD_ALLOC=OFF -DLIBXML2_WITH_TREE=ON -DLIBXML2_WITH_VALID=OFF -DLIBXML2_WITH_WRITER=OFF -DLIBXML2_WITH_XINCLUDE=OFF -DLIBXML2_WITH_XPATH=OFF -DLIBXML2_WITH_XPTR=OFF -DLIBXML2_WITH_ZLIB=OFF ../../libxml2-v2.9.12 || exit /b 1
134ninja install || exit /b 1
135set libxmldir=%cd%\install
136set "libxmldir=%libxmldir:\=/%"
137cd ..
138
139REM Stage0 binaries directory; used in stage1.
140set "stage0_bin_dir=%build_dir%/build32_stage0/bin"
141set cmake_flags=^
142  %common_cmake_flags% ^
143  -DLLDB_TEST_COMPILER=%stage0_bin_dir%/clang.exe ^
144  -DPYTHON_HOME=%PYTHONHOME% ^
145  -DPython3_ROOT_DIR=%PYTHONHOME% ^
146  -DLIBXML2_INCLUDE_DIRS=%libxmldir%/include/libxml2 ^
147  -DLIBXML2_LIBRARIES=%libxmldir%/lib/libxml2s.lib
148
149cmake -GNinja %cmake_flags% ..\llvm-project\llvm || exit /b 1
150ninja || ninja || ninja || exit /b 1
151REM ninja check-llvm || ninja check-llvm || ninja check-llvm || exit /b 1
152REM ninja check-clang || ninja check-clang || ninja check-clang || exit /b 1
153ninja check-lld || ninja check-lld || ninja check-lld || exit /b 1
154ninja check-sanitizer || ninja check-sanitizer || ninja check-sanitizer || exit /b 1
155REM ninja check-clang-tools || ninja check-clang-tools || ninja check-clang-tools || exit /b 1
156cd..
157
158REM CMake expects the paths that specifies the compiler and linker to be
159REM with forward slash.
160set all_cmake_flags=^
161  %cmake_flags% ^
162  -DCMAKE_C_COMPILER=%stage0_bin_dir%/clang-cl.exe ^
163  -DCMAKE_CXX_COMPILER=%stage0_bin_dir%/clang-cl.exe ^
164  -DCMAKE_LINKER=%stage0_bin_dir%/lld-link.exe ^
165  -DCMAKE_AR=%stage0_bin_dir%/llvm-lib.exe ^
166  -DCMAKE_RC=%stage0_bin_dir%/llvm-windres.exe
167set cmake_flags=%all_cmake_flags:\=/%
168
169mkdir build32
170cd build32
171cmake -GNinja %cmake_flags% ..\llvm-project\llvm || exit /b 1
172ninja || ninja || ninja || exit /b 1
173REM ninja check-llvm || ninja check-llvm || ninja check-llvm || exit /b 1
174REM ninja check-clang || ninja check-clang || ninja check-clang || exit /b 1
175ninja check-lld || ninja check-lld || ninja check-lld || exit /b 1
176ninja check-sanitizer || ninja check-sanitizer || ninja check-sanitizer || exit /b 1
177REM ninja check-clang-tools || ninja check-clang-tools || ninja check-clang-tools || exit /b 1
178ninja package || exit /b 1
179cd ..
180
181exit /b 0
182::==============================================================================
183
184::==============================================================================
185:: Build 64-bits binaries.
186::==============================================================================
187:do_build_64
188REM Restore original path
189set PATH=%OLDPATH%
190
191REM Set Python environment
192set PYTHONHOME=%python64_dir%
193set PATH=%PYTHONHOME%;%PATH%
194
195set "VSCMD_START_DIR=%build_dir%"
196call "%vsdevcmd%" -arch=amd64
197mkdir build64_stage0
198cd build64_stage0
199
200mkdir libxmlbuild
201cd libxmlbuild
202cmake -GNinja -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX=install -DBUILD_SHARED_LIBS=OFF -DLIBXML2_WITH_C14N=OFF -DLIBXML2_WITH_CATALOG=OFF -DLIBXML2_WITH_DEBUG=OFF -DLIBXML2_WITH_DOCB=OFF -DLIBXML2_WITH_FTP=OFF -DLIBXML2_WITH_HTML=OFF -DLIBXML2_WITH_HTTP=OFF -DLIBXML2_WITH_ICONV=OFF -DLIBXML2_WITH_ICU=OFF -DLIBXML2_WITH_ISO8859X=OFF -DLIBXML2_WITH_LEGACY=OFF -DLIBXML2_WITH_LZMA=OFF -DLIBXML2_WITH_MEM_DEBUG=OFF -DLIBXML2_WITH_MODULES=OFF -DLIBXML2_WITH_OUTPUT=ON -DLIBXML2_WITH_PATTERN=OFF -DLIBXML2_WITH_PROGRAMS=OFF -DLIBXML2_WITH_PUSH=OFF -DLIBXML2_WITH_PYTHON=OFF -DLIBXML2_WITH_READER=OFF -DLIBXML2_WITH_REGEXPS=OFF -DLIBXML2_WITH_RUN_DEBUG=OFF -DLIBXML2_WITH_SAX1=OFF -DLIBXML2_WITH_SCHEMAS=OFF -DLIBXML2_WITH_SCHEMATRON=OFF -DLIBXML2_WITH_TESTS=OFF -DLIBXML2_WITH_THREADS=ON -DLIBXML2_WITH_THREAD_ALLOC=OFF -DLIBXML2_WITH_TREE=ON -DLIBXML2_WITH_VALID=OFF -DLIBXML2_WITH_WRITER=OFF -DLIBXML2_WITH_XINCLUDE=OFF -DLIBXML2_WITH_XPATH=OFF -DLIBXML2_WITH_XPTR=OFF -DLIBXML2_WITH_ZLIB=OFF ../../libxml2-v2.9.12 || exit /b 1
203ninja install || exit /b 1
204set libxmldir=%cd%\install
205set "libxmldir=%libxmldir:\=/%"
206cd ..
207
208REM Stage0 binaries directory; used in stage1.
209set "stage0_bin_dir=%build_dir%/build64_stage0/bin"
210set cmake_flags=^
211  %common_cmake_flags% ^
212  -DLLDB_TEST_COMPILER=%stage0_bin_dir%/clang.exe ^
213  -DPYTHON_HOME=%PYTHONHOME% ^
214  -DPython3_ROOT_DIR=%PYTHONHOME% ^
215  -DLIBXML2_INCLUDE_DIRS=%libxmldir%/include/libxml2 ^
216  -DLIBXML2_LIBRARIES=%libxmldir%/lib/libxml2s.lib
217
218cmake -GNinja %cmake_flags% ..\llvm-project\llvm || exit /b 1
219ninja || ninja || ninja || exit /b 1
220ninja check-llvm || ninja check-llvm || ninja check-llvm || exit /b 1
221ninja check-clang || ninja check-clang || ninja check-clang || exit /b 1
222ninja check-lld || ninja check-lld || ninja check-lld || exit /b 1
223ninja check-sanitizer || ninja check-sanitizer || ninja check-sanitizer || exit /b 1
224ninja check-clang-tools || ninja check-clang-tools || ninja check-clang-tools || exit /b 1
225ninja check-clangd || ninja check-clangd || ninja check-clangd || exit /b 1
226cd..
227
228REM CMake expects the paths that specifies the compiler and linker to be
229REM with forward slash.
230set all_cmake_flags=^
231  %cmake_flags% ^
232  -DCMAKE_C_COMPILER=%stage0_bin_dir%/clang-cl.exe ^
233  -DCMAKE_CXX_COMPILER=%stage0_bin_dir%/clang-cl.exe ^
234  -DCMAKE_LINKER=%stage0_bin_dir%/lld-link.exe ^
235  -DCMAKE_AR=%stage0_bin_dir%/llvm-lib.exe ^
236  -DCMAKE_RC=%stage0_bin_dir%/llvm-windres.exe
237set cmake_flags=%all_cmake_flags:\=/%
238
239mkdir build64
240cd build64
241cmake -GNinja %cmake_flags% ..\llvm-project\llvm || exit /b 1
242ninja || ninja || ninja || exit /b 1
243ninja check-llvm || ninja check-llvm || ninja check-llvm || exit /b 1
244ninja check-clang || ninja check-clang || ninja check-clang || exit /b 1
245ninja check-lld || ninja check-lld || ninja check-lld || exit /b 1
246ninja check-sanitizer || ninja check-sanitizer || ninja check-sanitizer || exit /b 1
247ninja check-clang-tools || ninja check-clang-tools || ninja check-clang-tools || exit /b 1
248ninja check-clangd || ninja check-clangd || ninja check-clangd || exit /b 1
249ninja package || exit /b 1
250cd ..
251
252exit /b 0
253::==============================================================================
254