1set(LLVM_LINK_COMPONENTS support)
2
3set(BUILDVARIABLES_SRCPATH ${CMAKE_CURRENT_SOURCE_DIR}/BuildVariables.inc.in)
4set(BUILDVARIABLES_OBJPATH ${CMAKE_CURRENT_BINARY_DIR}/BuildVariables.inc)
5
6# Add the llvm-config tool.
7add_llvm_tool(llvm-config
8  llvm-config.cpp
9  # This utility doesn't use much of LLVM, so linking a shared library for the
10  # entire thing is overkill. Avoiding that especially saves on build time when cross
11  # compiling LLVM and building both cross and native `llvm-config`s. We don't
12  # want to build an entire native libLLVM.so in addition to the cross one just
13  # for the native `llvm-config`!
14  DISABLE_LLVM_LINK_LLVM_DYLIB
15  )
16
17# Compute the substitution values for various items.
18get_property(SUPPORT_SYSTEM_LIBS TARGET LLVMSupport PROPERTY LLVM_SYSTEM_LIBS)
19get_property(WINDOWSMANIFEST_SYSTEM_LIBS TARGET LLVMWindowsManifest PROPERTY LLVM_SYSTEM_LIBS)
20
21foreach(l ${SUPPORT_SYSTEM_LIBS} ${WINDOWSMANIFEST_SYSTEM_LIBS})
22  if(MSVC)
23    if(IS_ABSOLUTE ${l})
24      set(SYSTEM_LIBS ${SYSTEM_LIBS} "${l}")
25    else()
26      set(SYSTEM_LIBS ${SYSTEM_LIBS} "${l}.lib")
27    endif()
28  else()
29    if (l MATCHES "^-")
30      # If it's an option, pass it without changes.
31      set(SYSTEM_LIBS ${SYSTEM_LIBS} "${l}")
32    else()
33      # Otherwise assume it's a library name we need to link with.
34      if(IS_ABSOLUTE ${l})
35        set(SYSTEM_LIBS ${SYSTEM_LIBS} "${l}")
36      else()
37        set(SYSTEM_LIBS ${SYSTEM_LIBS} "-l${l}")
38      endif()
39    endif()
40  endif()
41endforeach()
42
43string(REPLACE ";" " " SYSTEM_LIBS "${SYSTEM_LIBS}")
44
45# Fetch target specific compile options, e.g. RTTI option
46get_property(COMPILE_FLAGS TARGET llvm-config PROPERTY COMPILE_FLAGS)
47
48# NOTE: We don't want to start extracting any random C/CXX flags that the
49# user may add that could affect the ABI.  We only want to extract flags
50# that have been added by the LLVM build system.
51string(REGEX MATCH "-stdlib=[^ ]+" LLVM_CXX_STDLIB_FLAG ${CMAKE_CXX_FLAGS})
52string(REGEX MATCH "-std=[^ ]+" LLVM_C_STD_FLAG ${CMAKE_C_FLAGS})
53
54# Use configure_file to create BuildVariables.inc.
55set(LLVM_SRC_ROOT ${LLVM_MAIN_SRC_DIR})
56set(LLVM_OBJ_ROOT ${LLVM_BINARY_DIR})
57set(LLVM_CPPFLAGS "${LLVM_DEFINITIONS}")
58set(LLVM_CFLAGS "${LLVM_C_STD_FLAG} ${LLVM_DEFINITIONS}")
59# The language standard potentially affects the ABI/API of LLVM, so we want
60# to make sure it is reported by llvm-config.
61set(LLVM_CXXFLAGS "${CMAKE_CXX${CMAKE_CXX_STANDARD}_STANDARD_COMPILE_OPTION} ${LLVM_CXX_STDLIB_FLAG} ${COMPILE_FLAGS} ${LLVM_DEFINITIONS}")
62set(LLVM_BUILD_SYSTEM cmake)
63set(LLVM_HAS_RTTI ${LLVM_CONFIG_HAS_RTTI})
64set(LLVM_DYLIB_VERSION "${LLVM_VERSION_MAJOR}${LLVM_VERSION_SUFFIX}")
65
66# Use the C++ link flags, since they should be a superset of C link flags.
67set(LLVM_LDFLAGS "${CMAKE_CXX_LINK_FLAGS}")
68set(LLVM_BUILDMODE ${CMAKE_BUILD_TYPE})
69set(LLVM_SYSTEM_LIBS ${SYSTEM_LIBS})
70string(REPLACE ";" " " LLVM_TARGETS_BUILT "${LLVM_TARGETS_TO_BUILD}")
71llvm_canonicalize_cmake_booleans(
72  LLVM_BUILD_LLVM_DYLIB
73  LLVM_LINK_LLVM_DYLIB
74  LLVM_HAS_RTTI
75  BUILD_SHARED_LIBS)
76llvm_expand_pseudo_components(LLVM_DYLIB_COMPONENTS_expanded "${LLVM_DYLIB_COMPONENTS}")
77configure_file(${BUILDVARIABLES_SRCPATH} ${BUILDVARIABLES_OBJPATH} @ONLY)
78
79# Set build-time environment(s).
80add_definitions(-DCMAKE_CFG_INTDIR="${CMAKE_CFG_INTDIR}")
81
82if(LLVM_ENABLE_MODULES)
83  target_compile_options(llvm-config PUBLIC
84    "-fmodules-ignore-macro=CMAKE_CFG_INTDIR"
85    )
86endif()
87
88# Add the dependency on the generation step.
89add_file_dependencies(${CMAKE_CURRENT_SOURCE_DIR}/llvm-config.cpp ${BUILDVARIABLES_OBJPATH})
90
91if(CMAKE_CROSSCOMPILING AND NOT LLVM_CONFIG_PATH)
92  build_native_tool(llvm-config LLVM_CONFIG_PATH)
93  set(LLVM_CONFIG_PATH "${LLVM_CONFIG_PATH}" CACHE STRING "")
94
95  add_custom_target(NativeLLVMConfig DEPENDS ${LLVM_CONFIG_PATH})
96  add_dependencies(llvm-config NativeLLVMConfig)
97endif()
98